xref: /linux/scripts/kernel-doc (revision f4fee216df7d28b87d1c9cc60bcebfecb51c1a05) 
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3# vim: softtabstop=4
4
5use warnings;
6use strict;
7
8## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
9## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
10## Copyright (C) 2001  Simon Huggins                             ##
11## Copyright (C) 2005-2012  Randy Dunlap                         ##
12## Copyright (C) 2012  Dan Luedtke                               ##
13## 								 ##
14## #define enhancements by Armin Kuster <akuster@mvista.com>	 ##
15## Copyright (c) 2000 MontaVista Software, Inc.			 ##
16#
17# Copyright (C) 2022 Tomasz Warniełło (POD)
18
19use Pod::Usage qw/pod2usage/;
20
21=head1 NAME
22
23kernel-doc - Print formatted kernel documentation to stdout
24
25=head1 SYNOPSIS
26
27 kernel-doc [-h] [-v] [-Werror] [-Wall] [-Wreturn] [-Wshort-desc[ription]] [-Wcontents-before-sections]
28   [ -man |
29     -rst [-sphinx-version VERSION] [-enable-lineno] |
30     -none
31   ]
32   [
33     -export |
34     -internal |
35     [-function NAME] ... |
36     [-nosymbol NAME] ...
37   ]
38   [-no-doc-sections]
39   [-export-file FILE] ...
40   FILE ...
41
42Run `kernel-doc -h` for details.
43
44=head1 DESCRIPTION
45
46Read C language source or header FILEs, extract embedded documentation comments,
47and print formatted documentation to standard output.
48
49The documentation comments are identified by the "/**" opening comment mark.
50
51See Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
52
53=cut
54
55# more perldoc at the end of the file
56
57## init lots of data
58
59my $errors = 0;
60my $warnings = 0;
61my $anon_struct_union = 0;
62
63# match expressions used to find embedded type information
64my $type_constant = '\b``([^\`]+)``\b';
65my $type_constant2 = '\%([-_\w]+)';
66my $type_func = '(\w+)\(\)';
67my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
68my $type_param_ref = '([\!~\*]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
69my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
70my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
71my $type_env = '(\$\w+)';
72my $type_enum = '\&(enum\s*([_\w]+))';
73my $type_struct = '\&(struct\s*([_\w]+))';
74my $type_typedef = '\&(typedef\s*([_\w]+))';
75my $type_union = '\&(union\s*([_\w]+))';
76my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
77my $type_fallback = '\&([_\w]+)';
78my $type_member_func = $type_member . '\(\)';
79
80# Output conversion substitutions.
81#  One for each output format
82
83# these are pretty rough
84my @highlights_man = (
85    [$type_constant, "\$1"],
86    [$type_constant2, "\$1"],
87    [$type_func, "\\\\fB\$1\\\\fP"],
88    [$type_enum, "\\\\fI\$1\\\\fP"],
89    [$type_struct, "\\\\fI\$1\\\\fP"],
90    [$type_typedef, "\\\\fI\$1\\\\fP"],
91    [$type_union, "\\\\fI\$1\\\\fP"],
92    [$type_param, "\\\\fI\$1\\\\fP"],
93    [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
94    [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
95    [$type_fallback, "\\\\fI\$1\\\\fP"]
96  );
97my $blankline_man = "";
98
99# rst-mode
100my @highlights_rst = (
101    [$type_constant, "``\$1``"],
102    [$type_constant2, "``\$1``"],
103
104    # Note: need to escape () to avoid func matching later
105    [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
106    [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
107    [$type_fp_param, "**\$1\\\\(\\\\)**"],
108    [$type_fp_param2, "**\$1\\\\(\\\\)**"],
109    [$type_func, "\$1()"],
110    [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
111    [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
112    [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
113    [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
114
115    # in rst this can refer to any type
116    [$type_fallback, "\\:c\\:type\\:`\$1`"],
117    [$type_param_ref, "**\$1\$2**"]
118  );
119my $blankline_rst = "\n";
120
121# read arguments
122if ($#ARGV == -1) {
123    pod2usage(
124        -message => "No arguments!\n",
125        -exitval => 1,
126        -verbose => 99,
127        -sections => 'SYNOPSIS',
128        -output => \*STDERR,
129      );
130}
131
132my $kernelversion;
133my ($sphinx_major, $sphinx_minor, $sphinx_patch);
134
135my $dohighlight = "";
136
137my $verbose = 0;
138my $Werror = 0;
139my $Wreturn = 0;
140my $Wshort_desc = 0;
141my $Wcontents_before_sections = 0;
142my $output_mode = "rst";
143my $output_preformatted = 0;
144my $no_doc_sections = 0;
145my $enable_lineno = 0;
146my @highlights = @highlights_rst;
147my $blankline = $blankline_rst;
148my $modulename = "Kernel API";
149
150use constant {
151    OUTPUT_ALL          => 0, # output all symbols and doc sections
152    OUTPUT_INCLUDE      => 1, # output only specified symbols
153    OUTPUT_EXPORTED     => 2, # output exported symbols
154    OUTPUT_INTERNAL     => 3, # output non-exported symbols
155};
156my $output_selection = OUTPUT_ALL;
157my $show_not_found = 0;	# No longer used
158
159my @export_file_list;
160
161my @build_time;
162if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
163    (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
164    @build_time = gmtime($seconds);
165} else {
166    @build_time = localtime;
167}
168
169my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
170                'July', 'August', 'September', 'October',
171                'November', 'December')[$build_time[4]] .
172    " " . ($build_time[5]+1900);
173
174# Essentially these are globals.
175# They probably want to be tidied up, made more localised or something.
176# CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
177# could cause "use of undefined value" or other bugs.
178my ($function, %function_table, %parametertypes, $declaration_purpose);
179my %nosymbol_table = ();
180my $declaration_start_line;
181my ($type, $declaration_name, $return_type);
182my ($newsection, $newcontents, $prototype, $brcount, %source_map);
183
184if (defined($ENV{'KBUILD_VERBOSE'}) && $ENV{'KBUILD_VERBOSE'} =~ '1') {
185    $verbose = 1;
186}
187
188if (defined($ENV{'KCFLAGS'})) {
189    my $kcflags = "$ENV{'KCFLAGS'}";
190
191    if ($kcflags =~ /(\s|^)-Werror(\s|$)/) {
192        $Werror = 1;
193    }
194}
195
196# reading this variable is for backwards compat just in case
197# someone was calling it with the variable from outside the
198# kernel's build system
199if (defined($ENV{'KDOC_WERROR'})) {
200    $Werror = "$ENV{'KDOC_WERROR'}";
201}
202# other environment variables are converted to command-line
203# arguments in cmd_checkdoc in the build system
204
205# Generated docbook code is inserted in a template at a point where
206# docbook v3.1 requires a non-zero sequence of RefEntry's; see:
207# https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
208# We keep track of number of generated entries and generate a dummy
209# if needs be to ensure the expanded template can be postprocessed
210# into html.
211my $section_counter = 0;
212
213my $lineprefix="";
214
215# Parser states
216use constant {
217    STATE_NORMAL        => 0,        # normal code
218    STATE_NAME          => 1,        # looking for function name
219    STATE_BODY_MAYBE    => 2,        # body - or maybe more description
220    STATE_BODY          => 3,        # the body of the comment
221    STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
222    STATE_PROTO         => 5,        # scanning prototype
223    STATE_DOCBLOCK      => 6,        # documentation block
224    STATE_INLINE        => 7,        # gathering doc outside main block
225};
226my $state;
227my $in_doc_sect;
228my $leading_space;
229
230# Inline documentation state
231use constant {
232    STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
233    STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
234    STATE_INLINE_TEXT   => 2, # looking for member documentation
235    STATE_INLINE_END    => 3, # done
236    STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
237                              # Spit a warning as it's not
238                              # proper kernel-doc and ignore the rest.
239};
240my $inline_doc_state;
241
242#declaration types: can be
243# 'function', 'struct', 'union', 'enum', 'typedef'
244my $decl_type;
245
246# Name of the kernel-doc identifier for non-DOC markups
247my $identifier;
248
249my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
250my $doc_end = '\*/';
251my $doc_com = '\s*\*\s*';
252my $doc_com_body = '\s*\* ?';
253my $doc_decl = $doc_com . '(\w+)';
254# @params and a strictly limited set of supported section names
255# Specifically:
256#   Match @word:
257#	  @...:
258#         @{section-name}:
259# while trying to not match literal block starts like "example::"
260#
261my $doc_sect = $doc_com .
262    '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:([^:].*)?$';
263my $doc_content = $doc_com_body . '(.*)';
264my $doc_block = $doc_com . 'DOC:\s*(.*)?';
265my $doc_inline_start = '^\s*/\*\*\s*$';
266my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
267my $doc_inline_end = '^\s*\*/\s*$';
268my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
269my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
270my $export_symbol_ns = '^\s*EXPORT_SYMBOL_NS(_GPL)?\s*\(\s*(\w+)\s*,\s*\w+\)\s*;';
271my $function_pointer = qr{([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)};
272my $attribute = qr{__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)}i;
273
274my %parameterdescs;
275my %parameterdesc_start_lines;
276my @parameterlist;
277my %sections;
278my @sectionlist;
279my %section_start_lines;
280my $sectcheck;
281my $struct_actual;
282
283my $contents = "";
284my $new_start_line = 0;
285
286# the canonical section names. see also $doc_sect above.
287my $section_default = "Description";	# default section
288my $section_intro = "Introduction";
289my $section = $section_default;
290my $section_context = "Context";
291my $section_return = "Return";
292
293my $undescribed = "-- undescribed --";
294
295reset_state();
296
297while ($ARGV[0] =~ m/^--?(.*)/) {
298    my $cmd = $1;
299    shift @ARGV;
300    if ($cmd eq "man") {
301        $output_mode = "man";
302        @highlights = @highlights_man;
303        $blankline = $blankline_man;
304    } elsif ($cmd eq "rst") {
305        $output_mode = "rst";
306        @highlights = @highlights_rst;
307        $blankline = $blankline_rst;
308    } elsif ($cmd eq "none") {
309        $output_mode = "none";
310    } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
311        $modulename = shift @ARGV;
312    } elsif ($cmd eq "function") { # to only output specific functions
313        $output_selection = OUTPUT_INCLUDE;
314        $function = shift @ARGV;
315        $function_table{$function} = 1;
316    } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
317        my $symbol = shift @ARGV;
318        $nosymbol_table{$symbol} = 1;
319    } elsif ($cmd eq "export") { # only exported symbols
320        $output_selection = OUTPUT_EXPORTED;
321        %function_table = ();
322    } elsif ($cmd eq "internal") { # only non-exported symbols
323        $output_selection = OUTPUT_INTERNAL;
324        %function_table = ();
325    } elsif ($cmd eq "export-file") {
326        my $file = shift @ARGV;
327        push(@export_file_list, $file);
328    } elsif ($cmd eq "v") {
329        $verbose = 1;
330    } elsif ($cmd eq "Werror") {
331        $Werror = 1;
332    } elsif ($cmd eq "Wreturn") {
333        $Wreturn = 1;
334    } elsif ($cmd eq "Wshort-desc" or $cmd eq "Wshort-description") {
335        $Wshort_desc = 1;
336    } elsif ($cmd eq "Wcontents-before-sections") {
337        $Wcontents_before_sections = 1;
338    } elsif ($cmd eq "Wall") {
339        $Wreturn = 1;
340        $Wshort_desc = 1;
341        $Wcontents_before_sections = 1;
342    } elsif (($cmd eq "h") || ($cmd eq "help")) {
343        pod2usage(-exitval => 0, -verbose => 2);
344    } elsif ($cmd eq 'no-doc-sections') {
345        $no_doc_sections = 1;
346    } elsif ($cmd eq 'enable-lineno') {
347        $enable_lineno = 1;
348    } elsif ($cmd eq 'show-not-found') {
349        $show_not_found = 1;  # A no-op but don't fail
350    } elsif ($cmd eq "sphinx-version") {
351        my $ver_string = shift @ARGV;
352        if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
353            $sphinx_major = $1;
354            if (defined($2)) {
355                $sphinx_minor = substr($2,1);
356            } else {
357                $sphinx_minor = 0;
358            }
359            if (defined($3)) {
360                $sphinx_patch = substr($3,1)
361            } else {
362                $sphinx_patch = 0;
363            }
364        } else {
365            die "Sphinx version should either major.minor or major.minor.patch format\n";
366        }
367    } else {
368        # Unknown argument
369        pod2usage(
370            -message => "Argument unknown!\n",
371            -exitval => 1,
372            -verbose => 99,
373            -sections => 'SYNOPSIS',
374            -output => \*STDERR,
375            );
376    }
377    if ($#ARGV < 0){
378        pod2usage(
379            -message => "FILE argument missing\n",
380            -exitval => 1,
381            -verbose => 99,
382            -sections => 'SYNOPSIS',
383            -output => \*STDERR,
384            );
385    }
386}
387
388# continue execution near EOF;
389
390# The C domain dialect changed on Sphinx 3. So, we need to check the
391# version in order to produce the right tags.
392sub findprog($)
393{
394    foreach(split(/:/, $ENV{PATH})) {
395        return "$_/$_[0]" if(-x "$_/$_[0]");
396    }
397}
398
399sub get_sphinx_version()
400{
401    my $ver;
402
403    my $cmd = "sphinx-build";
404    if (!findprog($cmd)) {
405        my $cmd = "sphinx-build3";
406        if (!findprog($cmd)) {
407            $sphinx_major = 1;
408            $sphinx_minor = 2;
409            $sphinx_patch = 0;
410            printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
411                   $sphinx_major, $sphinx_minor, $sphinx_patch;
412            return;
413        }
414    }
415
416    open IN, "$cmd --version 2>&1 |";
417    while (<IN>) {
418        if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
419            $sphinx_major = $1;
420            $sphinx_minor = $2;
421            $sphinx_patch = $3;
422            last;
423        }
424        # Sphinx 1.2.x uses a different format
425        if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
426            $sphinx_major = $1;
427            $sphinx_minor = $2;
428            $sphinx_patch = $3;
429            last;
430        }
431    }
432    close IN;
433}
434
435# get kernel version from env
436sub get_kernel_version() {
437    my $version = 'unknown kernel version';
438
439    if (defined($ENV{'KERNELVERSION'})) {
440        $version = $ENV{'KERNELVERSION'};
441    }
442    return $version;
443}
444
445#
446sub print_lineno {
447    my $lineno = shift;
448    if ($enable_lineno && defined($lineno)) {
449        print ".. LINENO " . $lineno . "\n";
450    }
451}
452
453sub emit_warning {
454    my $location = shift;
455    my $msg = shift;
456    print STDERR "$location: warning: $msg";
457    ++$warnings;
458}
459##
460# dumps section contents to arrays/hashes intended for that purpose.
461#
462sub dump_section {
463    my $file = shift;
464    my $name = shift;
465    my $contents = join "\n", @_;
466
467    if ($name =~ m/$type_param/) {
468        $name = $1;
469        $parameterdescs{$name} = $contents;
470        $sectcheck = $sectcheck . $name . " ";
471        $parameterdesc_start_lines{$name} = $new_start_line;
472        $new_start_line = 0;
473    } elsif ($name eq "@\.\.\.") {
474        $name = "...";
475        $parameterdescs{$name} = $contents;
476        $sectcheck = $sectcheck . $name . " ";
477        $parameterdesc_start_lines{$name} = $new_start_line;
478        $new_start_line = 0;
479    } else {
480        if (defined($sections{$name}) && ($sections{$name} ne "")) {
481            # Only warn on user specified duplicate section names.
482            if ($name ne $section_default) {
483                emit_warning("${file}:$.", "duplicate section name '$name'\n");
484            }
485            $sections{$name} .= $contents;
486        } else {
487            $sections{$name} = $contents;
488            push @sectionlist, $name;
489            $section_start_lines{$name} = $new_start_line;
490            $new_start_line = 0;
491        }
492    }
493}
494
495##
496# dump DOC: section after checking that it should go out
497#
498sub dump_doc_section {
499    my $file = shift;
500    my $name = shift;
501    my $contents = join "\n", @_;
502
503    if ($no_doc_sections) {
504        return;
505    }
506
507    return if (defined($nosymbol_table{$name}));
508
509    if (($output_selection == OUTPUT_ALL) ||
510        (($output_selection == OUTPUT_INCLUDE) &&
511         defined($function_table{$name})))
512    {
513        dump_section($file, $name, $contents);
514        output_blockhead({'sectionlist' => \@sectionlist,
515                          'sections' => \%sections,
516                          'module' => $modulename,
517                          'content-only' => ($output_selection != OUTPUT_ALL), });
518    }
519}
520
521##
522# output function
523#
524# parameterdescs, a hash.
525#  function => "function name"
526#  parameterlist => @list of parameters
527#  parameterdescs => %parameter descriptions
528#  sectionlist => @list of sections
529#  sections => %section descriptions
530#
531
532sub output_highlight {
533    my $contents = join "\n",@_;
534    my $line;
535
536#   DEBUG
537#   if (!defined $contents) {
538#	use Carp;
539#	confess "output_highlight got called with no args?\n";
540#   }
541
542#   print STDERR "contents b4:$contents\n";
543    eval $dohighlight;
544    die $@ if $@;
545#   print STDERR "contents af:$contents\n";
546
547    foreach $line (split "\n", $contents) {
548        if (! $output_preformatted) {
549            $line =~ s/^\s*//;
550        }
551        if ($line eq ""){
552            if (! $output_preformatted) {
553                print $lineprefix, $blankline;
554            }
555        } else {
556            if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
557                print "\\&$line";
558            } else {
559                print $lineprefix, $line;
560            }
561        }
562        print "\n";
563    }
564}
565
566##
567# output function in man
568sub output_function_man(%) {
569    my %args = %{$_[0]};
570    my ($parameter, $section);
571    my $count;
572
573    print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
574
575    print ".SH NAME\n";
576    print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
577
578    print ".SH SYNOPSIS\n";
579    if ($args{'functiontype'} ne "") {
580        print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
581    } else {
582        print ".B \"" . $args{'function'} . "\n";
583    }
584    $count = 0;
585    my $parenth = "(";
586    my $post = ",";
587    foreach my $parameter (@{$args{'parameterlist'}}) {
588        if ($count == $#{$args{'parameterlist'}}) {
589            $post = ");";
590        }
591        $type = $args{'parametertypes'}{$parameter};
592        if ($type =~ m/$function_pointer/) {
593            # pointer-to-function
594            print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
595        } else {
596            $type =~ s/([^\*])$/$1 /;
597            print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
598        }
599        $count++;
600        $parenth = "";
601    }
602
603    print ".SH ARGUMENTS\n";
604    foreach $parameter (@{$args{'parameterlist'}}) {
605        my $parameter_name = $parameter;
606        $parameter_name =~ s/\[.*//;
607
608        print ".IP \"" . $parameter . "\" 12\n";
609        output_highlight($args{'parameterdescs'}{$parameter_name});
610    }
611    foreach $section (@{$args{'sectionlist'}}) {
612        print ".SH \"", uc $section, "\"\n";
613        output_highlight($args{'sections'}{$section});
614    }
615}
616
617##
618# output enum in man
619sub output_enum_man(%) {
620    my %args = %{$_[0]};
621    my ($parameter, $section);
622    my $count;
623
624    print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
625
626    print ".SH NAME\n";
627    print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
628
629    print ".SH SYNOPSIS\n";
630    print "enum " . $args{'enum'} . " {\n";
631    $count = 0;
632    foreach my $parameter (@{$args{'parameterlist'}}) {
633        print ".br\n.BI \"    $parameter\"\n";
634        if ($count == $#{$args{'parameterlist'}}) {
635            print "\n};\n";
636            last;
637        } else {
638            print ", \n.br\n";
639        }
640        $count++;
641    }
642
643    print ".SH Constants\n";
644    foreach $parameter (@{$args{'parameterlist'}}) {
645        my $parameter_name = $parameter;
646        $parameter_name =~ s/\[.*//;
647
648        print ".IP \"" . $parameter . "\" 12\n";
649        output_highlight($args{'parameterdescs'}{$parameter_name});
650    }
651    foreach $section (@{$args{'sectionlist'}}) {
652        print ".SH \"$section\"\n";
653        output_highlight($args{'sections'}{$section});
654    }
655}
656
657##
658# output struct in man
659sub output_struct_man(%) {
660    my %args = %{$_[0]};
661    my ($parameter, $section);
662
663    print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
664
665    print ".SH NAME\n";
666    print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
667
668    my $declaration = $args{'definition'};
669    $declaration =~ s/\t/  /g;
670    $declaration =~ s/\n/"\n.br\n.BI \"/g;
671    print ".SH SYNOPSIS\n";
672    print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
673    print ".BI \"$declaration\n};\n.br\n\n";
674
675    print ".SH Members\n";
676    foreach $parameter (@{$args{'parameterlist'}}) {
677        ($parameter =~ /^#/) && next;
678
679        my $parameter_name = $parameter;
680        $parameter_name =~ s/\[.*//;
681
682        ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
683        print ".IP \"" . $parameter . "\" 12\n";
684        output_highlight($args{'parameterdescs'}{$parameter_name});
685    }
686    foreach $section (@{$args{'sectionlist'}}) {
687        print ".SH \"$section\"\n";
688        output_highlight($args{'sections'}{$section});
689    }
690}
691
692##
693# output typedef in man
694sub output_typedef_man(%) {
695    my %args = %{$_[0]};
696    my ($parameter, $section);
697
698    print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
699
700    print ".SH NAME\n";
701    print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
702
703    foreach $section (@{$args{'sectionlist'}}) {
704        print ".SH \"$section\"\n";
705        output_highlight($args{'sections'}{$section});
706    }
707}
708
709sub output_blockhead_man(%) {
710    my %args = %{$_[0]};
711    my ($parameter, $section);
712    my $count;
713
714    print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
715
716    foreach $section (@{$args{'sectionlist'}}) {
717        print ".SH \"$section\"\n";
718        output_highlight($args{'sections'}{$section});
719    }
720}
721
722##
723# output in restructured text
724#
725
726#
727# This could use some work; it's used to output the DOC: sections, and
728# starts by putting out the name of the doc section itself, but that tends
729# to duplicate a header already in the template file.
730#
731sub output_blockhead_rst(%) {
732    my %args = %{$_[0]};
733    my ($parameter, $section);
734
735    foreach $section (@{$args{'sectionlist'}}) {
736        next if (defined($nosymbol_table{$section}));
737
738        if ($output_selection != OUTPUT_INCLUDE) {
739            print ".. _$section:\n\n";
740            print "**$section**\n\n";
741        }
742        print_lineno($section_start_lines{$section});
743        output_highlight_rst($args{'sections'}{$section});
744        print "\n";
745    }
746}
747
748#
749# Apply the RST highlights to a sub-block of text.
750#
751sub highlight_block($) {
752    # The dohighlight kludge requires the text be called $contents
753    my $contents = shift;
754    eval $dohighlight;
755    die $@ if $@;
756    return $contents;
757}
758
759#
760# Regexes used only here.
761#
762my $sphinx_literal = '^[^.].*::$';
763my $sphinx_cblock = '^\.\.\ +code-block::';
764
765sub output_highlight_rst {
766    my $input = join "\n",@_;
767    my $output = "";
768    my $line;
769    my $in_literal = 0;
770    my $litprefix;
771    my $block = "";
772
773    foreach $line (split "\n",$input) {
774        #
775        # If we're in a literal block, see if we should drop out
776        # of it.  Otherwise pass the line straight through unmunged.
777        #
778        if ($in_literal) {
779            if (! ($line =~ /^\s*$/)) {
780                #
781                # If this is the first non-blank line in a literal
782                # block we need to figure out what the proper indent is.
783                #
784                if ($litprefix eq "") {
785                    $line =~ /^(\s*)/;
786                    $litprefix = '^' . $1;
787                    $output .= $line . "\n";
788                } elsif (! ($line =~ /$litprefix/)) {
789                    $in_literal = 0;
790                } else {
791                    $output .= $line . "\n";
792                }
793            } else {
794                $output .= $line . "\n";
795            }
796        }
797        #
798        # Not in a literal block (or just dropped out)
799        #
800        if (! $in_literal) {
801            $block .= $line . "\n";
802            if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
803                $in_literal = 1;
804                $litprefix = "";
805                $output .= highlight_block($block);
806                $block = ""
807            }
808        }
809    }
810
811    if ($block) {
812        $output .= highlight_block($block);
813    }
814    foreach $line (split "\n", $output) {
815        print $lineprefix . $line . "\n";
816    }
817}
818
819sub output_function_rst(%) {
820    my %args = %{$_[0]};
821    my ($parameter, $section);
822    my $oldprefix = $lineprefix;
823
824    my $signature = "";
825    if ($args{'functiontype'} ne "") {
826        $signature = $args{'functiontype'} . " " . $args{'function'} . " (";
827    } else {
828        $signature = $args{'function'} . " (";
829    }
830
831    my $count = 0;
832    foreach my $parameter (@{$args{'parameterlist'}}) {
833        if ($count ne 0) {
834            $signature .= ", ";
835        }
836        $count++;
837        $type = $args{'parametertypes'}{$parameter};
838
839        if ($type =~ m/$function_pointer/) {
840            # pointer-to-function
841            $signature .= $1 . $parameter . ") (" . $2 . ")";
842        } else {
843            $signature .= $type;
844        }
845    }
846
847    $signature .= ")";
848
849    if ($sphinx_major < 3) {
850        if ($args{'typedef'}) {
851            print ".. c:type:: ". $args{'function'} . "\n\n";
852            print_lineno($declaration_start_line);
853            print "   **Typedef**: ";
854            $lineprefix = "";
855            output_highlight_rst($args{'purpose'});
856            print "\n\n**Syntax**\n\n";
857            print "  ``$signature``\n\n";
858        } else {
859            print ".. c:function:: $signature\n\n";
860        }
861    } else {
862        if ($args{'typedef'} || $args{'functiontype'} eq "") {
863            print ".. c:macro:: ". $args{'function'} . "\n\n";
864
865            if ($args{'typedef'}) {
866                print_lineno($declaration_start_line);
867                print "   **Typedef**: ";
868                $lineprefix = "";
869                output_highlight_rst($args{'purpose'});
870                print "\n\n**Syntax**\n\n";
871                print "  ``$signature``\n\n";
872            } else {
873                print "``$signature``\n\n";
874            }
875        } else {
876            print ".. c:function:: $signature\n\n";
877        }
878    }
879
880    if (!$args{'typedef'}) {
881        print_lineno($declaration_start_line);
882        $lineprefix = "   ";
883        output_highlight_rst($args{'purpose'});
884        print "\n";
885    }
886
887    #
888    # Put our descriptive text into a container (thus an HTML <div>) to help
889    # set the function prototypes apart.
890    #
891    print ".. container:: kernelindent\n\n";
892    $lineprefix = "  ";
893    print $lineprefix . "**Parameters**\n\n";
894    foreach $parameter (@{$args{'parameterlist'}}) {
895        my $parameter_name = $parameter;
896        $parameter_name =~ s/\[.*//;
897        $type = $args{'parametertypes'}{$parameter};
898
899        if ($type ne "") {
900            print $lineprefix . "``$type``\n";
901        } else {
902            print $lineprefix . "``$parameter``\n";
903        }
904
905        print_lineno($parameterdesc_start_lines{$parameter_name});
906
907        $lineprefix = "    ";
908        if (defined($args{'parameterdescs'}{$parameter_name}) &&
909            $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
910            output_highlight_rst($args{'parameterdescs'}{$parameter_name});
911        } else {
912            print $lineprefix . "*undescribed*\n";
913        }
914        $lineprefix = "  ";
915        print "\n";
916    }
917
918    output_section_rst(@_);
919    $lineprefix = $oldprefix;
920}
921
922sub output_section_rst(%) {
923    my %args = %{$_[0]};
924    my $section;
925    my $oldprefix = $lineprefix;
926
927    foreach $section (@{$args{'sectionlist'}}) {
928        print $lineprefix . "**$section**\n\n";
929        print_lineno($section_start_lines{$section});
930        output_highlight_rst($args{'sections'}{$section});
931        print "\n";
932    }
933    print "\n";
934}
935
936sub output_enum_rst(%) {
937    my %args = %{$_[0]};
938    my ($parameter);
939    my $oldprefix = $lineprefix;
940    my $count;
941    my $outer;
942
943    if ($sphinx_major < 3) {
944        my $name = "enum " . $args{'enum'};
945        print "\n\n.. c:type:: " . $name . "\n\n";
946    } else {
947        my $name = $args{'enum'};
948        print "\n\n.. c:enum:: " . $name . "\n\n";
949    }
950    print_lineno($declaration_start_line);
951    $lineprefix = "  ";
952    output_highlight_rst($args{'purpose'});
953    print "\n";
954
955    print ".. container:: kernelindent\n\n";
956    $outer = $lineprefix . "  ";
957    $lineprefix = $outer . "  ";
958    print $outer . "**Constants**\n\n";
959    foreach $parameter (@{$args{'parameterlist'}}) {
960        print $outer . "``$parameter``\n";
961
962        if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
963            output_highlight_rst($args{'parameterdescs'}{$parameter});
964        } else {
965            print $lineprefix . "*undescribed*\n";
966        }
967        print "\n";
968    }
969    print "\n";
970    $lineprefix = $oldprefix;
971    output_section_rst(@_);
972}
973
974sub output_typedef_rst(%) {
975    my %args = %{$_[0]};
976    my ($parameter);
977    my $oldprefix = $lineprefix;
978    my $name;
979
980    if ($sphinx_major < 3) {
981        $name = "typedef " . $args{'typedef'};
982    } else {
983        $name = $args{'typedef'};
984    }
985    print "\n\n.. c:type:: " . $name . "\n\n";
986    print_lineno($declaration_start_line);
987    $lineprefix = "   ";
988    output_highlight_rst($args{'purpose'});
989    print "\n";
990
991    $lineprefix = $oldprefix;
992    output_section_rst(@_);
993}
994
995sub output_struct_rst(%) {
996    my %args = %{$_[0]};
997    my ($parameter);
998    my $oldprefix = $lineprefix;
999
1000    if ($sphinx_major < 3) {
1001        my $name = $args{'type'} . " " . $args{'struct'};
1002        print "\n\n.. c:type:: " . $name . "\n\n";
1003    } else {
1004        my $name = $args{'struct'};
1005        if ($args{'type'} eq 'union') {
1006            print "\n\n.. c:union:: " . $name . "\n\n";
1007        } else {
1008            print "\n\n.. c:struct:: " . $name . "\n\n";
1009        }
1010    }
1011    print_lineno($declaration_start_line);
1012    $lineprefix = "  ";
1013    output_highlight_rst($args{'purpose'});
1014    print "\n";
1015
1016    print ".. container:: kernelindent\n\n";
1017    print $lineprefix . "**Definition**::\n\n";
1018    my $declaration = $args{'definition'};
1019    $lineprefix = $lineprefix . "  ";
1020    $declaration =~ s/\t/$lineprefix/g;
1021    print $lineprefix . $args{'type'} . " " . $args{'struct'} . " {\n$declaration" . $lineprefix . "};\n\n";
1022
1023    $lineprefix = "  ";
1024    print $lineprefix . "**Members**\n\n";
1025    foreach $parameter (@{$args{'parameterlist'}}) {
1026        ($parameter =~ /^#/) && next;
1027
1028        my $parameter_name = $parameter;
1029        $parameter_name =~ s/\[.*//;
1030
1031        ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1032        $type = $args{'parametertypes'}{$parameter};
1033        print_lineno($parameterdesc_start_lines{$parameter_name});
1034        print $lineprefix . "``" . $parameter . "``\n";
1035        $lineprefix = "    ";
1036        output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1037        $lineprefix = "  ";
1038        print "\n";
1039    }
1040    print "\n";
1041
1042    $lineprefix = $oldprefix;
1043    output_section_rst(@_);
1044}
1045
1046## none mode output functions
1047
1048sub output_function_none(%) {
1049}
1050
1051sub output_enum_none(%) {
1052}
1053
1054sub output_typedef_none(%) {
1055}
1056
1057sub output_struct_none(%) {
1058}
1059
1060sub output_blockhead_none(%) {
1061}
1062
1063##
1064# generic output function for all types (function, struct/union, typedef, enum);
1065# calls the generated, variable output_ function name based on
1066# functype and output_mode
1067sub output_declaration {
1068    no strict 'refs';
1069    my $name = shift;
1070    my $functype = shift;
1071    my $func = "output_${functype}_$output_mode";
1072
1073    return if (defined($nosymbol_table{$name}));
1074
1075    if (($output_selection == OUTPUT_ALL) ||
1076        (($output_selection == OUTPUT_INCLUDE ||
1077          $output_selection == OUTPUT_EXPORTED) &&
1078         defined($function_table{$name})) ||
1079        ($output_selection == OUTPUT_INTERNAL &&
1080         !($functype eq "function" && defined($function_table{$name}))))
1081    {
1082        &$func(@_);
1083        $section_counter++;
1084    }
1085}
1086
1087##
1088# generic output function - calls the right one based on current output mode.
1089sub output_blockhead {
1090    no strict 'refs';
1091    my $func = "output_blockhead_" . $output_mode;
1092    &$func(@_);
1093    $section_counter++;
1094}
1095
1096##
1097# takes a declaration (struct, union, enum, typedef) and
1098# invokes the right handler. NOT called for functions.
1099sub dump_declaration($$) {
1100    no strict 'refs';
1101    my ($prototype, $file) = @_;
1102    my $func = "dump_" . $decl_type;
1103    &$func(@_);
1104}
1105
1106sub dump_union($$) {
1107    dump_struct(@_);
1108}
1109
1110sub dump_struct($$) {
1111    my $x = shift;
1112    my $file = shift;
1113    my $decl_type;
1114    my $members;
1115    my $type = qr{struct|union};
1116    # For capturing struct/union definition body, i.e. "{members*}qualifiers*"
1117    my $qualifiers = qr{$attribute|__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned};
1118    my $definition_body = qr{\{(.*)\}\s*$qualifiers*};
1119    my $struct_members = qr{($type)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;};
1120
1121    if ($x =~ /($type)\s+(\w+)\s*$definition_body/) {
1122        $decl_type = $1;
1123        $declaration_name = $2;
1124        $members = $3;
1125    } elsif ($x =~ /typedef\s+($type)\s*$definition_body\s*(\w+)\s*;/) {
1126        $decl_type = $1;
1127        $declaration_name = $3;
1128        $members = $2;
1129    }
1130
1131    if ($members) {
1132        if ($identifier ne $declaration_name) {
1133            emit_warning("${file}:$.", "expecting prototype for $decl_type $identifier. Prototype was for $decl_type $declaration_name instead\n");
1134            return;
1135        }
1136
1137        # ignore members marked private:
1138        $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1139        $members =~ s/\/\*\s*private:.*//gosi;
1140        # strip comments:
1141        $members =~ s/\/\*.*?\*\///gos;
1142        # strip attributes
1143        $members =~ s/\s*$attribute/ /gi;
1144        $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1145        $members =~ s/\s*__counted_by\s*\([^;]*\)/ /gos;
1146        $members =~ s/\s*__packed\s*/ /gos;
1147        $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1148        $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1149        $members =~ s/\s*____cacheline_aligned/ /gos;
1150        # unwrap struct_group():
1151        # - first eat non-declaration parameters and rewrite for final match
1152        # - then remove macro, outer parens, and trailing semicolon
1153        $members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1154        $members =~ s/\bstruct_group_(attr|tagged)\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1155        $members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1156        $members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1157
1158        my $args = qr{([^,)]+)};
1159        # replace DECLARE_BITMAP
1160        $members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1161        $members =~ s/DECLARE_PHY_INTERFACE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, PHY_INTERFACE_MODE_MAX)/gos;
1162        $members =~ s/DECLARE_BITMAP\s*\($args,\s*$args\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1163        # replace DECLARE_HASHTABLE
1164        $members =~ s/DECLARE_HASHTABLE\s*\($args,\s*$args\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1165        # replace DECLARE_KFIFO
1166        $members =~ s/DECLARE_KFIFO\s*\($args,\s*$args,\s*$args\)/$2 \*$1/gos;
1167        # replace DECLARE_KFIFO_PTR
1168        $members =~ s/DECLARE_KFIFO_PTR\s*\($args,\s*$args\)/$2 \*$1/gos;
1169        # replace DECLARE_FLEX_ARRAY
1170        $members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1171        #replace DEFINE_DMA_UNMAP_ADDR
1172        $members =~ s/DEFINE_DMA_UNMAP_ADDR\s*\($args\)/dma_addr_t $1/gos;
1173        #replace DEFINE_DMA_UNMAP_LEN
1174        $members =~ s/DEFINE_DMA_UNMAP_LEN\s*\($args\)/__u32 $1/gos;
1175        my $declaration = $members;
1176
1177        # Split nested struct/union elements as newer ones
1178        while ($members =~ m/$struct_members/) {
1179            my $newmember;
1180            my $maintype = $1;
1181            my $ids = $4;
1182            my $content = $3;
1183            foreach my $id(split /,/, $ids) {
1184                $newmember .= "$maintype $id; ";
1185
1186                $id =~ s/[:\[].*//;
1187                $id =~ s/^\s*\**(\S+)\s*/$1/;
1188                foreach my $arg (split /;/, $content) {
1189                    next if ($arg =~ m/^\s*$/);
1190                    if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1191                        # pointer-to-function
1192                        my $type = $1;
1193                        my $name = $2;
1194                        my $extra = $3;
1195                        next if (!$name);
1196                        if ($id =~ m/^\s*$/) {
1197                            # anonymous struct/union
1198                            $newmember .= "$type$name$extra; ";
1199                        } else {
1200                            $newmember .= "$type$id.$name$extra; ";
1201                        }
1202                    } else {
1203                        my $type;
1204                        my $names;
1205                        $arg =~ s/^\s+//;
1206                        $arg =~ s/\s+$//;
1207                        # Handle bitmaps
1208                        $arg =~ s/:\s*\d+\s*//g;
1209                        # Handle arrays
1210                        $arg =~ s/\[.*\]//g;
1211                        # The type may have multiple words,
1212                        # and multiple IDs can be defined, like:
1213                        #    const struct foo, *bar, foobar
1214                        # So, we remove spaces when parsing the
1215                        # names, in order to match just names
1216                        # and commas for the names
1217                        $arg =~ s/\s*,\s*/,/g;
1218                        if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1219                            $type = $1;
1220                            $names = $2;
1221                        } else {
1222                            $newmember .= "$arg; ";
1223                            next;
1224                        }
1225                        foreach my $name (split /,/, $names) {
1226                            $name =~ s/^\s*\**(\S+)\s*/$1/;
1227                            next if (($name =~ m/^\s*$/));
1228                            if ($id =~ m/^\s*$/) {
1229                                # anonymous struct/union
1230                                $newmember .= "$type $name; ";
1231                            } else {
1232                                $newmember .= "$type $id.$name; ";
1233                            }
1234                        }
1235                    }
1236                }
1237            }
1238            $members =~ s/$struct_members/$newmember/;
1239        }
1240
1241        # Ignore other nested elements, like enums
1242        $members =~ s/(\{[^\{\}]*\})//g;
1243
1244        create_parameterlist($members, ';', $file, $declaration_name);
1245        check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1246
1247        # Adjust declaration for better display
1248        $declaration =~ s/([\{;])/$1\n/g;
1249        $declaration =~ s/\}\s+;/};/g;
1250        # Better handle inlined enums
1251        do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1252
1253        my @def_args = split /\n/, $declaration;
1254        my $level = 1;
1255        $declaration = "";
1256        foreach my $clause (@def_args) {
1257            $clause =~ s/^\s+//;
1258            $clause =~ s/\s+$//;
1259            $clause =~ s/\s+/ /;
1260            next if (!$clause);
1261            $level-- if ($clause =~ m/(\})/ && $level > 1);
1262            if (!($clause =~ m/^\s*#/)) {
1263                $declaration .= "\t" x $level;
1264            }
1265            $declaration .= "\t" . $clause . "\n";
1266            $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1267        }
1268        output_declaration($declaration_name,
1269                   'struct',
1270                   {'struct' => $declaration_name,
1271                    'module' => $modulename,
1272                    'definition' => $declaration,
1273                    'parameterlist' => \@parameterlist,
1274                    'parameterdescs' => \%parameterdescs,
1275                    'parametertypes' => \%parametertypes,
1276                    'sectionlist' => \@sectionlist,
1277                    'sections' => \%sections,
1278                    'purpose' => $declaration_purpose,
1279                    'type' => $decl_type
1280                   });
1281    } else {
1282        print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1283        ++$errors;
1284    }
1285}
1286
1287
1288sub show_warnings($$) {
1289    my $functype = shift;
1290    my $name = shift;
1291
1292    return 0 if (defined($nosymbol_table{$name}));
1293
1294    return 1 if ($output_selection == OUTPUT_ALL);
1295
1296    if ($output_selection == OUTPUT_EXPORTED) {
1297        if (defined($function_table{$name})) {
1298            return 1;
1299        } else {
1300            return 0;
1301        }
1302    }
1303    if ($output_selection == OUTPUT_INTERNAL) {
1304        if (!($functype eq "function" && defined($function_table{$name}))) {
1305            return 1;
1306        } else {
1307            return 0;
1308        }
1309    }
1310    if ($output_selection == OUTPUT_INCLUDE) {
1311        if (defined($function_table{$name})) {
1312            return 1;
1313        } else {
1314            return 0;
1315        }
1316    }
1317    die("Please add the new output type at show_warnings()");
1318}
1319
1320sub dump_enum($$) {
1321    my $x = shift;
1322    my $file = shift;
1323    my $members;
1324
1325    # ignore members marked private:
1326    $x =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1327    $x =~ s/\/\*\s*private:.*}/}/gosi;
1328
1329    $x =~ s@/\*.*?\*/@@gos;	# strip comments.
1330    # strip #define macros inside enums
1331    $x =~ s@#\s*((define|ifdef|if)\s+|endif)[^;]*;@@gos;
1332
1333    if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1334        $declaration_name = $2;
1335        $members = $1;
1336    } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1337        $declaration_name = $1;
1338        $members = $2;
1339    }
1340
1341    if ($members) {
1342        if ($identifier ne $declaration_name) {
1343            if ($identifier eq "") {
1344                emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n");
1345            } else {
1346                emit_warning("${file}:$.", "expecting prototype for enum $identifier. Prototype was for enum $declaration_name instead\n");
1347            }
1348            return;
1349        }
1350        $declaration_name = "(anonymous)" if ($declaration_name eq "");
1351
1352        my %_members;
1353
1354        $members =~ s/\s+$//;
1355        $members =~ s/\([^;]*?[\)]//g;
1356
1357        foreach my $arg (split ',', $members) {
1358            $arg =~ s/^\s*(\w+).*/$1/;
1359            push @parameterlist, $arg;
1360            if (!$parameterdescs{$arg}) {
1361                $parameterdescs{$arg} = $undescribed;
1362                if (show_warnings("enum", $declaration_name)) {
1363                    emit_warning("${file}:$.", "Enum value '$arg' not described in enum '$declaration_name'\n");
1364                }
1365            }
1366            $_members{$arg} = 1;
1367        }
1368
1369        while (my ($k, $v) = each %parameterdescs) {
1370            if (!exists($_members{$k})) {
1371                if (show_warnings("enum", $declaration_name)) {
1372                    emit_warning("${file}:$.", "Excess enum value '$k' description in '$declaration_name'\n");
1373                }
1374            }
1375        }
1376
1377        output_declaration($declaration_name,
1378                           'enum',
1379                           {'enum' => $declaration_name,
1380                            'module' => $modulename,
1381                            'parameterlist' => \@parameterlist,
1382                            'parameterdescs' => \%parameterdescs,
1383                            'sectionlist' => \@sectionlist,
1384                            'sections' => \%sections,
1385                            'purpose' => $declaration_purpose
1386                           });
1387    } else {
1388        print STDERR "${file}:$.: error: Cannot parse enum!\n";
1389        ++$errors;
1390    }
1391}
1392
1393my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1394my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1395my $typedef_args = qr { \s*\((.*)\); }x;
1396
1397my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1398my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1399
1400sub dump_typedef($$) {
1401    my $x = shift;
1402    my $file = shift;
1403
1404    $x =~ s@/\*.*?\*/@@gos;	# strip comments.
1405
1406    # Parse function typedef prototypes
1407    if ($x =~ $typedef1 || $x =~ $typedef2) {
1408        $return_type = $1;
1409        $declaration_name = $2;
1410        my $args = $3;
1411        $return_type =~ s/^\s+//;
1412
1413        if ($identifier ne $declaration_name) {
1414            emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1415            return;
1416        }
1417
1418        create_parameterlist($args, ',', $file, $declaration_name);
1419
1420        output_declaration($declaration_name,
1421                           'function',
1422                           {'function' => $declaration_name,
1423                            'typedef' => 1,
1424                            'module' => $modulename,
1425                            'functiontype' => $return_type,
1426                            'parameterlist' => \@parameterlist,
1427                            'parameterdescs' => \%parameterdescs,
1428                            'parametertypes' => \%parametertypes,
1429                            'sectionlist' => \@sectionlist,
1430                            'sections' => \%sections,
1431                            'purpose' => $declaration_purpose
1432                           });
1433        return;
1434    }
1435
1436    while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1437        $x =~ s/\(*.\)\s*;$/;/;
1438        $x =~ s/\[*.\]\s*;$/;/;
1439    }
1440
1441    if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1442        $declaration_name = $1;
1443
1444        if ($identifier ne $declaration_name) {
1445            emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1446            return;
1447        }
1448
1449        output_declaration($declaration_name,
1450                           'typedef',
1451                           {'typedef' => $declaration_name,
1452                            'module' => $modulename,
1453                            'sectionlist' => \@sectionlist,
1454                            'sections' => \%sections,
1455                            'purpose' => $declaration_purpose
1456                           });
1457    } else {
1458        print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1459        ++$errors;
1460    }
1461}
1462
1463sub save_struct_actual($) {
1464    my $actual = shift;
1465
1466    # strip all spaces from the actual param so that it looks like one string item
1467    $actual =~ s/\s*//g;
1468    $struct_actual = $struct_actual . $actual . " ";
1469}
1470
1471sub create_parameterlist($$$$) {
1472    my $args = shift;
1473    my $splitter = shift;
1474    my $file = shift;
1475    my $declaration_name = shift;
1476    my $type;
1477    my $param;
1478
1479    # temporarily replace commas inside function pointer definition
1480    my $arg_expr = qr{\([^\),]+};
1481    while ($args =~ /$arg_expr,/) {
1482        $args =~ s/($arg_expr),/$1#/g;
1483    }
1484
1485    foreach my $arg (split($splitter, $args)) {
1486        # strip comments
1487        $arg =~ s/\/\*.*\*\///;
1488        # ignore argument attributes
1489        $arg =~ s/\sPOS0?\s/ /;
1490        # strip leading/trailing spaces
1491        $arg =~ s/^\s*//;
1492        $arg =~ s/\s*$//;
1493        $arg =~ s/\s+/ /;
1494
1495        if ($arg =~ /^#/) {
1496            # Treat preprocessor directive as a typeless variable just to fill
1497            # corresponding data structures "correctly". Catch it later in
1498            # output_* subs.
1499            push_parameter($arg, "", "", $file);
1500        } elsif ($arg =~ m/\(.+\)\s*\(/) {
1501            # pointer-to-function
1502            $arg =~ tr/#/,/;
1503            $arg =~ m/[^\(]+\(\*?\s*([\w\[\]\.]*)\s*\)/;
1504            $param = $1;
1505            $type = $arg;
1506            $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1507            save_struct_actual($param);
1508            push_parameter($param, $type, $arg, $file, $declaration_name);
1509        } elsif ($arg =~ m/\(.+\)\s*\[/) {
1510            # array-of-pointers
1511            $arg =~ tr/#/,/;
1512            $arg =~ m/[^\(]+\(\s*\*\s*([\w\[\]\.]*?)\s*(\s*\[\s*[\w]+\s*\]\s*)*\)/;
1513            $param = $1;
1514            $type = $arg;
1515            $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1516            save_struct_actual($param);
1517            push_parameter($param, $type, $arg, $file, $declaration_name);
1518        } elsif ($arg) {
1519            $arg =~ s/\s*:\s*/:/g;
1520            $arg =~ s/\s*\[/\[/g;
1521
1522            my @args = split('\s*,\s*', $arg);
1523            if ($args[0] =~ m/\*/) {
1524                $args[0] =~ s/(\*+)\s*/ $1/;
1525            }
1526
1527            my @first_arg;
1528            if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1529                shift @args;
1530                push(@first_arg, split('\s+', $1));
1531                push(@first_arg, $2);
1532            } else {
1533                @first_arg = split('\s+', shift @args);
1534            }
1535
1536            unshift(@args, pop @first_arg);
1537            $type = join " ", @first_arg;
1538
1539            foreach $param (@args) {
1540                if ($param =~ m/^(\*+)\s*(.*)/) {
1541                    save_struct_actual($2);
1542
1543                    push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1544                } elsif ($param =~ m/(.*?):(\d+)/) {
1545                    if ($type ne "") { # skip unnamed bit-fields
1546                        save_struct_actual($1);
1547                        push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1548                    }
1549                } else {
1550                    save_struct_actual($param);
1551                    push_parameter($param, $type, $arg, $file, $declaration_name);
1552                }
1553            }
1554        }
1555    }
1556}
1557
1558sub push_parameter($$$$$) {
1559    my $param = shift;
1560    my $type = shift;
1561    my $org_arg = shift;
1562    my $file = shift;
1563    my $declaration_name = shift;
1564
1565    if (($anon_struct_union == 1) && ($type eq "") &&
1566        ($param eq "}")) {
1567        return;        # ignore the ending }; from anon. struct/union
1568    }
1569
1570    $anon_struct_union = 0;
1571    $param =~ s/[\[\)].*//;
1572
1573    if ($type eq "" && $param =~ /\.\.\.$/)
1574    {
1575        if (!$param =~ /\w\.\.\.$/) {
1576            # handles unnamed variable parameters
1577            $param = "...";
1578        } elsif ($param =~ /\w\.\.\.$/) {
1579            # for named variable parameters of the form `x...`, remove the dots
1580            $param =~ s/\.\.\.$//;
1581        }
1582        if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1583            $parameterdescs{$param} = "variable arguments";
1584        }
1585    }
1586    elsif ($type eq "" && ($param eq "" or $param eq "void"))
1587    {
1588        $param="void";
1589        $parameterdescs{void} = "no arguments";
1590    }
1591    elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1592    # handle unnamed (anonymous) union or struct:
1593    {
1594        $type = $param;
1595        $param = "{unnamed_" . $param . "}";
1596        $parameterdescs{$param} = "anonymous\n";
1597        $anon_struct_union = 1;
1598    }
1599    elsif ($param =~ "__cacheline_group" )
1600    # handle cache group enforcing variables: they do not need be described in header files
1601    {
1602        return; # ignore __cacheline_group_begin and __cacheline_group_end
1603    }
1604
1605    # warn if parameter has no description
1606    # (but ignore ones starting with # as these are not parameters
1607    # but inline preprocessor statements);
1608    # Note: It will also ignore void params and unnamed structs/unions
1609    if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1610        $parameterdescs{$param} = $undescribed;
1611
1612        if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1613            emit_warning("${file}:$.", "Function parameter or struct member '$param' not described in '$declaration_name'\n");
1614        }
1615    }
1616
1617    # strip spaces from $param so that it is one continuous string
1618    # on @parameterlist;
1619    # this fixes a problem where check_sections() cannot find
1620    # a parameter like "addr[6 + 2]" because it actually appears
1621    # as "addr[6", "+", "2]" on the parameter list;
1622    # but it's better to maintain the param string unchanged for output,
1623    # so just weaken the string compare in check_sections() to ignore
1624    # "[blah" in a parameter string;
1625    ###$param =~ s/\s*//g;
1626    push @parameterlist, $param;
1627    $org_arg =~ s/\s\s+/ /g;
1628    $parametertypes{$param} = $org_arg;
1629}
1630
1631sub check_sections($$$$$) {
1632    my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1633    my @sects = split ' ', $sectcheck;
1634    my @prms = split ' ', $prmscheck;
1635    my $err;
1636    my ($px, $sx);
1637    my $prm_clean;        # strip trailing "[array size]" and/or beginning "*"
1638
1639    foreach $sx (0 .. $#sects) {
1640        $err = 1;
1641        foreach $px (0 .. $#prms) {
1642            $prm_clean = $prms[$px];
1643            $prm_clean =~ s/\[.*\]//;
1644            $prm_clean =~ s/$attribute//i;
1645            # ignore array size in a parameter string;
1646            # however, the original param string may contain
1647            # spaces, e.g.:  addr[6 + 2]
1648            # and this appears in @prms as "addr[6" since the
1649            # parameter list is split at spaces;
1650            # hence just ignore "[..." for the sections check;
1651            $prm_clean =~ s/\[.*//;
1652
1653            ##$prm_clean =~ s/^\**//;
1654            if ($prm_clean eq $sects[$sx]) {
1655                $err = 0;
1656                last;
1657            }
1658        }
1659        if ($err) {
1660            if ($decl_type eq "function") {
1661                emit_warning("${file}:$.",
1662                    "Excess function parameter " .
1663                    "'$sects[$sx]' " .
1664                    "description in '$decl_name'\n");
1665            } elsif (($decl_type eq "struct") or
1666                          ($decl_type eq "union")) {
1667                emit_warning("${file}:$.",
1668                    "Excess $decl_type member " .
1669                    "'$sects[$sx]' " .
1670                    "description in '$decl_name'\n");
1671            }
1672        }
1673    }
1674}
1675
1676##
1677# Checks the section describing the return value of a function.
1678sub check_return_section {
1679    my $file = shift;
1680    my $declaration_name = shift;
1681    my $return_type = shift;
1682
1683    # Ignore an empty return type (It's a macro)
1684    # Ignore functions with a "void" return type. (But don't ignore "void *")
1685    if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1686        return;
1687    }
1688
1689    if (!defined($sections{$section_return}) ||
1690        $sections{$section_return} eq "")
1691    {
1692        emit_warning("${file}:$.",
1693                     "No description found for return value of " .
1694                     "'$declaration_name'\n");
1695    }
1696}
1697
1698##
1699# takes a function prototype and the name of the current file being
1700# processed and spits out all the details stored in the global
1701# arrays/hashes.
1702sub dump_function($$) {
1703    my $prototype = shift;
1704    my $file = shift;
1705    my $noret = 0;
1706
1707    print_lineno($new_start_line);
1708
1709    $prototype =~ s/^static +//;
1710    $prototype =~ s/^extern +//;
1711    $prototype =~ s/^asmlinkage +//;
1712    $prototype =~ s/^inline +//;
1713    $prototype =~ s/^__inline__ +//;
1714    $prototype =~ s/^__inline +//;
1715    $prototype =~ s/^__always_inline +//;
1716    $prototype =~ s/^noinline +//;
1717    $prototype =~ s/^__FORTIFY_INLINE +//;
1718    $prototype =~ s/__init +//;
1719    $prototype =~ s/__init_or_module +//;
1720    $prototype =~ s/__deprecated +//;
1721    $prototype =~ s/__flatten +//;
1722    $prototype =~ s/__meminit +//;
1723    $prototype =~ s/__must_check +//;
1724    $prototype =~ s/__weak +//;
1725    $prototype =~ s/__sched +//;
1726    $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1727    $prototype =~ s/__(?:re)?alloc_size\s*\(\s*\d+\s*(?:,\s*\d+\s*)?\) +//;
1728    $prototype =~ s/__diagnose_as\s*\(\s*\S+\s*(?:,\s*\d+\s*)*\) +//;
1729    my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1730    $prototype =~ s/__attribute_const__ +//;
1731    $prototype =~ s/__attribute__\s*\(\(
1732            (?:
1733                 [\w\s]++          # attribute name
1734                 (?:\([^)]*+\))?   # attribute arguments
1735                 \s*+,?            # optional comma at the end
1736            )+
1737          \)\)\s+//x;
1738
1739    # Yes, this truly is vile.  We are looking for:
1740    # 1. Return type (may be nothing if we're looking at a macro)
1741    # 2. Function name
1742    # 3. Function parameters.
1743    #
1744    # All the while we have to watch out for function pointer parameters
1745    # (which IIRC is what the two sections are for), C types (these
1746    # regexps don't even start to express all the possibilities), and
1747    # so on.
1748    #
1749    # If you mess with these regexps, it's a good idea to check that
1750    # the following functions' documentation still comes out right:
1751    # - parport_register_device (function pointer parameters)
1752    # - atomic_set (macro)
1753    # - pci_match_device, __copy_to_user (long return type)
1754    my $name = qr{[a-zA-Z0-9_~:]+};
1755    my $prototype_end1 = qr{[^\(]*};
1756    my $prototype_end2 = qr{[^\{]*};
1757    my $prototype_end = qr{\(($prototype_end1|$prototype_end2)\)};
1758    my $type1 = qr{[\w\s]+};
1759    my $type2 = qr{$type1\*+};
1760
1761    if ($define && $prototype =~ m/^()($name)\s+/) {
1762        # This is an object-like macro, it has no return type and no parameter
1763        # list.
1764        # Function-like macros are not allowed to have spaces between
1765        # declaration_name and opening parenthesis (notice the \s+).
1766        $return_type = $1;
1767        $declaration_name = $2;
1768        $noret = 1;
1769    } elsif ($prototype =~ m/^()($name)\s*$prototype_end/ ||
1770        $prototype =~ m/^($type1)\s+($name)\s*$prototype_end/ ||
1771        $prototype =~ m/^($type2+)\s*($name)\s*$prototype_end/)  {
1772        $return_type = $1;
1773        $declaration_name = $2;
1774        my $args = $3;
1775
1776        create_parameterlist($args, ',', $file, $declaration_name);
1777    } else {
1778        emit_warning("${file}:$.", "cannot understand function prototype: '$prototype'\n");
1779        return;
1780    }
1781
1782    if ($identifier ne $declaration_name) {
1783        emit_warning("${file}:$.", "expecting prototype for $identifier(). Prototype was for $declaration_name() instead\n");
1784        return;
1785    }
1786
1787    my $prms = join " ", @parameterlist;
1788    check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1789
1790    # This check emits a lot of warnings at the moment, because many
1791    # functions don't have a 'Return' doc section. So until the number
1792    # of warnings goes sufficiently down, the check is only performed in
1793    # -Wreturn mode.
1794    # TODO: always perform the check.
1795    if ($Wreturn && !$noret) {
1796        check_return_section($file, $declaration_name, $return_type);
1797    }
1798
1799    # The function parser can be called with a typedef parameter.
1800    # Handle it.
1801    if ($return_type =~ /typedef/) {
1802        output_declaration($declaration_name,
1803                           'function',
1804                           {'function' => $declaration_name,
1805                            'typedef' => 1,
1806                            'module' => $modulename,
1807                            'functiontype' => $return_type,
1808                            'parameterlist' => \@parameterlist,
1809                            'parameterdescs' => \%parameterdescs,
1810                            'parametertypes' => \%parametertypes,
1811                            'sectionlist' => \@sectionlist,
1812                            'sections' => \%sections,
1813                            'purpose' => $declaration_purpose
1814                           });
1815    } else {
1816        output_declaration($declaration_name,
1817                           'function',
1818                           {'function' => $declaration_name,
1819                            'module' => $modulename,
1820                            'functiontype' => $return_type,
1821                            'parameterlist' => \@parameterlist,
1822                            'parameterdescs' => \%parameterdescs,
1823                            'parametertypes' => \%parametertypes,
1824                            'sectionlist' => \@sectionlist,
1825                            'sections' => \%sections,
1826                            'purpose' => $declaration_purpose
1827                           });
1828    }
1829}
1830
1831sub reset_state {
1832    $function = "";
1833    %parameterdescs = ();
1834    %parametertypes = ();
1835    @parameterlist = ();
1836    %sections = ();
1837    @sectionlist = ();
1838    $sectcheck = "";
1839    $struct_actual = "";
1840    $prototype = "";
1841
1842    $state = STATE_NORMAL;
1843    $inline_doc_state = STATE_INLINE_NA;
1844}
1845
1846sub tracepoint_munge($) {
1847    my $file = shift;
1848    my $tracepointname = 0;
1849    my $tracepointargs = 0;
1850
1851    if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1852        $tracepointname = $1;
1853    }
1854    if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1855        $tracepointname = $1;
1856    }
1857    if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1858        $tracepointname = $2;
1859    }
1860    $tracepointname =~ s/^\s+//; #strip leading whitespace
1861    if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1862        $tracepointargs = $1;
1863    }
1864    if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1865        emit_warning("${file}:$.", "Unrecognized tracepoint format: \n".
1866                 "$prototype\n");
1867    } else {
1868        $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1869        $identifier = "trace_$identifier";
1870    }
1871}
1872
1873sub syscall_munge() {
1874    my $void = 0;
1875
1876    $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1877##    if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1878    if ($prototype =~ m/SYSCALL_DEFINE0/) {
1879        $void = 1;
1880##        $prototype = "long sys_$1(void)";
1881    }
1882
1883    $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1884    if ($prototype =~ m/long (sys_.*?),/) {
1885        $prototype =~ s/,/\(/;
1886    } elsif ($void) {
1887        $prototype =~ s/\)/\(void\)/;
1888    }
1889
1890    # now delete all of the odd-number commas in $prototype
1891    # so that arg types & arg names don't have a comma between them
1892    my $count = 0;
1893    my $len = length($prototype);
1894    if ($void) {
1895        $len = 0;    # skip the for-loop
1896    }
1897    for (my $ix = 0; $ix < $len; $ix++) {
1898        if (substr($prototype, $ix, 1) eq ',') {
1899            $count++;
1900            if ($count % 2 == 1) {
1901                substr($prototype, $ix, 1) = ' ';
1902            }
1903        }
1904    }
1905}
1906
1907sub process_proto_function($$) {
1908    my $x = shift;
1909    my $file = shift;
1910
1911    $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1912
1913    if ($x =~ /^#/ && $x !~ /^#\s*define/) {
1914        # do nothing
1915    } elsif ($x =~ /([^\{]*)/) {
1916        $prototype .= $1;
1917    }
1918
1919    if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1920        $prototype =~ s@/\*.*?\*/@@gos;        # strip comments.
1921        $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1922        $prototype =~ s@^\s+@@gos; # strip leading spaces
1923
1924        # Handle prototypes for function pointers like:
1925        # int (*pcs_config)(struct foo)
1926        $prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
1927
1928        if ($prototype =~ /SYSCALL_DEFINE/) {
1929            syscall_munge();
1930        }
1931        if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1932            $prototype =~ /DEFINE_SINGLE_EVENT/)
1933        {
1934            tracepoint_munge($file);
1935        }
1936        dump_function($prototype, $file);
1937        reset_state();
1938    }
1939}
1940
1941sub process_proto_type($$) {
1942    my $x = shift;
1943    my $file = shift;
1944
1945    $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1946    $x =~ s@^\s+@@gos; # strip leading spaces
1947    $x =~ s@\s+$@@gos; # strip trailing spaces
1948    $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1949
1950    if ($x =~ /^#/) {
1951        # To distinguish preprocessor directive from regular declaration later.
1952        $x .= ";";
1953    }
1954
1955    while (1) {
1956        if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1957            if( length $prototype ) {
1958                $prototype .= " "
1959            }
1960            $prototype .= $1 . $2;
1961            ($2 eq '{') && $brcount++;
1962            ($2 eq '}') && $brcount--;
1963            if (($2 eq ';') && ($brcount == 0)) {
1964                dump_declaration($prototype, $file);
1965                reset_state();
1966                last;
1967            }
1968            $x = $3;
1969        } else {
1970            $prototype .= $x;
1971            last;
1972        }
1973    }
1974}
1975
1976
1977sub map_filename($) {
1978    my $file;
1979    my ($orig_file) = @_;
1980
1981    if (defined($ENV{'SRCTREE'})) {
1982        $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1983    } else {
1984        $file = $orig_file;
1985    }
1986
1987    if (defined($source_map{$file})) {
1988        $file = $source_map{$file};
1989    }
1990
1991    return $file;
1992}
1993
1994sub process_export_file($) {
1995    my ($orig_file) = @_;
1996    my $file = map_filename($orig_file);
1997
1998    if (!open(IN,"<$file")) {
1999        print STDERR "Error: Cannot open file $file\n";
2000        ++$errors;
2001        return;
2002    }
2003
2004    while (<IN>) {
2005        if (/$export_symbol/) {
2006            next if (defined($nosymbol_table{$2}));
2007            $function_table{$2} = 1;
2008        }
2009        if (/$export_symbol_ns/) {
2010            next if (defined($nosymbol_table{$2}));
2011            $function_table{$2} = 1;
2012        }
2013    }
2014
2015    close(IN);
2016}
2017
2018#
2019# Parsers for the various processing states.
2020#
2021# STATE_NORMAL: looking for the /** to begin everything.
2022#
2023sub process_normal() {
2024    if (/$doc_start/o) {
2025        $state = STATE_NAME;        # next line is always the function name
2026        $in_doc_sect = 0;
2027        $declaration_start_line = $. + 1;
2028    }
2029}
2030
2031#
2032# STATE_NAME: Looking for the "name - description" line
2033#
2034sub process_name($$) {
2035    my $file = shift;
2036    my $descr;
2037
2038    if (/$doc_block/o) {
2039        $state = STATE_DOCBLOCK;
2040        $contents = "";
2041        $new_start_line = $.;
2042
2043        if ( $1 eq "" ) {
2044            $section = $section_intro;
2045        } else {
2046            $section = $1;
2047        }
2048    } elsif (/$doc_decl/o) {
2049        $identifier = $1;
2050        my $is_kernel_comment = 0;
2051        my $decl_start = qr{$doc_com};
2052        # test for pointer declaration type, foo * bar() - desc
2053        my $fn_type = qr{\w+\s*\*\s*};
2054        my $parenthesis = qr{\(\w*\)};
2055        my $decl_end = qr{[-:].*};
2056        if (/^$decl_start([\w\s]+?)$parenthesis?\s*$decl_end?$/) {
2057            $identifier = $1;
2058        }
2059        if ($identifier =~ m/^(struct|union|enum|typedef)\b\s*(\S*)/) {
2060            $decl_type = $1;
2061            $identifier = $2;
2062            $is_kernel_comment = 1;
2063        }
2064        # Look for foo() or static void foo() - description; or misspelt
2065        # identifier
2066        elsif (/^$decl_start$fn_type?(\w+)\s*$parenthesis?\s*$decl_end?$/ ||
2067            /^$decl_start$fn_type?(\w+.*)$parenthesis?\s*$decl_end$/) {
2068            $identifier = $1;
2069            $decl_type = 'function';
2070            $identifier =~ s/^define\s+//;
2071            $is_kernel_comment = 1;
2072        }
2073        $identifier =~ s/\s+$//;
2074
2075        $state = STATE_BODY;
2076        # if there's no @param blocks need to set up default section
2077        # here
2078        $contents = "";
2079        $section = $section_default;
2080        $new_start_line = $. + 1;
2081        if (/[-:](.*)/) {
2082            # strip leading/trailing/multiple spaces
2083            $descr= $1;
2084            $descr =~ s/^\s*//;
2085            $descr =~ s/\s*$//;
2086            $descr =~ s/\s+/ /g;
2087            $declaration_purpose = $descr;
2088            $state = STATE_BODY_MAYBE;
2089        } else {
2090            $declaration_purpose = "";
2091        }
2092
2093        if (!$is_kernel_comment) {
2094            emit_warning("${file}:$.", "This comment starts with '/**', but isn't a kernel-doc comment. Refer Documentation/doc-guide/kernel-doc.rst\n$_");
2095            $state = STATE_NORMAL;
2096        }
2097
2098        if (($declaration_purpose eq "") && $Wshort_desc) {
2099            emit_warning("${file}:$.", "missing initial short description on line:\n$_");
2100        }
2101
2102        if ($identifier eq "" && $decl_type ne "enum") {
2103            emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n$_");
2104            $state = STATE_NORMAL;
2105        }
2106
2107        if ($verbose) {
2108            print STDERR "${file}:$.: info: Scanning doc for $decl_type $identifier\n";
2109        }
2110    } else {
2111        emit_warning("${file}:$.", "Cannot understand $_ on line $. - I thought it was a doc line\n");
2112        $state = STATE_NORMAL;
2113    }
2114}
2115
2116
2117#
2118# STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2119#
2120sub process_body($$) {
2121    my $file = shift;
2122
2123    if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2124        dump_section($file, $section, $contents);
2125        $section = $section_default;
2126        $new_start_line = $.;
2127        $contents = "";
2128    }
2129
2130    if (/$doc_sect/i) { # case insensitive for supported section names
2131        $in_doc_sect = 1;
2132        $newsection = $1;
2133        $newcontents = $2;
2134
2135        # map the supported section names to the canonical names
2136        if ($newsection =~ m/^description$/i) {
2137            $newsection = $section_default;
2138        } elsif ($newsection =~ m/^context$/i) {
2139            $newsection = $section_context;
2140        } elsif ($newsection =~ m/^returns?$/i) {
2141            $newsection = $section_return;
2142        } elsif ($newsection =~ m/^\@return$/) {
2143            # special: @return is a section, not a param description
2144            $newsection = $section_return;
2145        }
2146
2147        if (($contents ne "") && ($contents ne "\n")) {
2148            if (!$in_doc_sect && $Wcontents_before_sections) {
2149                emit_warning("${file}:$.", "contents before sections\n");
2150            }
2151            dump_section($file, $section, $contents);
2152            $section = $section_default;
2153        }
2154
2155        $in_doc_sect = 1;
2156        $state = STATE_BODY;
2157        $contents = $newcontents;
2158        $new_start_line = $.;
2159        while (substr($contents, 0, 1) eq " ") {
2160            $contents = substr($contents, 1);
2161        }
2162        if ($contents ne "") {
2163            $contents .= "\n";
2164        }
2165        $section = $newsection;
2166        $leading_space = undef;
2167    } elsif (/$doc_end/) {
2168        if (($contents ne "") && ($contents ne "\n")) {
2169            dump_section($file, $section, $contents);
2170            $section = $section_default;
2171            $contents = "";
2172        }
2173        # look for doc_com + <text> + doc_end:
2174        if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2175            emit_warning("${file}:$.", "suspicious ending line: $_");
2176        }
2177
2178        $prototype = "";
2179        $state = STATE_PROTO;
2180        $brcount = 0;
2181        $new_start_line = $. + 1;
2182    } elsif (/$doc_content/) {
2183        if ($1 eq "") {
2184            if ($section eq $section_context) {
2185                dump_section($file, $section, $contents);
2186                $section = $section_default;
2187                $contents = "";
2188                $new_start_line = $.;
2189                $state = STATE_BODY;
2190            } else {
2191                if ($section ne $section_default) {
2192                    $state = STATE_BODY_WITH_BLANK_LINE;
2193                } else {
2194                    $state = STATE_BODY;
2195                }
2196                $contents .= "\n";
2197            }
2198        } elsif ($state == STATE_BODY_MAYBE) {
2199            # Continued declaration purpose
2200            chomp($declaration_purpose);
2201            $declaration_purpose .= " " . $1;
2202            $declaration_purpose =~ s/\s+/ /g;
2203        } else {
2204            my $cont = $1;
2205            if ($section =~ m/^@/ || $section eq $section_context) {
2206                if (!defined $leading_space) {
2207                    if ($cont =~ m/^(\s+)/) {
2208                        $leading_space = $1;
2209                    } else {
2210                        $leading_space = "";
2211                    }
2212                }
2213                $cont =~ s/^$leading_space//;
2214            }
2215            $contents .= $cont . "\n";
2216        }
2217    } else {
2218        # i dont know - bad line?  ignore.
2219        emit_warning("${file}:$.", "bad line: $_");
2220    }
2221}
2222
2223
2224#
2225# STATE_PROTO: reading a function/whatever prototype.
2226#
2227sub process_proto($$) {
2228    my $file = shift;
2229
2230    if (/$doc_inline_oneline/) {
2231        $section = $1;
2232        $contents = $2;
2233        if ($contents ne "") {
2234            $contents .= "\n";
2235            dump_section($file, $section, $contents);
2236            $section = $section_default;
2237            $contents = "";
2238        }
2239    } elsif (/$doc_inline_start/) {
2240        $state = STATE_INLINE;
2241        $inline_doc_state = STATE_INLINE_NAME;
2242    } elsif ($decl_type eq 'function') {
2243        process_proto_function($_, $file);
2244    } else {
2245        process_proto_type($_, $file);
2246    }
2247}
2248
2249#
2250# STATE_DOCBLOCK: within a DOC: block.
2251#
2252sub process_docblock($$) {
2253    my $file = shift;
2254
2255    if (/$doc_end/) {
2256        dump_doc_section($file, $section, $contents);
2257        $section = $section_default;
2258        $contents = "";
2259        $function = "";
2260        %parameterdescs = ();
2261        %parametertypes = ();
2262        @parameterlist = ();
2263        %sections = ();
2264        @sectionlist = ();
2265        $prototype = "";
2266        $state = STATE_NORMAL;
2267    } elsif (/$doc_content/) {
2268        if ( $1 eq "" )        {
2269            $contents .= $blankline;
2270        } else {
2271            $contents .= $1 . "\n";
2272        }
2273    }
2274}
2275
2276#
2277# STATE_INLINE: docbook comments within a prototype.
2278#
2279sub process_inline($$) {
2280    my $file = shift;
2281
2282    # First line (state 1) needs to be a @parameter
2283    if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2284        $section = $1;
2285        $contents = $2;
2286        $new_start_line = $.;
2287        if ($contents ne "") {
2288            while (substr($contents, 0, 1) eq " ") {
2289                $contents = substr($contents, 1);
2290            }
2291            $contents .= "\n";
2292        }
2293        $inline_doc_state = STATE_INLINE_TEXT;
2294        # Documentation block end */
2295    } elsif (/$doc_inline_end/) {
2296        if (($contents ne "") && ($contents ne "\n")) {
2297            dump_section($file, $section, $contents);
2298            $section = $section_default;
2299            $contents = "";
2300        }
2301        $state = STATE_PROTO;
2302        $inline_doc_state = STATE_INLINE_NA;
2303        # Regular text
2304    } elsif (/$doc_content/) {
2305        if ($inline_doc_state == STATE_INLINE_TEXT) {
2306            $contents .= $1 . "\n";
2307            # nuke leading blank lines
2308            if ($contents =~ /^\s*$/) {
2309                $contents = "";
2310            }
2311        } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2312            $inline_doc_state = STATE_INLINE_ERROR;
2313            emit_warning("${file}:$.", "Incorrect use of kernel-doc format: $_");
2314        }
2315    }
2316}
2317
2318
2319sub process_file($) {
2320    my $file;
2321    my $initial_section_counter = $section_counter;
2322    my ($orig_file) = @_;
2323
2324    $file = map_filename($orig_file);
2325
2326    if (!open(IN_FILE,"<$file")) {
2327        print STDERR "Error: Cannot open file $file\n";
2328        ++$errors;
2329        return;
2330    }
2331
2332    $. = 1;
2333
2334    $section_counter = 0;
2335    while (<IN_FILE>) {
2336        while (!/^ \*/ && s/\\\s*$//) {
2337            $_ .= <IN_FILE>;
2338        }
2339        # Replace tabs by spaces
2340        while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2341        # Hand this line to the appropriate state handler
2342        if ($state == STATE_NORMAL) {
2343            process_normal();
2344        } elsif ($state == STATE_NAME) {
2345            process_name($file, $_);
2346        } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2347                 $state == STATE_BODY_WITH_BLANK_LINE) {
2348            process_body($file, $_);
2349        } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2350            process_inline($file, $_);
2351        } elsif ($state == STATE_PROTO) {
2352            process_proto($file, $_);
2353        } elsif ($state == STATE_DOCBLOCK) {
2354            process_docblock($file, $_);
2355        }
2356    }
2357
2358    # Make sure we got something interesting.
2359    if ($initial_section_counter == $section_counter && $
2360        output_mode ne "none") {
2361        if ($output_selection == OUTPUT_INCLUDE) {
2362            emit_warning("${file}:1", "'$_' not found\n")
2363                for keys %function_table;
2364        } else {
2365            emit_warning("${file}:1", "no structured comments found\n");
2366        }
2367    }
2368    close IN_FILE;
2369}
2370
2371
2372if ($output_mode eq "rst") {
2373    get_sphinx_version() if (!$sphinx_major);
2374}
2375
2376$kernelversion = get_kernel_version();
2377
2378# generate a sequence of code that will splice in highlighting information
2379# using the s// operator.
2380for (my $k = 0; $k < @highlights; $k++) {
2381    my $pattern = $highlights[$k][0];
2382    my $result = $highlights[$k][1];
2383#   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2384    $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2385}
2386
2387# Read the file that maps relative names to absolute names for
2388# separate source and object directories and for shadow trees.
2389if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2390    my ($relname, $absname);
2391    while(<SOURCE_MAP>) {
2392        chop();
2393        ($relname, $absname) = (split())[0..1];
2394        $relname =~ s:^/+::;
2395        $source_map{$relname} = $absname;
2396    }
2397    close(SOURCE_MAP);
2398}
2399
2400if ($output_selection == OUTPUT_EXPORTED ||
2401    $output_selection == OUTPUT_INTERNAL) {
2402
2403    push(@export_file_list, @ARGV);
2404
2405    foreach (@export_file_list) {
2406        chomp;
2407        process_export_file($_);
2408    }
2409}
2410
2411foreach (@ARGV) {
2412    chomp;
2413    process_file($_);
2414}
2415if ($verbose && $errors) {
2416    print STDERR "$errors errors\n";
2417}
2418if ($verbose && $warnings) {
2419    print STDERR "$warnings warnings\n";
2420}
2421
2422if ($Werror && $warnings) {
2423    print STDERR "$warnings warnings as Errors\n";
2424    exit($warnings);
2425} else {
2426    exit($output_mode eq "none" ? 0 : $errors)
2427}
2428
2429__END__
2430
2431=head1 OPTIONS
2432
2433=head2 Output format selection (mutually exclusive):
2434
2435=over 8
2436
2437=item -man
2438
2439Output troff manual page format.
2440
2441=item -rst
2442
2443Output reStructuredText format. This is the default.
2444
2445=item -none
2446
2447Do not output documentation, only warnings.
2448
2449=back
2450
2451=head2 Output format modifiers
2452
2453=head3 reStructuredText only
2454
2455=over 8
2456
2457=item -sphinx-version VERSION
2458
2459Use the ReST C domain dialect compatible with a specific Sphinx Version.
2460
2461If not specified, kernel-doc will auto-detect using the sphinx-build version
2462found on PATH.
2463
2464=back
2465
2466=head2 Output selection (mutually exclusive):
2467
2468=over 8
2469
2470=item -export
2471
2472Only output documentation for the symbols that have been exported using
2473EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2474
2475=item -internal
2476
2477Only output documentation for the symbols that have NOT been exported using
2478EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2479
2480=item -function NAME
2481
2482Only output documentation for the given function or DOC: section title.
2483All other functions and DOC: sections are ignored.
2484
2485May be specified multiple times.
2486
2487=item -nosymbol NAME
2488
2489Exclude the specified symbol from the output documentation.
2490
2491May be specified multiple times.
2492
2493=back
2494
2495=head2 Output selection modifiers:
2496
2497=over 8
2498
2499=item -no-doc-sections
2500
2501Do not output DOC: sections.
2502
2503=item -export-file FILE
2504
2505Specify an additional FILE in which to look for EXPORT_SYMBOL information.
2506
2507To be used with -export or -internal.
2508
2509May be specified multiple times.
2510
2511=back
2512
2513=head3 reStructuredText only
2514
2515=over 8
2516
2517=item -enable-lineno
2518
2519Enable output of .. LINENO lines.
2520
2521=back
2522
2523=head2 Other parameters:
2524
2525=over 8
2526
2527=item -h, -help
2528
2529Print this help.
2530
2531=item -v
2532
2533Verbose output, more warnings and other information.
2534
2535=item -Werror
2536
2537Treat warnings as errors.
2538
2539=back
2540
2541=cut
2542