1 /*
2  * CDDL HEADER START
3  *
4  * The contents of this file are subject to the terms of the
5  * Common Development and Distribution License, Version 1.0 only
6  * (the "License").  You may not use this file except in compliance
7  * with the License.
8  *
9  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
10  * or http://www.opensolaris.org/os/licensing.
11  * See the License for the specific language governing permissions
12  * and limitations under the License.
13  *
14  * When distributing Covered Code, include this CDDL HEADER in each
15  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
16  * If applicable, add the following below this CDDL HEADER, with the
17  * fields enclosed by brackets "[]" replaced with your own identifying
18  * information: Portions Copyright [yyyy] [name of copyright owner]
19  *
20  * CDDL HEADER END
21  */
22 /*
23  * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
24  * Use is subject to license terms.
25  *
26  * This D script is used as an example in the Solaris Dynamic Tracing Guide
27  * wiki in the "io Provider" Chapter.
28  *
29  * The full text of the this chapter may be found here:
30  *
31  *   http://wikis.sun.com/display/DTrace/io+Provider
32  *
33  * On machines that have DTrace installed, this script is available as
34  * iocpu.d in /usr/demo/dtrace, a directory that contains all D scripts
35  * used in the Solaris Dynamic Tracing Guide.  A table of the scripts and their
36  * corresponding chapters may be found here:
37  *
38  *   file:///usr/demo/dtrace/index.html
39  */
40 
41 #pragma D option quiet
42 
43 sched:::on-cpu
44 /execname == "soffice.bin"/
45 {
46 	self->on = vtimestamp;
47 }
48 
49 sched:::off-cpu
50 /self->on/
51 {
52 	@time["<on cpu>"] = sum(vtimestamp - self->on);
53 	self->on = 0;
54 }
55 
56 io:::wait-start
57 /execname == "soffice.bin"/
58 {
59 	self->wait = timestamp;
60 }
61 
62 io:::wait-done
63 /self->wait/
64 {
65 	@io[args[2]->fi_name] = sum(timestamp - self->wait);
66 	@time["<I/O wait>"] = sum(timestamp - self->wait);
67 	self->wait = 0;
68 }
69 
70 END
71 {
72 	printf("Time breakdown (milliseconds):\n");
73 	normalize(@time, 1000000);
74 	printa("  %-50s %15@d\n", @time);
75 
76 	printf("\nI/O wait breakdown (milliseconds):\n");
77 	normalize(@io, 1000000);
78 	printa("  %-50s %15@d\n", @io);
79 }
80