1 /*
2  * CDDL HEADER START
3  *
4  * The contents of this file are subject to the terms of the
5  * Common Development and Distribution License, Version 1.0 only
6  * (the "License").  You may not use this file except in compliance
7  * with the License.
8  *
9  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
10  * or http://www.opensolaris.org/os/licensing.
11  * See the License for the specific language governing permissions
12  * and limitations under the License.
13  *
14  * When distributing Covered Code, include this CDDL HEADER in each
15  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
16  * If applicable, add the following below this CDDL HEADER, with the
17  * fields enclosed by brackets "[]" replaced with your own identifying
18  * information: Portions Copyright [yyyy] [name of copyright owner]
19  *
20  * CDDL HEADER END
21  */
22 /*
23  * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
24  * Use is subject to license terms.
25  *
26  * This D script is used as an example in the Solaris Dynamic Tracing Guide
27  * wiki in the "io Provider" Chapter.
28  *
29  * The full text of the this chapter may be found here:
30  *
31  *   http://wikis.sun.com/display/DTrace/io+Provider
32  *
33  * On machines that have DTrace installed, this script is available as
34  * iothrough.d in /usr/demo/dtrace, a directory that contains all D scripts
35  * used in the Solaris Dynamic Tracing Guide.  A table of the scripts and their
36  * corresponding chapters may be found here:
37  *
38  *   file:///usr/demo/dtrace/index.html
39  */
40 
41 #pragma D option quiet
42 
43 io:::start
44 {
45 	start[args[0]->b_edev, args[0]->b_blkno] = timestamp;
46 }
47 
48 io:::done
49 /start[args[0]->b_edev, args[0]->b_blkno]/
50 {
51 	/*
52 	 * We want to get an idea of our throughput to this device in KB/sec.
53 	 * What we have, however, is nanoseconds and bytes.  That is we want
54 	 * to calculate:
55 	 *
56 	 *                        bytes / 1024
57 	 *                  ------------------------
58 	 *                  nanoseconds / 1000000000
59 	 *
60 	 * But we can't calculate this using integer arithmetic without losing
61 	 * precision (the denomenator, for one, is between 0 and 1 for nearly
62 	 * all I/Os).  So we restate the fraction, and cancel:
63 	 *
64 	 *     bytes      1000000000         bytes        976562
65 	 *   --------- * -------------  =  --------- * -------------
66 	 *      1024      nanoseconds          1        nanoseconds
67 	 *
68 	 * This is easy to calculate using integer arithmetic; this is what
69 	 * we do below.
70 	 */
71 	this->elapsed = timestamp - start[args[0]->b_edev, args[0]->b_blkno];
72 	@[args[1]->dev_statname, args[1]->dev_pathname] =
73 	    quantize((args[0]->b_bcount * 976562) / this->elapsed);
74 	start[args[0]->b_edev, args[0]->b_blkno] = 0;
75 }
76 
77 END
78 {
79 	printa("  %s (%s)\n%@d\n", @);
80 }
81