xref: /linux/scripts/kernel-doc (revision 042db639bf33aee118846a87223acebe6700137d) 
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3# vim: softtabstop=4
4
5use warnings;
6use strict;
7
8## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
9## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
10## Copyright (C) 2001  Simon Huggins                             ##
11## Copyright (C) 2005-2012  Randy Dunlap                         ##
12## Copyright (C) 2012  Dan Luedtke                               ##
13## 								 ##
14## #define enhancements by Armin Kuster <akuster@mvista.com>	 ##
15## Copyright (c) 2000 MontaVista Software, Inc.			 ##
16#
17# Copyright (C) 2022 Tomasz Warniełło (POD)
18
19use Pod::Usage qw/pod2usage/;
20
21=head1 NAME
22
23kernel-doc - Print formatted kernel documentation to stdout
24
25=head1 SYNOPSIS
26
27 kernel-doc [-h] [-v] [-Werror] [-Wall] [-Wreturn] [-Wshort-desc[ription]] [-Wcontents-before-sections]
28   [ -man |
29     -rst [-sphinx-version VERSION] [-enable-lineno] |
30     -none
31   ]
32   [
33     -export |
34     -internal |
35     [-function NAME] ... |
36     [-nosymbol NAME] ...
37   ]
38   [-no-doc-sections]
39   [-export-file FILE] ...
40   FILE ...
41
42Run `kernel-doc -h` for details.
43
44=head1 DESCRIPTION
45
46Read C language source or header FILEs, extract embedded documentation comments,
47and print formatted documentation to standard output.
48
49The documentation comments are identified by the "/**" opening comment mark.
50
51See Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
52
53=cut
54
55# more perldoc at the end of the file
56
57## init lots of data
58
59my $errors = 0;
60my $warnings = 0;
61my $anon_struct_union = 0;
62
63# match expressions used to find embedded type information
64my $type_constant = '\b``([^\`]+)``\b';
65my $type_constant2 = '\%([-_\w]+)';
66my $type_func = '(\w+)\(\)';
67my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
68my $type_param_ref = '([\!~\*]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
69my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
70my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
71my $type_env = '(\$\w+)';
72my $type_enum = '\&(enum\s*([_\w]+))';
73my $type_struct = '\&(struct\s*([_\w]+))';
74my $type_typedef = '\&(typedef\s*([_\w]+))';
75my $type_union = '\&(union\s*([_\w]+))';
76my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
77my $type_fallback = '\&([_\w]+)';
78my $type_member_func = $type_member . '\(\)';
79
80# Output conversion substitutions.
81#  One for each output format
82
83# these are pretty rough
84my @highlights_man = (
85    [$type_constant, "\$1"],
86    [$type_constant2, "\$1"],
87    [$type_func, "\\\\fB\$1\\\\fP"],
88    [$type_enum, "\\\\fI\$1\\\\fP"],
89    [$type_struct, "\\\\fI\$1\\\\fP"],
90    [$type_typedef, "\\\\fI\$1\\\\fP"],
91    [$type_union, "\\\\fI\$1\\\\fP"],
92    [$type_param, "\\\\fI\$1\\\\fP"],
93    [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
94    [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
95    [$type_fallback, "\\\\fI\$1\\\\fP"]
96  );
97my $blankline_man = "";
98
99# rst-mode
100my @highlights_rst = (
101    [$type_constant, "``\$1``"],
102    [$type_constant2, "``\$1``"],
103
104    # Note: need to escape () to avoid func matching later
105    [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
106    [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
107    [$type_fp_param, "**\$1\\\\(\\\\)**"],
108    [$type_fp_param2, "**\$1\\\\(\\\\)**"],
109    [$type_func, "\$1()"],
110    [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
111    [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
112    [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
113    [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
114
115    # in rst this can refer to any type
116    [$type_fallback, "\\:c\\:type\\:`\$1`"],
117    [$type_param_ref, "**\$1\$2**"]
118  );
119my $blankline_rst = "\n";
120
121# read arguments
122if ($#ARGV == -1) {
123    pod2usage(
124        -message => "No arguments!\n",
125        -exitval => 1,
126        -verbose => 99,
127        -sections => 'SYNOPSIS',
128        -output => \*STDERR,
129      );
130}
131
132my $kernelversion;
133my ($sphinx_major, $sphinx_minor, $sphinx_patch);
134
135my $dohighlight = "";
136
137my $verbose = 0;
138my $Werror = 0;
139my $Wreturn = 0;
140my $Wshort_desc = 0;
141my $Wcontents_before_sections = 0;
142my $output_mode = "rst";
143my $output_preformatted = 0;
144my $no_doc_sections = 0;
145my $enable_lineno = 0;
146my @highlights = @highlights_rst;
147my $blankline = $blankline_rst;
148my $modulename = "Kernel API";
149
150use constant {
151    OUTPUT_ALL          => 0, # output all symbols and doc sections
152    OUTPUT_INCLUDE      => 1, # output only specified symbols
153    OUTPUT_EXPORTED     => 2, # output exported symbols
154    OUTPUT_INTERNAL     => 3, # output non-exported symbols
155};
156my $output_selection = OUTPUT_ALL;
157my $show_not_found = 0;	# No longer used
158
159my @export_file_list;
160
161my @build_time;
162if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
163    (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
164    @build_time = gmtime($seconds);
165} else {
166    @build_time = localtime;
167}
168
169my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
170                'July', 'August', 'September', 'October',
171                'November', 'December')[$build_time[4]] .
172    " " . ($build_time[5]+1900);
173
174# Essentially these are globals.
175# They probably want to be tidied up, made more localised or something.
176# CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
177# could cause "use of undefined value" or other bugs.
178my ($function, %function_table, %parametertypes, $declaration_purpose);
179my %nosymbol_table = ();
180my $declaration_start_line;
181my ($type, $declaration_name, $return_type);
182my ($newsection, $newcontents, $prototype, $brcount, %source_map);
183
184if (defined($ENV{'KBUILD_VERBOSE'}) && $ENV{'KBUILD_VERBOSE'} =~ '1') {
185    $verbose = 1;
186}
187
188if (defined($ENV{'KCFLAGS'})) {
189    my $kcflags = "$ENV{'KCFLAGS'}";
190
191    if ($kcflags =~ /(\s|^)-Werror(\s|$)/) {
192        $Werror = 1;
193    }
194}
195
196# reading this variable is for backwards compat just in case
197# someone was calling it with the variable from outside the
198# kernel's build system
199if (defined($ENV{'KDOC_WERROR'})) {
200    $Werror = "$ENV{'KDOC_WERROR'}";
201}
202# other environment variables are converted to command-line
203# arguments in cmd_checkdoc in the build system
204
205# Generated docbook code is inserted in a template at a point where
206# docbook v3.1 requires a non-zero sequence of RefEntry's; see:
207# https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
208# We keep track of number of generated entries and generate a dummy
209# if needs be to ensure the expanded template can be postprocessed
210# into html.
211my $section_counter = 0;
212
213my $lineprefix="";
214
215# Parser states
216use constant {
217    STATE_NORMAL        => 0,        # normal code
218    STATE_NAME          => 1,        # looking for function name
219    STATE_BODY_MAYBE    => 2,        # body - or maybe more description
220    STATE_BODY          => 3,        # the body of the comment
221    STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
222    STATE_PROTO         => 5,        # scanning prototype
223    STATE_DOCBLOCK      => 6,        # documentation block
224    STATE_INLINE        => 7,        # gathering doc outside main block
225};
226my $state;
227my $in_doc_sect;
228my $leading_space;
229
230# Inline documentation state
231use constant {
232    STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
233    STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
234    STATE_INLINE_TEXT   => 2, # looking for member documentation
235    STATE_INLINE_END    => 3, # done
236    STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
237                              # Spit a warning as it's not
238                              # proper kernel-doc and ignore the rest.
239};
240my $inline_doc_state;
241
242#declaration types: can be
243# 'function', 'struct', 'union', 'enum', 'typedef'
244my $decl_type;
245
246# Name of the kernel-doc identifier for non-DOC markups
247my $identifier;
248
249my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
250my $doc_end = '\*/';
251my $doc_com = '\s*\*\s*';
252my $doc_com_body = '\s*\* ?';
253my $doc_decl = $doc_com . '(\w+)';
254# @params and a strictly limited set of supported section names
255# Specifically:
256#   Match @word:
257#	  @...:
258#         @{section-name}:
259# while trying to not match literal block starts like "example::"
260#
261my $doc_sect = $doc_com .
262    '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:([^:].*)?$';
263my $doc_content = $doc_com_body . '(.*)';
264my $doc_block = $doc_com . 'DOC:\s*(.*)?';
265my $doc_inline_start = '^\s*/\*\*\s*$';
266my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
267my $doc_inline_end = '^\s*\*/\s*$';
268my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
269my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
270my $export_symbol_ns = '^\s*EXPORT_SYMBOL_NS(_GPL)?\s*\(\s*(\w+)\s*,\s*\w+\)\s*;';
271my $function_pointer = qr{([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)};
272my $attribute = qr{__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)}i;
273
274my %parameterdescs;
275my %parameterdesc_start_lines;
276my @parameterlist;
277my %sections;
278my @sectionlist;
279my %section_start_lines;
280my $sectcheck;
281my $struct_actual;
282
283my $contents = "";
284my $new_start_line = 0;
285
286# the canonical section names. see also $doc_sect above.
287my $section_default = "Description";	# default section
288my $section_intro = "Introduction";
289my $section = $section_default;
290my $section_context = "Context";
291my $section_return = "Return";
292
293my $undescribed = "-- undescribed --";
294
295reset_state();
296
297while ($ARGV[0] =~ m/^--?(.*)/) {
298    my $cmd = $1;
299    shift @ARGV;
300    if ($cmd eq "man") {
301        $output_mode = "man";
302        @highlights = @highlights_man;
303        $blankline = $blankline_man;
304    } elsif ($cmd eq "rst") {
305        $output_mode = "rst";
306        @highlights = @highlights_rst;
307        $blankline = $blankline_rst;
308    } elsif ($cmd eq "none") {
309        $output_mode = "none";
310    } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
311        $modulename = shift @ARGV;
312    } elsif ($cmd eq "function") { # to only output specific functions
313        $output_selection = OUTPUT_INCLUDE;
314        $function = shift @ARGV;
315        $function_table{$function} = 1;
316    } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
317        my $symbol = shift @ARGV;
318        $nosymbol_table{$symbol} = 1;
319    } elsif ($cmd eq "export") { # only exported symbols
320        $output_selection = OUTPUT_EXPORTED;
321        %function_table = ();
322    } elsif ($cmd eq "internal") { # only non-exported symbols
323        $output_selection = OUTPUT_INTERNAL;
324        %function_table = ();
325    } elsif ($cmd eq "export-file") {
326        my $file = shift @ARGV;
327        push(@export_file_list, $file);
328    } elsif ($cmd eq "v") {
329        $verbose = 1;
330    } elsif ($cmd eq "Werror") {
331        $Werror = 1;
332    } elsif ($cmd eq "Wreturn") {
333        $Wreturn = 1;
334    } elsif ($cmd eq "Wshort-desc" or $cmd eq "Wshort-description") {
335        $Wshort_desc = 1;
336    } elsif ($cmd eq "Wcontents-before-sections") {
337        $Wcontents_before_sections = 1;
338    } elsif ($cmd eq "Wall") {
339        $Wreturn = 1;
340        $Wshort_desc = 1;
341        $Wcontents_before_sections = 1;
342    } elsif (($cmd eq "h") || ($cmd eq "help")) {
343        pod2usage(-exitval => 0, -verbose => 2);
344    } elsif ($cmd eq 'no-doc-sections') {
345        $no_doc_sections = 1;
346    } elsif ($cmd eq 'enable-lineno') {
347        $enable_lineno = 1;
348    } elsif ($cmd eq 'show-not-found') {
349        $show_not_found = 1;  # A no-op but don't fail
350    } elsif ($cmd eq "sphinx-version") {
351        my $ver_string = shift @ARGV;
352        if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
353            $sphinx_major = $1;
354            if (defined($2)) {
355                $sphinx_minor = substr($2,1);
356            } else {
357                $sphinx_minor = 0;
358            }
359            if (defined($3)) {
360                $sphinx_patch = substr($3,1)
361            } else {
362                $sphinx_patch = 0;
363            }
364        } else {
365            die "Sphinx version should either major.minor or major.minor.patch format\n";
366        }
367    } else {
368        # Unknown argument
369        pod2usage(
370            -message => "Argument unknown!\n",
371            -exitval => 1,
372            -verbose => 99,
373            -sections => 'SYNOPSIS',
374            -output => \*STDERR,
375            );
376    }
377    if ($#ARGV < 0){
378        pod2usage(
379            -message => "FILE argument missing\n",
380            -exitval => 1,
381            -verbose => 99,
382            -sections => 'SYNOPSIS',
383            -output => \*STDERR,
384            );
385    }
386}
387
388# continue execution near EOF;
389
390# The C domain dialect changed on Sphinx 3. So, we need to check the
391# version in order to produce the right tags.
392sub findprog($)
393{
394    foreach(split(/:/, $ENV{PATH})) {
395        return "$_/$_[0]" if(-x "$_/$_[0]");
396    }
397}
398
399sub get_sphinx_version()
400{
401    my $ver;
402
403    my $cmd = "sphinx-build";
404    if (!findprog($cmd)) {
405        my $cmd = "sphinx-build3";
406        if (!findprog($cmd)) {
407            $sphinx_major = 1;
408            $sphinx_minor = 2;
409            $sphinx_patch = 0;
410            printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
411                   $sphinx_major, $sphinx_minor, $sphinx_patch;
412            return;
413        }
414    }
415
416    open IN, "$cmd --version 2>&1 |";
417    while (<IN>) {
418        if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
419            $sphinx_major = $1;
420            $sphinx_minor = $2;
421            $sphinx_patch = $3;
422            last;
423        }
424        # Sphinx 1.2.x uses a different format
425        if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
426            $sphinx_major = $1;
427            $sphinx_minor = $2;
428            $sphinx_patch = $3;
429            last;
430        }
431    }
432    close IN;
433}
434
435# get kernel version from env
436sub get_kernel_version() {
437    my $version = 'unknown kernel version';
438
439    if (defined($ENV{'KERNELVERSION'})) {
440        $version = $ENV{'KERNELVERSION'};
441    }
442    return $version;
443}
444
445#
446sub print_lineno {
447    my $lineno = shift;
448    if ($enable_lineno && defined($lineno)) {
449        print ".. LINENO " . $lineno . "\n";
450    }
451}
452
453sub emit_warning {
454    my $location = shift;
455    my $msg = shift;
456    print STDERR "$location: warning: $msg";
457    ++$warnings;
458}
459##
460# dumps section contents to arrays/hashes intended for that purpose.
461#
462sub dump_section {
463    my $file = shift;
464    my $name = shift;
465    my $contents = join "\n", @_;
466
467    if ($name =~ m/$type_param/) {
468        $name = $1;
469        $parameterdescs{$name} = $contents;
470        $sectcheck = $sectcheck . $name . " ";
471        $parameterdesc_start_lines{$name} = $new_start_line;
472        $new_start_line = 0;
473    } elsif ($name eq "@\.\.\.") {
474        $name = "...";
475        $parameterdescs{$name} = $contents;
476        $sectcheck = $sectcheck . $name . " ";
477        $parameterdesc_start_lines{$name} = $new_start_line;
478        $new_start_line = 0;
479    } else {
480        if (defined($sections{$name}) && ($sections{$name} ne "")) {
481            # Only warn on user specified duplicate section names.
482            if ($name ne $section_default) {
483                emit_warning("${file}:$.", "duplicate section name '$name'\n");
484            }
485            $sections{$name} .= $contents;
486        } else {
487            $sections{$name} = $contents;
488            push @sectionlist, $name;
489            $section_start_lines{$name} = $new_start_line;
490            $new_start_line = 0;
491        }
492    }
493}
494
495##
496# dump DOC: section after checking that it should go out
497#
498sub dump_doc_section {
499    my $file = shift;
500    my $name = shift;
501    my $contents = join "\n", @_;
502
503    if ($no_doc_sections) {
504        return;
505    }
506
507    return if (defined($nosymbol_table{$name}));
508
509    if (($output_selection == OUTPUT_ALL) ||
510        (($output_selection == OUTPUT_INCLUDE) &&
511         defined($function_table{$name})))
512    {
513        dump_section($file, $name, $contents);
514        output_blockhead({'sectionlist' => \@sectionlist,
515                          'sections' => \%sections,
516                          'module' => $modulename,
517                          'content-only' => ($output_selection != OUTPUT_ALL), });
518    }
519}
520
521##
522# output function
523#
524# parameterdescs, a hash.
525#  function => "function name"
526#  parameterlist => @list of parameters
527#  parameterdescs => %parameter descriptions
528#  sectionlist => @list of sections
529#  sections => %section descriptions
530#
531
532sub output_highlight {
533    my $contents = join "\n",@_;
534    my $line;
535
536#   DEBUG
537#   if (!defined $contents) {
538#	use Carp;
539#	confess "output_highlight got called with no args?\n";
540#   }
541
542#   print STDERR "contents b4:$contents\n";
543    eval $dohighlight;
544    die $@ if $@;
545#   print STDERR "contents af:$contents\n";
546
547    foreach $line (split "\n", $contents) {
548        if (! $output_preformatted) {
549            $line =~ s/^\s*//;
550        }
551        if ($line eq ""){
552            if (! $output_preformatted) {
553                print $lineprefix, $blankline;
554            }
555        } else {
556            if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
557                print "\\&$line";
558            } else {
559                print $lineprefix, $line;
560            }
561        }
562        print "\n";
563    }
564}
565
566##
567# output function in man
568sub output_function_man(%) {
569    my %args = %{$_[0]};
570    my ($parameter, $section);
571    my $count;
572
573    print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
574
575    print ".SH NAME\n";
576    print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
577
578    print ".SH SYNOPSIS\n";
579    if ($args{'functiontype'} ne "") {
580        print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
581    } else {
582        print ".B \"" . $args{'function'} . "\n";
583    }
584    $count = 0;
585    my $parenth = "(";
586    my $post = ",";
587    foreach my $parameter (@{$args{'parameterlist'}}) {
588        if ($count == $#{$args{'parameterlist'}}) {
589            $post = ");";
590        }
591        $type = $args{'parametertypes'}{$parameter};
592        if ($type =~ m/$function_pointer/) {
593            # pointer-to-function
594            print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
595        } else {
596            $type =~ s/([^\*])$/$1 /;
597            print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
598        }
599        $count++;
600        $parenth = "";
601    }
602
603    print ".SH ARGUMENTS\n";
604    foreach $parameter (@{$args{'parameterlist'}}) {
605        my $parameter_name = $parameter;
606        $parameter_name =~ s/\[.*//;
607
608        print ".IP \"" . $parameter . "\" 12\n";
609        output_highlight($args{'parameterdescs'}{$parameter_name});
610    }
611    foreach $section (@{$args{'sectionlist'}}) {
612        print ".SH \"", uc $section, "\"\n";
613        output_highlight($args{'sections'}{$section});
614    }
615}
616
617##
618# output enum in man
619sub output_enum_man(%) {
620    my %args = %{$_[0]};
621    my ($parameter, $section);
622    my $count;
623
624    print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
625
626    print ".SH NAME\n";
627    print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
628
629    print ".SH SYNOPSIS\n";
630    print "enum " . $args{'enum'} . " {\n";
631    $count = 0;
632    foreach my $parameter (@{$args{'parameterlist'}}) {
633        print ".br\n.BI \"    $parameter\"\n";
634        if ($count == $#{$args{'parameterlist'}}) {
635            print "\n};\n";
636            last;
637        } else {
638            print ", \n.br\n";
639        }
640        $count++;
641    }
642
643    print ".SH Constants\n";
644    foreach $parameter (@{$args{'parameterlist'}}) {
645        my $parameter_name = $parameter;
646        $parameter_name =~ s/\[.*//;
647
648        print ".IP \"" . $parameter . "\" 12\n";
649        output_highlight($args{'parameterdescs'}{$parameter_name});
650    }
651    foreach $section (@{$args{'sectionlist'}}) {
652        print ".SH \"$section\"\n";
653        output_highlight($args{'sections'}{$section});
654    }
655}
656
657##
658# output struct in man
659sub output_struct_man(%) {
660    my %args = %{$_[0]};
661    my ($parameter, $section);
662
663    print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
664
665    print ".SH NAME\n";
666    print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
667
668    my $declaration = $args{'definition'};
669    $declaration =~ s/\t/  /g;
670    $declaration =~ s/\n/"\n.br\n.BI \"/g;
671    print ".SH SYNOPSIS\n";
672    print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
673    print ".BI \"$declaration\n};\n.br\n\n";
674
675    print ".SH Members\n";
676    foreach $parameter (@{$args{'parameterlist'}}) {
677        ($parameter =~ /^#/) && next;
678
679        my $parameter_name = $parameter;
680        $parameter_name =~ s/\[.*//;
681
682        ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
683        print ".IP \"" . $parameter . "\" 12\n";
684        output_highlight($args{'parameterdescs'}{$parameter_name});
685    }
686    foreach $section (@{$args{'sectionlist'}}) {
687        print ".SH \"$section\"\n";
688        output_highlight($args{'sections'}{$section});
689    }
690}
691
692##
693# output typedef in man
694sub output_typedef_man(%) {
695    my %args = %{$_[0]};
696    my ($parameter, $section);
697
698    print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
699
700    print ".SH NAME\n";
701    print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
702
703    foreach $section (@{$args{'sectionlist'}}) {
704        print ".SH \"$section\"\n";
705        output_highlight($args{'sections'}{$section});
706    }
707}
708
709sub output_blockhead_man(%) {
710    my %args = %{$_[0]};
711    my ($parameter, $section);
712    my $count;
713
714    print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
715
716    foreach $section (@{$args{'sectionlist'}}) {
717        print ".SH \"$section\"\n";
718        output_highlight($args{'sections'}{$section});
719    }
720}
721
722##
723# output in restructured text
724#
725
726#
727# This could use some work; it's used to output the DOC: sections, and
728# starts by putting out the name of the doc section itself, but that tends
729# to duplicate a header already in the template file.
730#
731sub output_blockhead_rst(%) {
732    my %args = %{$_[0]};
733    my ($parameter, $section);
734
735    foreach $section (@{$args{'sectionlist'}}) {
736        next if (defined($nosymbol_table{$section}));
737
738        if ($output_selection != OUTPUT_INCLUDE) {
739            print ".. _$section:\n\n";
740            print "**$section**\n\n";
741        }
742        print_lineno($section_start_lines{$section});
743        output_highlight_rst($args{'sections'}{$section});
744        print "\n";
745    }
746}
747
748#
749# Apply the RST highlights to a sub-block of text.
750#
751sub highlight_block($) {
752    # The dohighlight kludge requires the text be called $contents
753    my $contents = shift;
754    eval $dohighlight;
755    die $@ if $@;
756    return $contents;
757}
758
759#
760# Regexes used only here.
761#
762my $sphinx_literal = '^[^.].*::$';
763my $sphinx_cblock = '^\.\.\ +code-block::';
764
765sub output_highlight_rst {
766    my $input = join "\n",@_;
767    my $output = "";
768    my $line;
769    my $in_literal = 0;
770    my $litprefix;
771    my $block = "";
772
773    foreach $line (split "\n",$input) {
774        #
775        # If we're in a literal block, see if we should drop out
776        # of it.  Otherwise pass the line straight through unmunged.
777        #
778        if ($in_literal) {
779            if (! ($line =~ /^\s*$/)) {
780                #
781                # If this is the first non-blank line in a literal
782                # block we need to figure out what the proper indent is.
783                #
784                if ($litprefix eq "") {
785                    $line =~ /^(\s*)/;
786                    $litprefix = '^' . $1;
787                    $output .= $line . "\n";
788                } elsif (! ($line =~ /$litprefix/)) {
789                    $in_literal = 0;
790                } else {
791                    $output .= $line . "\n";
792                }
793            } else {
794                $output .= $line . "\n";
795            }
796        }
797        #
798        # Not in a literal block (or just dropped out)
799        #
800        if (! $in_literal) {
801            $block .= $line . "\n";
802            if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
803                $in_literal = 1;
804                $litprefix = "";
805                $output .= highlight_block($block);
806                $block = ""
807            }
808        }
809    }
810
811    if ($block) {
812        $output .= highlight_block($block);
813    }
814    foreach $line (split "\n", $output) {
815        print $lineprefix . $line . "\n";
816    }
817}
818
819sub output_function_rst(%) {
820    my %args = %{$_[0]};
821    my ($parameter, $section);
822    my $oldprefix = $lineprefix;
823
824    my $signature = "";
825    if ($args{'functiontype'} ne "") {
826        $signature = $args{'functiontype'} . " " . $args{'function'} . " (";
827    } else {
828        $signature = $args{'function'} . " (";
829    }
830
831    my $count = 0;
832    foreach my $parameter (@{$args{'parameterlist'}}) {
833        if ($count ne 0) {
834            $signature .= ", ";
835        }
836        $count++;
837        $type = $args{'parametertypes'}{$parameter};
838
839        if ($type =~ m/$function_pointer/) {
840            # pointer-to-function
841            $signature .= $1 . $parameter . ") (" . $2 . ")";
842        } else {
843            $signature .= $type;
844        }
845    }
846
847    $signature .= ")";
848
849    if ($sphinx_major < 3) {
850        if ($args{'typedef'}) {
851            print ".. c:type:: ". $args{'function'} . "\n\n";
852            print_lineno($declaration_start_line);
853            print "   **Typedef**: ";
854            $lineprefix = "";
855            output_highlight_rst($args{'purpose'});
856            print "\n\n**Syntax**\n\n";
857            print "  ``$signature``\n\n";
858        } else {
859            print ".. c:function:: $signature\n\n";
860        }
861    } else {
862        if ($args{'typedef'} || $args{'functiontype'} eq "") {
863            print ".. c:macro:: ". $args{'function'} . "\n\n";
864
865            if ($args{'typedef'}) {
866                print_lineno($declaration_start_line);
867                print "   **Typedef**: ";
868                $lineprefix = "";
869                output_highlight_rst($args{'purpose'});
870                print "\n\n**Syntax**\n\n";
871                print "  ``$signature``\n\n";
872            } else {
873                print "``$signature``\n\n";
874            }
875        } else {
876            print ".. c:function:: $signature\n\n";
877        }
878    }
879
880    if (!$args{'typedef'}) {
881        print_lineno($declaration_start_line);
882        $lineprefix = "   ";
883        output_highlight_rst($args{'purpose'});
884        print "\n";
885    }
886
887    #
888    # Put our descriptive text into a container (thus an HTML <div>) to help
889    # set the function prototypes apart.
890    #
891    print ".. container:: kernelindent\n\n";
892    $lineprefix = "  ";
893    print $lineprefix . "**Parameters**\n\n";
894    foreach $parameter (@{$args{'parameterlist'}}) {
895        my $parameter_name = $parameter;
896        $parameter_name =~ s/\[.*//;
897        $type = $args{'parametertypes'}{$parameter};
898
899        if ($type ne "") {
900            print $lineprefix . "``$type``\n";
901        } else {
902            print $lineprefix . "``$parameter``\n";
903        }
904
905        print_lineno($parameterdesc_start_lines{$parameter_name});
906
907        $lineprefix = "    ";
908        if (defined($args{'parameterdescs'}{$parameter_name}) &&
909            $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
910            output_highlight_rst($args{'parameterdescs'}{$parameter_name});
911        } else {
912            print $lineprefix . "*undescribed*\n";
913        }
914        $lineprefix = "  ";
915        print "\n";
916    }
917
918    output_section_rst(@_);
919    $lineprefix = $oldprefix;
920}
921
922sub output_section_rst(%) {
923    my %args = %{$_[0]};
924    my $section;
925    my $oldprefix = $lineprefix;
926
927    foreach $section (@{$args{'sectionlist'}}) {
928        print $lineprefix . "**$section**\n\n";
929        print_lineno($section_start_lines{$section});
930        output_highlight_rst($args{'sections'}{$section});
931        print "\n";
932    }
933    print "\n";
934}
935
936sub output_enum_rst(%) {
937    my %args = %{$_[0]};
938    my ($parameter);
939    my $oldprefix = $lineprefix;
940    my $count;
941    my $outer;
942
943    if ($sphinx_major < 3) {
944        my $name = "enum " . $args{'enum'};
945        print "\n\n.. c:type:: " . $name . "\n\n";
946    } else {
947        my $name = $args{'enum'};
948        print "\n\n.. c:enum:: " . $name . "\n\n";
949    }
950    print_lineno($declaration_start_line);
951    $lineprefix = "  ";
952    output_highlight_rst($args{'purpose'});
953    print "\n";
954
955    print ".. container:: kernelindent\n\n";
956    $outer = $lineprefix . "  ";
957    $lineprefix = $outer . "  ";
958    print $outer . "**Constants**\n\n";
959    foreach $parameter (@{$args{'parameterlist'}}) {
960        print $outer . "``$parameter``\n";
961
962        if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
963            output_highlight_rst($args{'parameterdescs'}{$parameter});
964        } else {
965            print $lineprefix . "*undescribed*\n";
966        }
967        print "\n";
968    }
969    print "\n";
970    $lineprefix = $oldprefix;
971    output_section_rst(@_);
972}
973
974sub output_typedef_rst(%) {
975    my %args = %{$_[0]};
976    my ($parameter);
977    my $oldprefix = $lineprefix;
978    my $name;
979
980    if ($sphinx_major < 3) {
981        $name = "typedef " . $args{'typedef'};
982    } else {
983        $name = $args{'typedef'};
984    }
985    print "\n\n.. c:type:: " . $name . "\n\n";
986    print_lineno($declaration_start_line);
987    $lineprefix = "   ";
988    output_highlight_rst($args{'purpose'});
989    print "\n";
990
991    $lineprefix = $oldprefix;
992    output_section_rst(@_);
993}
994
995sub output_struct_rst(%) {
996    my %args = %{$_[0]};
997    my ($parameter);
998    my $oldprefix = $lineprefix;
999
1000    if ($sphinx_major < 3) {
1001        my $name = $args{'type'} . " " . $args{'struct'};
1002        print "\n\n.. c:type:: " . $name . "\n\n";
1003    } else {
1004        my $name = $args{'struct'};
1005        if ($args{'type'} eq 'union') {
1006            print "\n\n.. c:union:: " . $name . "\n\n";
1007        } else {
1008            print "\n\n.. c:struct:: " . $name . "\n\n";
1009        }
1010    }
1011    print_lineno($declaration_start_line);
1012    $lineprefix = "  ";
1013    output_highlight_rst($args{'purpose'});
1014    print "\n";
1015
1016    print ".. container:: kernelindent\n\n";
1017    print $lineprefix . "**Definition**::\n\n";
1018    my $declaration = $args{'definition'};
1019    $lineprefix = $lineprefix . "  ";
1020    $declaration =~ s/\t/$lineprefix/g;
1021    print $lineprefix . $args{'type'} . " " . $args{'struct'} . " {\n$declaration" . $lineprefix . "};\n\n";
1022
1023    $lineprefix = "  ";
1024    print $lineprefix . "**Members**\n\n";
1025    foreach $parameter (@{$args{'parameterlist'}}) {
1026        ($parameter =~ /^#/) && next;
1027
1028        my $parameter_name = $parameter;
1029        $parameter_name =~ s/\[.*//;
1030
1031        ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1032        $type = $args{'parametertypes'}{$parameter};
1033        print_lineno($parameterdesc_start_lines{$parameter_name});
1034        print $lineprefix . "``" . $parameter . "``\n";
1035        $lineprefix = "    ";
1036        output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1037        $lineprefix = "  ";
1038        print "\n";
1039    }
1040    print "\n";
1041
1042    $lineprefix = $oldprefix;
1043    output_section_rst(@_);
1044}
1045
1046## none mode output functions
1047
1048sub output_function_none(%) {
1049}
1050
1051sub output_enum_none(%) {
1052}
1053
1054sub output_typedef_none(%) {
1055}
1056
1057sub output_struct_none(%) {
1058}
1059
1060sub output_blockhead_none(%) {
1061}
1062
1063##
1064# generic output function for all types (function, struct/union, typedef, enum);
1065# calls the generated, variable output_ function name based on
1066# functype and output_mode
1067sub output_declaration {
1068    no strict 'refs';
1069    my $name = shift;
1070    my $functype = shift;
1071    my $func = "output_${functype}_$output_mode";
1072
1073    return if (defined($nosymbol_table{$name}));
1074
1075    if (($output_selection == OUTPUT_ALL) ||
1076        (($output_selection == OUTPUT_INCLUDE ||
1077          $output_selection == OUTPUT_EXPORTED) &&
1078         defined($function_table{$name})) ||
1079        ($output_selection == OUTPUT_INTERNAL &&
1080         !($functype eq "function" && defined($function_table{$name}))))
1081    {
1082        &$func(@_);
1083        $section_counter++;
1084    }
1085}
1086
1087##
1088# generic output function - calls the right one based on current output mode.
1089sub output_blockhead {
1090    no strict 'refs';
1091    my $func = "output_blockhead_" . $output_mode;
1092    &$func(@_);
1093    $section_counter++;
1094}
1095
1096##
1097# takes a declaration (struct, union, enum, typedef) and
1098# invokes the right handler. NOT called for functions.
1099sub dump_declaration($$) {
1100    no strict 'refs';
1101    my ($prototype, $file) = @_;
1102    my $func = "dump_" . $decl_type;
1103    &$func(@_);
1104}
1105
1106sub dump_union($$) {
1107    dump_struct(@_);
1108}
1109
1110sub dump_struct($$) {
1111    my $x = shift;
1112    my $file = shift;
1113    my $decl_type;
1114    my $members;
1115    my $type = qr{struct|union};
1116    # For capturing struct/union definition body, i.e. "{members*}qualifiers*"
1117    my $qualifiers = qr{$attribute|__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned};
1118    my $definition_body = qr{\{(.*)\}\s*$qualifiers*};
1119    my $struct_members = qr{($type)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;};
1120
1121    if ($x =~ /($type)\s+(\w+)\s*$definition_body/) {
1122        $decl_type = $1;
1123        $declaration_name = $2;
1124        $members = $3;
1125    } elsif ($x =~ /typedef\s+($type)\s*$definition_body\s*(\w+)\s*;/) {
1126        $decl_type = $1;
1127        $declaration_name = $3;
1128        $members = $2;
1129    }
1130
1131    if ($members) {
1132        if ($identifier ne $declaration_name) {
1133            emit_warning("${file}:$.", "expecting prototype for $decl_type $identifier. Prototype was for $decl_type $declaration_name instead\n");
1134            return;
1135        }
1136
1137        # ignore members marked private:
1138        $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1139        $members =~ s/\/\*\s*private:.*//gosi;
1140        # strip comments:
1141        $members =~ s/\/\*.*?\*\///gos;
1142        # strip attributes
1143        $members =~ s/\s*$attribute/ /gi;
1144        $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1145        $members =~ s/\s*__counted_by\s*\([^;]*\)/ /gos;
1146        $members =~ s/\s*__counted_by_(le|be)\s*\([^;]*\)/ /gos;
1147        $members =~ s/\s*__packed\s*/ /gos;
1148        $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1149        $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1150        $members =~ s/\s*____cacheline_aligned/ /gos;
1151        # unwrap struct_group():
1152        # - first eat non-declaration parameters and rewrite for final match
1153        # - then remove macro, outer parens, and trailing semicolon
1154        $members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1155        $members =~ s/\bstruct_group_(attr|tagged)\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1156        $members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1157        $members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1158
1159        my $args = qr{([^,)]+)};
1160        # replace DECLARE_BITMAP
1161        $members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1162        $members =~ s/DECLARE_PHY_INTERFACE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, PHY_INTERFACE_MODE_MAX)/gos;
1163        $members =~ s/DECLARE_BITMAP\s*\($args,\s*$args\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1164        # replace DECLARE_HASHTABLE
1165        $members =~ s/DECLARE_HASHTABLE\s*\($args,\s*$args\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1166        # replace DECLARE_KFIFO
1167        $members =~ s/DECLARE_KFIFO\s*\($args,\s*$args,\s*$args\)/$2 \*$1/gos;
1168        # replace DECLARE_KFIFO_PTR
1169        $members =~ s/DECLARE_KFIFO_PTR\s*\($args,\s*$args\)/$2 \*$1/gos;
1170        # replace DECLARE_FLEX_ARRAY
1171        $members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1172        #replace DEFINE_DMA_UNMAP_ADDR
1173        $members =~ s/DEFINE_DMA_UNMAP_ADDR\s*\($args\)/dma_addr_t $1/gos;
1174        #replace DEFINE_DMA_UNMAP_LEN
1175        $members =~ s/DEFINE_DMA_UNMAP_LEN\s*\($args\)/__u32 $1/gos;
1176        my $declaration = $members;
1177
1178        # Split nested struct/union elements as newer ones
1179        while ($members =~ m/$struct_members/) {
1180            my $newmember;
1181            my $maintype = $1;
1182            my $ids = $4;
1183            my $content = $3;
1184            foreach my $id(split /,/, $ids) {
1185                $newmember .= "$maintype $id; ";
1186
1187                $id =~ s/[:\[].*//;
1188                $id =~ s/^\s*\**(\S+)\s*/$1/;
1189                foreach my $arg (split /;/, $content) {
1190                    next if ($arg =~ m/^\s*$/);
1191                    if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1192                        # pointer-to-function
1193                        my $type = $1;
1194                        my $name = $2;
1195                        my $extra = $3;
1196                        next if (!$name);
1197                        if ($id =~ m/^\s*$/) {
1198                            # anonymous struct/union
1199                            $newmember .= "$type$name$extra; ";
1200                        } else {
1201                            $newmember .= "$type$id.$name$extra; ";
1202                        }
1203                    } else {
1204                        my $type;
1205                        my $names;
1206                        $arg =~ s/^\s+//;
1207                        $arg =~ s/\s+$//;
1208                        # Handle bitmaps
1209                        $arg =~ s/:\s*\d+\s*//g;
1210                        # Handle arrays
1211                        $arg =~ s/\[.*\]//g;
1212                        # The type may have multiple words,
1213                        # and multiple IDs can be defined, like:
1214                        #    const struct foo, *bar, foobar
1215                        # So, we remove spaces when parsing the
1216                        # names, in order to match just names
1217                        # and commas for the names
1218                        $arg =~ s/\s*,\s*/,/g;
1219                        if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1220                            $type = $1;
1221                            $names = $2;
1222                        } else {
1223                            $newmember .= "$arg; ";
1224                            next;
1225                        }
1226                        foreach my $name (split /,/, $names) {
1227                            $name =~ s/^\s*\**(\S+)\s*/$1/;
1228                            next if (($name =~ m/^\s*$/));
1229                            if ($id =~ m/^\s*$/) {
1230                                # anonymous struct/union
1231                                $newmember .= "$type $name; ";
1232                            } else {
1233                                $newmember .= "$type $id.$name; ";
1234                            }
1235                        }
1236                    }
1237                }
1238            }
1239            $members =~ s/$struct_members/$newmember/;
1240        }
1241
1242        # Ignore other nested elements, like enums
1243        $members =~ s/(\{[^\{\}]*\})//g;
1244
1245        create_parameterlist($members, ';', $file, $declaration_name);
1246        check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1247
1248        # Adjust declaration for better display
1249        $declaration =~ s/([\{;])/$1\n/g;
1250        $declaration =~ s/\}\s+;/};/g;
1251        # Better handle inlined enums
1252        do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1253
1254        my @def_args = split /\n/, $declaration;
1255        my $level = 1;
1256        $declaration = "";
1257        foreach my $clause (@def_args) {
1258            $clause =~ s/^\s+//;
1259            $clause =~ s/\s+$//;
1260            $clause =~ s/\s+/ /;
1261            next if (!$clause);
1262            $level-- if ($clause =~ m/(\})/ && $level > 1);
1263            if (!($clause =~ m/^\s*#/)) {
1264                $declaration .= "\t" x $level;
1265            }
1266            $declaration .= "\t" . $clause . "\n";
1267            $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1268        }
1269        output_declaration($declaration_name,
1270                   'struct',
1271                   {'struct' => $declaration_name,
1272                    'module' => $modulename,
1273                    'definition' => $declaration,
1274                    'parameterlist' => \@parameterlist,
1275                    'parameterdescs' => \%parameterdescs,
1276                    'parametertypes' => \%parametertypes,
1277                    'sectionlist' => \@sectionlist,
1278                    'sections' => \%sections,
1279                    'purpose' => $declaration_purpose,
1280                    'type' => $decl_type
1281                   });
1282    } else {
1283        print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1284        ++$errors;
1285    }
1286}
1287
1288
1289sub show_warnings($$) {
1290    my $functype = shift;
1291    my $name = shift;
1292
1293    return 0 if (defined($nosymbol_table{$name}));
1294
1295    return 1 if ($output_selection == OUTPUT_ALL);
1296
1297    if ($output_selection == OUTPUT_EXPORTED) {
1298        if (defined($function_table{$name})) {
1299            return 1;
1300        } else {
1301            return 0;
1302        }
1303    }
1304    if ($output_selection == OUTPUT_INTERNAL) {
1305        if (!($functype eq "function" && defined($function_table{$name}))) {
1306            return 1;
1307        } else {
1308            return 0;
1309        }
1310    }
1311    if ($output_selection == OUTPUT_INCLUDE) {
1312        if (defined($function_table{$name})) {
1313            return 1;
1314        } else {
1315            return 0;
1316        }
1317    }
1318    die("Please add the new output type at show_warnings()");
1319}
1320
1321sub dump_enum($$) {
1322    my $x = shift;
1323    my $file = shift;
1324    my $members;
1325
1326    # ignore members marked private:
1327    $x =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1328    $x =~ s/\/\*\s*private:.*}/}/gosi;
1329
1330    $x =~ s@/\*.*?\*/@@gos;	# strip comments.
1331    # strip #define macros inside enums
1332    $x =~ s@#\s*((define|ifdef|if)\s+|endif)[^;]*;@@gos;
1333
1334    if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1335        $declaration_name = $2;
1336        $members = $1;
1337    } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1338        $declaration_name = $1;
1339        $members = $2;
1340    }
1341
1342    if ($members) {
1343        if ($identifier ne $declaration_name) {
1344            if ($identifier eq "") {
1345                emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n");
1346            } else {
1347                emit_warning("${file}:$.", "expecting prototype for enum $identifier. Prototype was for enum $declaration_name instead\n");
1348            }
1349            return;
1350        }
1351        $declaration_name = "(anonymous)" if ($declaration_name eq "");
1352
1353        my %_members;
1354
1355        $members =~ s/\s+$//;
1356        $members =~ s/\([^;]*?[\)]//g;
1357
1358        foreach my $arg (split ',', $members) {
1359            $arg =~ s/^\s*(\w+).*/$1/;
1360            push @parameterlist, $arg;
1361            if (!$parameterdescs{$arg}) {
1362                $parameterdescs{$arg} = $undescribed;
1363                if (show_warnings("enum", $declaration_name)) {
1364                    emit_warning("${file}:$.", "Enum value '$arg' not described in enum '$declaration_name'\n");
1365                }
1366            }
1367            $_members{$arg} = 1;
1368        }
1369
1370        while (my ($k, $v) = each %parameterdescs) {
1371            if (!exists($_members{$k})) {
1372                if (show_warnings("enum", $declaration_name)) {
1373                    emit_warning("${file}:$.", "Excess enum value '$k' description in '$declaration_name'\n");
1374                }
1375            }
1376        }
1377
1378        output_declaration($declaration_name,
1379                           'enum',
1380                           {'enum' => $declaration_name,
1381                            'module' => $modulename,
1382                            'parameterlist' => \@parameterlist,
1383                            'parameterdescs' => \%parameterdescs,
1384                            'sectionlist' => \@sectionlist,
1385                            'sections' => \%sections,
1386                            'purpose' => $declaration_purpose
1387                           });
1388    } else {
1389        print STDERR "${file}:$.: error: Cannot parse enum!\n";
1390        ++$errors;
1391    }
1392}
1393
1394my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1395my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1396my $typedef_args = qr { \s*\((.*)\); }x;
1397
1398my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1399my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1400
1401sub dump_typedef($$) {
1402    my $x = shift;
1403    my $file = shift;
1404
1405    $x =~ s@/\*.*?\*/@@gos;	# strip comments.
1406
1407    # Parse function typedef prototypes
1408    if ($x =~ $typedef1 || $x =~ $typedef2) {
1409        $return_type = $1;
1410        $declaration_name = $2;
1411        my $args = $3;
1412        $return_type =~ s/^\s+//;
1413
1414        if ($identifier ne $declaration_name) {
1415            emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1416            return;
1417        }
1418
1419        create_parameterlist($args, ',', $file, $declaration_name);
1420
1421        output_declaration($declaration_name,
1422                           'function',
1423                           {'function' => $declaration_name,
1424                            'typedef' => 1,
1425                            'module' => $modulename,
1426                            'functiontype' => $return_type,
1427                            'parameterlist' => \@parameterlist,
1428                            'parameterdescs' => \%parameterdescs,
1429                            'parametertypes' => \%parametertypes,
1430                            'sectionlist' => \@sectionlist,
1431                            'sections' => \%sections,
1432                            'purpose' => $declaration_purpose
1433                           });
1434        return;
1435    }
1436
1437    while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1438        $x =~ s/\(*.\)\s*;$/;/;
1439        $x =~ s/\[*.\]\s*;$/;/;
1440    }
1441
1442    if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1443        $declaration_name = $1;
1444
1445        if ($identifier ne $declaration_name) {
1446            emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1447            return;
1448        }
1449
1450        output_declaration($declaration_name,
1451                           'typedef',
1452                           {'typedef' => $declaration_name,
1453                            'module' => $modulename,
1454                            'sectionlist' => \@sectionlist,
1455                            'sections' => \%sections,
1456                            'purpose' => $declaration_purpose
1457                           });
1458    } else {
1459        print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1460        ++$errors;
1461    }
1462}
1463
1464sub save_struct_actual($) {
1465    my $actual = shift;
1466
1467    # strip all spaces from the actual param so that it looks like one string item
1468    $actual =~ s/\s*//g;
1469    $struct_actual = $struct_actual . $actual . " ";
1470}
1471
1472sub create_parameterlist($$$$) {
1473    my $args = shift;
1474    my $splitter = shift;
1475    my $file = shift;
1476    my $declaration_name = shift;
1477    my $type;
1478    my $param;
1479
1480    # temporarily replace commas inside function pointer definition
1481    my $arg_expr = qr{\([^\),]+};
1482    while ($args =~ /$arg_expr,/) {
1483        $args =~ s/($arg_expr),/$1#/g;
1484    }
1485
1486    foreach my $arg (split($splitter, $args)) {
1487        # strip comments
1488        $arg =~ s/\/\*.*\*\///;
1489        # ignore argument attributes
1490        $arg =~ s/\sPOS0?\s/ /;
1491        # strip leading/trailing spaces
1492        $arg =~ s/^\s*//;
1493        $arg =~ s/\s*$//;
1494        $arg =~ s/\s+/ /;
1495
1496        if ($arg =~ /^#/) {
1497            # Treat preprocessor directive as a typeless variable just to fill
1498            # corresponding data structures "correctly". Catch it later in
1499            # output_* subs.
1500            push_parameter($arg, "", "", $file);
1501        } elsif ($arg =~ m/\(.+\)\s*\(/) {
1502            # pointer-to-function
1503            $arg =~ tr/#/,/;
1504            $arg =~ m/[^\(]+\(\*?\s*([\w\[\]\.]*)\s*\)/;
1505            $param = $1;
1506            $type = $arg;
1507            $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1508            save_struct_actual($param);
1509            push_parameter($param, $type, $arg, $file, $declaration_name);
1510        } elsif ($arg =~ m/\(.+\)\s*\[/) {
1511            # array-of-pointers
1512            $arg =~ tr/#/,/;
1513            $arg =~ m/[^\(]+\(\s*\*\s*([\w\[\]\.]*?)\s*(\s*\[\s*[\w]+\s*\]\s*)*\)/;
1514            $param = $1;
1515            $type = $arg;
1516            $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1517            save_struct_actual($param);
1518            push_parameter($param, $type, $arg, $file, $declaration_name);
1519        } elsif ($arg) {
1520            $arg =~ s/\s*:\s*/:/g;
1521            $arg =~ s/\s*\[/\[/g;
1522
1523            my @args = split('\s*,\s*', $arg);
1524            if ($args[0] =~ m/\*/) {
1525                $args[0] =~ s/(\*+)\s*/ $1/;
1526            }
1527
1528            my @first_arg;
1529            if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1530                shift @args;
1531                push(@first_arg, split('\s+', $1));
1532                push(@first_arg, $2);
1533            } else {
1534                @first_arg = split('\s+', shift @args);
1535            }
1536
1537            unshift(@args, pop @first_arg);
1538            $type = join " ", @first_arg;
1539
1540            foreach $param (@args) {
1541                if ($param =~ m/^(\*+)\s*(.*)/) {
1542                    save_struct_actual($2);
1543
1544                    push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1545                } elsif ($param =~ m/(.*?):(\w+)/) {
1546                    if ($type ne "") { # skip unnamed bit-fields
1547                        save_struct_actual($1);
1548                        push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1549                    }
1550                } else {
1551                    save_struct_actual($param);
1552                    push_parameter($param, $type, $arg, $file, $declaration_name);
1553                }
1554            }
1555        }
1556    }
1557}
1558
1559sub push_parameter($$$$$) {
1560    my $param = shift;
1561    my $type = shift;
1562    my $org_arg = shift;
1563    my $file = shift;
1564    my $declaration_name = shift;
1565
1566    if (($anon_struct_union == 1) && ($type eq "") &&
1567        ($param eq "}")) {
1568        return;        # ignore the ending }; from anon. struct/union
1569    }
1570
1571    $anon_struct_union = 0;
1572    $param =~ s/[\[\)].*//;
1573
1574    if ($type eq "" && $param =~ /\.\.\.$/)
1575    {
1576        if (!$param =~ /\w\.\.\.$/) {
1577            # handles unnamed variable parameters
1578            $param = "...";
1579        } elsif ($param =~ /\w\.\.\.$/) {
1580            # for named variable parameters of the form `x...`, remove the dots
1581            $param =~ s/\.\.\.$//;
1582        }
1583        if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1584            $parameterdescs{$param} = "variable arguments";
1585        }
1586    }
1587    elsif ($type eq "" && ($param eq "" or $param eq "void"))
1588    {
1589        $param="void";
1590        $parameterdescs{void} = "no arguments";
1591    }
1592    elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1593    # handle unnamed (anonymous) union or struct:
1594    {
1595        $type = $param;
1596        $param = "{unnamed_" . $param . "}";
1597        $parameterdescs{$param} = "anonymous\n";
1598        $anon_struct_union = 1;
1599    }
1600    elsif ($param =~ "__cacheline_group" )
1601    # handle cache group enforcing variables: they do not need be described in header files
1602    {
1603        return; # ignore __cacheline_group_begin and __cacheline_group_end
1604    }
1605
1606    # warn if parameter has no description
1607    # (but ignore ones starting with # as these are not parameters
1608    # but inline preprocessor statements);
1609    # Note: It will also ignore void params and unnamed structs/unions
1610    if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1611        $parameterdescs{$param} = $undescribed;
1612
1613        if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1614            emit_warning("${file}:$.", "Function parameter or struct member '$param' not described in '$declaration_name'\n");
1615        }
1616    }
1617
1618    # strip spaces from $param so that it is one continuous string
1619    # on @parameterlist;
1620    # this fixes a problem where check_sections() cannot find
1621    # a parameter like "addr[6 + 2]" because it actually appears
1622    # as "addr[6", "+", "2]" on the parameter list;
1623    # but it's better to maintain the param string unchanged for output,
1624    # so just weaken the string compare in check_sections() to ignore
1625    # "[blah" in a parameter string;
1626    ###$param =~ s/\s*//g;
1627    push @parameterlist, $param;
1628    $org_arg =~ s/\s\s+/ /g;
1629    $parametertypes{$param} = $org_arg;
1630}
1631
1632sub check_sections($$$$$) {
1633    my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1634    my @sects = split ' ', $sectcheck;
1635    my @prms = split ' ', $prmscheck;
1636    my $err;
1637    my ($px, $sx);
1638    my $prm_clean;        # strip trailing "[array size]" and/or beginning "*"
1639
1640    foreach $sx (0 .. $#sects) {
1641        $err = 1;
1642        foreach $px (0 .. $#prms) {
1643            $prm_clean = $prms[$px];
1644            $prm_clean =~ s/\[.*\]//;
1645            $prm_clean =~ s/$attribute//i;
1646            # ignore array size in a parameter string;
1647            # however, the original param string may contain
1648            # spaces, e.g.:  addr[6 + 2]
1649            # and this appears in @prms as "addr[6" since the
1650            # parameter list is split at spaces;
1651            # hence just ignore "[..." for the sections check;
1652            $prm_clean =~ s/\[.*//;
1653
1654            ##$prm_clean =~ s/^\**//;
1655            if ($prm_clean eq $sects[$sx]) {
1656                $err = 0;
1657                last;
1658            }
1659        }
1660        if ($err) {
1661            if ($decl_type eq "function") {
1662                emit_warning("${file}:$.",
1663                    "Excess function parameter " .
1664                    "'$sects[$sx]' " .
1665                    "description in '$decl_name'\n");
1666            } elsif (($decl_type eq "struct") or
1667                          ($decl_type eq "union")) {
1668                emit_warning("${file}:$.",
1669                    "Excess $decl_type member " .
1670                    "'$sects[$sx]' " .
1671                    "description in '$decl_name'\n");
1672            }
1673        }
1674    }
1675}
1676
1677##
1678# Checks the section describing the return value of a function.
1679sub check_return_section {
1680    my $file = shift;
1681    my $declaration_name = shift;
1682    my $return_type = shift;
1683
1684    # Ignore an empty return type (It's a macro)
1685    # Ignore functions with a "void" return type. (But don't ignore "void *")
1686    if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1687        return;
1688    }
1689
1690    if (!defined($sections{$section_return}) ||
1691        $sections{$section_return} eq "")
1692    {
1693        emit_warning("${file}:$.",
1694                     "No description found for return value of " .
1695                     "'$declaration_name'\n");
1696    }
1697}
1698
1699##
1700# takes a function prototype and the name of the current file being
1701# processed and spits out all the details stored in the global
1702# arrays/hashes.
1703sub dump_function($$) {
1704    my $prototype = shift;
1705    my $file = shift;
1706    my $noret = 0;
1707
1708    print_lineno($new_start_line);
1709
1710    $prototype =~ s/^static +//;
1711    $prototype =~ s/^extern +//;
1712    $prototype =~ s/^asmlinkage +//;
1713    $prototype =~ s/^inline +//;
1714    $prototype =~ s/^__inline__ +//;
1715    $prototype =~ s/^__inline +//;
1716    $prototype =~ s/^__always_inline +//;
1717    $prototype =~ s/^noinline +//;
1718    $prototype =~ s/^__FORTIFY_INLINE +//;
1719    $prototype =~ s/__init +//;
1720    $prototype =~ s/__init_or_module +//;
1721    $prototype =~ s/__deprecated +//;
1722    $prototype =~ s/__flatten +//;
1723    $prototype =~ s/__meminit +//;
1724    $prototype =~ s/__must_check +//;
1725    $prototype =~ s/__weak +//;
1726    $prototype =~ s/__sched +//;
1727    $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1728    $prototype =~ s/__(?:re)?alloc_size\s*\(\s*\d+\s*(?:,\s*\d+\s*)?\) +//;
1729    $prototype =~ s/__diagnose_as\s*\(\s*\S+\s*(?:,\s*\d+\s*)*\) +//;
1730    my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1731    $prototype =~ s/__attribute_const__ +//;
1732    $prototype =~ s/__attribute__\s*\(\(
1733            (?:
1734                 [\w\s]++          # attribute name
1735                 (?:\([^)]*+\))?   # attribute arguments
1736                 \s*+,?            # optional comma at the end
1737            )+
1738          \)\)\s+//x;
1739
1740    # Yes, this truly is vile.  We are looking for:
1741    # 1. Return type (may be nothing if we're looking at a macro)
1742    # 2. Function name
1743    # 3. Function parameters.
1744    #
1745    # All the while we have to watch out for function pointer parameters
1746    # (which IIRC is what the two sections are for), C types (these
1747    # regexps don't even start to express all the possibilities), and
1748    # so on.
1749    #
1750    # If you mess with these regexps, it's a good idea to check that
1751    # the following functions' documentation still comes out right:
1752    # - parport_register_device (function pointer parameters)
1753    # - atomic_set (macro)
1754    # - pci_match_device, __copy_to_user (long return type)
1755    my $name = qr{[a-zA-Z0-9_~:]+};
1756    my $prototype_end1 = qr{[^\(]*};
1757    my $prototype_end2 = qr{[^\{]*};
1758    my $prototype_end = qr{\(($prototype_end1|$prototype_end2)\)};
1759    my $type1 = qr{[\w\s]+};
1760    my $type2 = qr{$type1\*+};
1761
1762    if ($define && $prototype =~ m/^()($name)\s+/) {
1763        # This is an object-like macro, it has no return type and no parameter
1764        # list.
1765        # Function-like macros are not allowed to have spaces between
1766        # declaration_name and opening parenthesis (notice the \s+).
1767        $return_type = $1;
1768        $declaration_name = $2;
1769        $noret = 1;
1770    } elsif ($prototype =~ m/^()($name)\s*$prototype_end/ ||
1771        $prototype =~ m/^($type1)\s+($name)\s*$prototype_end/ ||
1772        $prototype =~ m/^($type2+)\s*($name)\s*$prototype_end/)  {
1773        $return_type = $1;
1774        $declaration_name = $2;
1775        my $args = $3;
1776
1777        create_parameterlist($args, ',', $file, $declaration_name);
1778    } else {
1779        emit_warning("${file}:$.", "cannot understand function prototype: '$prototype'\n");
1780        return;
1781    }
1782
1783    if ($identifier ne $declaration_name) {
1784        emit_warning("${file}:$.", "expecting prototype for $identifier(). Prototype was for $declaration_name() instead\n");
1785        return;
1786    }
1787
1788    my $prms = join " ", @parameterlist;
1789    check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1790
1791    # This check emits a lot of warnings at the moment, because many
1792    # functions don't have a 'Return' doc section. So until the number
1793    # of warnings goes sufficiently down, the check is only performed in
1794    # -Wreturn mode.
1795    # TODO: always perform the check.
1796    if ($Wreturn && !$noret) {
1797        check_return_section($file, $declaration_name, $return_type);
1798    }
1799
1800    # The function parser can be called with a typedef parameter.
1801    # Handle it.
1802    if ($return_type =~ /typedef/) {
1803        output_declaration($declaration_name,
1804                           'function',
1805                           {'function' => $declaration_name,
1806                            'typedef' => 1,
1807                            'module' => $modulename,
1808                            'functiontype' => $return_type,
1809                            'parameterlist' => \@parameterlist,
1810                            'parameterdescs' => \%parameterdescs,
1811                            'parametertypes' => \%parametertypes,
1812                            'sectionlist' => \@sectionlist,
1813                            'sections' => \%sections,
1814                            'purpose' => $declaration_purpose
1815                           });
1816    } else {
1817        output_declaration($declaration_name,
1818                           'function',
1819                           {'function' => $declaration_name,
1820                            'module' => $modulename,
1821                            'functiontype' => $return_type,
1822                            'parameterlist' => \@parameterlist,
1823                            'parameterdescs' => \%parameterdescs,
1824                            'parametertypes' => \%parametertypes,
1825                            'sectionlist' => \@sectionlist,
1826                            'sections' => \%sections,
1827                            'purpose' => $declaration_purpose
1828                           });
1829    }
1830}
1831
1832sub reset_state {
1833    $function = "";
1834    %parameterdescs = ();
1835    %parametertypes = ();
1836    @parameterlist = ();
1837    %sections = ();
1838    @sectionlist = ();
1839    $sectcheck = "";
1840    $struct_actual = "";
1841    $prototype = "";
1842
1843    $state = STATE_NORMAL;
1844    $inline_doc_state = STATE_INLINE_NA;
1845}
1846
1847sub tracepoint_munge($) {
1848    my $file = shift;
1849    my $tracepointname = 0;
1850    my $tracepointargs = 0;
1851
1852    if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1853        $tracepointname = $1;
1854    }
1855    if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1856        $tracepointname = $1;
1857    }
1858    if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1859        $tracepointname = $2;
1860    }
1861    $tracepointname =~ s/^\s+//; #strip leading whitespace
1862    if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1863        $tracepointargs = $1;
1864    }
1865    if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1866        emit_warning("${file}:$.", "Unrecognized tracepoint format: \n".
1867                 "$prototype\n");
1868    } else {
1869        $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1870        $identifier = "trace_$identifier";
1871    }
1872}
1873
1874sub syscall_munge() {
1875    my $void = 0;
1876
1877    $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1878##    if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1879    if ($prototype =~ m/SYSCALL_DEFINE0/) {
1880        $void = 1;
1881##        $prototype = "long sys_$1(void)";
1882    }
1883
1884    $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1885    if ($prototype =~ m/long (sys_.*?),/) {
1886        $prototype =~ s/,/\(/;
1887    } elsif ($void) {
1888        $prototype =~ s/\)/\(void\)/;
1889    }
1890
1891    # now delete all of the odd-number commas in $prototype
1892    # so that arg types & arg names don't have a comma between them
1893    my $count = 0;
1894    my $len = length($prototype);
1895    if ($void) {
1896        $len = 0;    # skip the for-loop
1897    }
1898    for (my $ix = 0; $ix < $len; $ix++) {
1899        if (substr($prototype, $ix, 1) eq ',') {
1900            $count++;
1901            if ($count % 2 == 1) {
1902                substr($prototype, $ix, 1) = ' ';
1903            }
1904        }
1905    }
1906}
1907
1908sub process_proto_function($$) {
1909    my $x = shift;
1910    my $file = shift;
1911
1912    $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1913
1914    if ($x =~ /^#/ && $x !~ /^#\s*define/) {
1915        # do nothing
1916    } elsif ($x =~ /([^\{]*)/) {
1917        $prototype .= $1;
1918    }
1919
1920    if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1921        $prototype =~ s@/\*.*?\*/@@gos;        # strip comments.
1922        $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1923        $prototype =~ s@^\s+@@gos; # strip leading spaces
1924
1925        # Handle prototypes for function pointers like:
1926        # int (*pcs_config)(struct foo)
1927        $prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
1928
1929        if ($prototype =~ /SYSCALL_DEFINE/) {
1930            syscall_munge();
1931        }
1932        if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1933            $prototype =~ /DEFINE_SINGLE_EVENT/)
1934        {
1935            tracepoint_munge($file);
1936        }
1937        dump_function($prototype, $file);
1938        reset_state();
1939    }
1940}
1941
1942sub process_proto_type($$) {
1943    my $x = shift;
1944    my $file = shift;
1945
1946    $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1947    $x =~ s@^\s+@@gos; # strip leading spaces
1948    $x =~ s@\s+$@@gos; # strip trailing spaces
1949    $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1950
1951    if ($x =~ /^#/) {
1952        # To distinguish preprocessor directive from regular declaration later.
1953        $x .= ";";
1954    }
1955
1956    while (1) {
1957        if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1958            if( length $prototype ) {
1959                $prototype .= " "
1960            }
1961            $prototype .= $1 . $2;
1962            ($2 eq '{') && $brcount++;
1963            ($2 eq '}') && $brcount--;
1964            if (($2 eq ';') && ($brcount == 0)) {
1965                dump_declaration($prototype, $file);
1966                reset_state();
1967                last;
1968            }
1969            $x = $3;
1970        } else {
1971            $prototype .= $x;
1972            last;
1973        }
1974    }
1975}
1976
1977
1978sub map_filename($) {
1979    my $file;
1980    my ($orig_file) = @_;
1981
1982    if (defined($ENV{'SRCTREE'})) {
1983        $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1984    } else {
1985        $file = $orig_file;
1986    }
1987
1988    if (defined($source_map{$file})) {
1989        $file = $source_map{$file};
1990    }
1991
1992    return $file;
1993}
1994
1995sub process_export_file($) {
1996    my ($orig_file) = @_;
1997    my $file = map_filename($orig_file);
1998
1999    if (!open(IN,"<$file")) {
2000        print STDERR "Error: Cannot open file $file\n";
2001        ++$errors;
2002        return;
2003    }
2004
2005    while (<IN>) {
2006        if (/$export_symbol/) {
2007            next if (defined($nosymbol_table{$2}));
2008            $function_table{$2} = 1;
2009        }
2010        if (/$export_symbol_ns/) {
2011            next if (defined($nosymbol_table{$2}));
2012            $function_table{$2} = 1;
2013        }
2014    }
2015
2016    close(IN);
2017}
2018
2019#
2020# Parsers for the various processing states.
2021#
2022# STATE_NORMAL: looking for the /** to begin everything.
2023#
2024sub process_normal() {
2025    if (/$doc_start/o) {
2026        $state = STATE_NAME;        # next line is always the function name
2027        $in_doc_sect = 0;
2028        $declaration_start_line = $. + 1;
2029    }
2030}
2031
2032#
2033# STATE_NAME: Looking for the "name - description" line
2034#
2035sub process_name($$) {
2036    my $file = shift;
2037    my $descr;
2038
2039    if (/$doc_block/o) {
2040        $state = STATE_DOCBLOCK;
2041        $contents = "";
2042        $new_start_line = $.;
2043
2044        if ( $1 eq "" ) {
2045            $section = $section_intro;
2046        } else {
2047            $section = $1;
2048        }
2049    } elsif (/$doc_decl/o) {
2050        $identifier = $1;
2051        my $is_kernel_comment = 0;
2052        my $decl_start = qr{$doc_com};
2053        # test for pointer declaration type, foo * bar() - desc
2054        my $fn_type = qr{\w+\s*\*\s*};
2055        my $parenthesis = qr{\(\w*\)};
2056        my $decl_end = qr{[-:].*};
2057        if (/^$decl_start([\w\s]+?)$parenthesis?\s*$decl_end?$/) {
2058            $identifier = $1;
2059        }
2060        if ($identifier =~ m/^(struct|union|enum|typedef)\b\s*(\S*)/) {
2061            $decl_type = $1;
2062            $identifier = $2;
2063            $is_kernel_comment = 1;
2064        }
2065        # Look for foo() or static void foo() - description; or misspelt
2066        # identifier
2067        elsif (/^$decl_start$fn_type?(\w+)\s*$parenthesis?\s*$decl_end?$/ ||
2068            /^$decl_start$fn_type?(\w+.*)$parenthesis?\s*$decl_end$/) {
2069            $identifier = $1;
2070            $decl_type = 'function';
2071            $identifier =~ s/^define\s+//;
2072            $is_kernel_comment = 1;
2073        }
2074        $identifier =~ s/\s+$//;
2075
2076        $state = STATE_BODY;
2077        # if there's no @param blocks need to set up default section
2078        # here
2079        $contents = "";
2080        $section = $section_default;
2081        $new_start_line = $. + 1;
2082        if (/[-:](.*)/) {
2083            # strip leading/trailing/multiple spaces
2084            $descr= $1;
2085            $descr =~ s/^\s*//;
2086            $descr =~ s/\s*$//;
2087            $descr =~ s/\s+/ /g;
2088            $declaration_purpose = $descr;
2089            $state = STATE_BODY_MAYBE;
2090        } else {
2091            $declaration_purpose = "";
2092        }
2093
2094        if (!$is_kernel_comment) {
2095            emit_warning("${file}:$.", "This comment starts with '/**', but isn't a kernel-doc comment. Refer Documentation/doc-guide/kernel-doc.rst\n$_");
2096            $state = STATE_NORMAL;
2097        }
2098
2099        if (($declaration_purpose eq "") && $Wshort_desc) {
2100            emit_warning("${file}:$.", "missing initial short description on line:\n$_");
2101        }
2102
2103        if ($identifier eq "" && $decl_type ne "enum") {
2104            emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n$_");
2105            $state = STATE_NORMAL;
2106        }
2107
2108        if ($verbose) {
2109            print STDERR "${file}:$.: info: Scanning doc for $decl_type $identifier\n";
2110        }
2111    } else {
2112        emit_warning("${file}:$.", "Cannot understand $_ on line $. - I thought it was a doc line\n");
2113        $state = STATE_NORMAL;
2114    }
2115}
2116
2117
2118#
2119# STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2120#
2121sub process_body($$) {
2122    my $file = shift;
2123
2124    if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2125        dump_section($file, $section, $contents);
2126        $section = $section_default;
2127        $new_start_line = $.;
2128        $contents = "";
2129    }
2130
2131    if (/$doc_sect/i) { # case insensitive for supported section names
2132        $in_doc_sect = 1;
2133        $newsection = $1;
2134        $newcontents = $2;
2135
2136        # map the supported section names to the canonical names
2137        if ($newsection =~ m/^description$/i) {
2138            $newsection = $section_default;
2139        } elsif ($newsection =~ m/^context$/i) {
2140            $newsection = $section_context;
2141        } elsif ($newsection =~ m/^returns?$/i) {
2142            $newsection = $section_return;
2143        } elsif ($newsection =~ m/^\@return$/) {
2144            # special: @return is a section, not a param description
2145            $newsection = $section_return;
2146        }
2147
2148        if (($contents ne "") && ($contents ne "\n")) {
2149            if (!$in_doc_sect && $Wcontents_before_sections) {
2150                emit_warning("${file}:$.", "contents before sections\n");
2151            }
2152            dump_section($file, $section, $contents);
2153            $section = $section_default;
2154        }
2155
2156        $in_doc_sect = 1;
2157        $state = STATE_BODY;
2158        $contents = $newcontents;
2159        $new_start_line = $.;
2160        while (substr($contents, 0, 1) eq " ") {
2161            $contents = substr($contents, 1);
2162        }
2163        if ($contents ne "") {
2164            $contents .= "\n";
2165        }
2166        $section = $newsection;
2167        $leading_space = undef;
2168    } elsif (/$doc_end/) {
2169        if (($contents ne "") && ($contents ne "\n")) {
2170            dump_section($file, $section, $contents);
2171            $section = $section_default;
2172            $contents = "";
2173        }
2174        # look for doc_com + <text> + doc_end:
2175        if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2176            emit_warning("${file}:$.", "suspicious ending line: $_");
2177        }
2178
2179        $prototype = "";
2180        $state = STATE_PROTO;
2181        $brcount = 0;
2182        $new_start_line = $. + 1;
2183    } elsif (/$doc_content/) {
2184        if ($1 eq "") {
2185            if ($section eq $section_context) {
2186                dump_section($file, $section, $contents);
2187                $section = $section_default;
2188                $contents = "";
2189                $new_start_line = $.;
2190                $state = STATE_BODY;
2191            } else {
2192                if ($section ne $section_default) {
2193                    $state = STATE_BODY_WITH_BLANK_LINE;
2194                } else {
2195                    $state = STATE_BODY;
2196                }
2197                $contents .= "\n";
2198            }
2199        } elsif ($state == STATE_BODY_MAYBE) {
2200            # Continued declaration purpose
2201            chomp($declaration_purpose);
2202            $declaration_purpose .= " " . $1;
2203            $declaration_purpose =~ s/\s+/ /g;
2204        } else {
2205            my $cont = $1;
2206            if ($section =~ m/^@/ || $section eq $section_context) {
2207                if (!defined $leading_space) {
2208                    if ($cont =~ m/^(\s+)/) {
2209                        $leading_space = $1;
2210                    } else {
2211                        $leading_space = "";
2212                    }
2213                }
2214                $cont =~ s/^$leading_space//;
2215            }
2216            $contents .= $cont . "\n";
2217        }
2218    } else {
2219        # i dont know - bad line?  ignore.
2220        emit_warning("${file}:$.", "bad line: $_");
2221    }
2222}
2223
2224
2225#
2226# STATE_PROTO: reading a function/whatever prototype.
2227#
2228sub process_proto($$) {
2229    my $file = shift;
2230
2231    if (/$doc_inline_oneline/) {
2232        $section = $1;
2233        $contents = $2;
2234        if ($contents ne "") {
2235            $contents .= "\n";
2236            dump_section($file, $section, $contents);
2237            $section = $section_default;
2238            $contents = "";
2239        }
2240    } elsif (/$doc_inline_start/) {
2241        $state = STATE_INLINE;
2242        $inline_doc_state = STATE_INLINE_NAME;
2243    } elsif ($decl_type eq 'function') {
2244        process_proto_function($_, $file);
2245    } else {
2246        process_proto_type($_, $file);
2247    }
2248}
2249
2250#
2251# STATE_DOCBLOCK: within a DOC: block.
2252#
2253sub process_docblock($$) {
2254    my $file = shift;
2255
2256    if (/$doc_end/) {
2257        dump_doc_section($file, $section, $contents);
2258        $section = $section_default;
2259        $contents = "";
2260        $function = "";
2261        %parameterdescs = ();
2262        %parametertypes = ();
2263        @parameterlist = ();
2264        %sections = ();
2265        @sectionlist = ();
2266        $prototype = "";
2267        $state = STATE_NORMAL;
2268    } elsif (/$doc_content/) {
2269        if ( $1 eq "" )        {
2270            $contents .= $blankline;
2271        } else {
2272            $contents .= $1 . "\n";
2273        }
2274    }
2275}
2276
2277#
2278# STATE_INLINE: docbook comments within a prototype.
2279#
2280sub process_inline($$) {
2281    my $file = shift;
2282
2283    # First line (state 1) needs to be a @parameter
2284    if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2285        $section = $1;
2286        $contents = $2;
2287        $new_start_line = $.;
2288        if ($contents ne "") {
2289            while (substr($contents, 0, 1) eq " ") {
2290                $contents = substr($contents, 1);
2291            }
2292            $contents .= "\n";
2293        }
2294        $inline_doc_state = STATE_INLINE_TEXT;
2295        # Documentation block end */
2296    } elsif (/$doc_inline_end/) {
2297        if (($contents ne "") && ($contents ne "\n")) {
2298            dump_section($file, $section, $contents);
2299            $section = $section_default;
2300            $contents = "";
2301        }
2302        $state = STATE_PROTO;
2303        $inline_doc_state = STATE_INLINE_NA;
2304        # Regular text
2305    } elsif (/$doc_content/) {
2306        if ($inline_doc_state == STATE_INLINE_TEXT) {
2307            $contents .= $1 . "\n";
2308            # nuke leading blank lines
2309            if ($contents =~ /^\s*$/) {
2310                $contents = "";
2311            }
2312        } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2313            $inline_doc_state = STATE_INLINE_ERROR;
2314            emit_warning("${file}:$.", "Incorrect use of kernel-doc format: $_");
2315        }
2316    }
2317}
2318
2319
2320sub process_file($) {
2321    my $file;
2322    my $initial_section_counter = $section_counter;
2323    my ($orig_file) = @_;
2324
2325    $file = map_filename($orig_file);
2326
2327    if (!open(IN_FILE,"<$file")) {
2328        print STDERR "Error: Cannot open file $file\n";
2329        ++$errors;
2330        return;
2331    }
2332
2333    $. = 1;
2334
2335    $section_counter = 0;
2336    while (<IN_FILE>) {
2337        while (!/^ \*/ && s/\\\s*$//) {
2338            $_ .= <IN_FILE>;
2339        }
2340        # Replace tabs by spaces
2341        while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2342        # Hand this line to the appropriate state handler
2343        if ($state == STATE_NORMAL) {
2344            process_normal();
2345        } elsif ($state == STATE_NAME) {
2346            process_name($file, $_);
2347        } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2348                 $state == STATE_BODY_WITH_BLANK_LINE) {
2349            process_body($file, $_);
2350        } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2351            process_inline($file, $_);
2352        } elsif ($state == STATE_PROTO) {
2353            process_proto($file, $_);
2354        } elsif ($state == STATE_DOCBLOCK) {
2355            process_docblock($file, $_);
2356        }
2357    }
2358
2359    # Make sure we got something interesting.
2360    if ($initial_section_counter == $section_counter && $
2361        output_mode ne "none") {
2362        if ($output_selection == OUTPUT_INCLUDE) {
2363            emit_warning("${file}:1", "'$_' not found\n")
2364                for keys %function_table;
2365        } else {
2366            emit_warning("${file}:1", "no structured comments found\n");
2367        }
2368    }
2369    close IN_FILE;
2370}
2371
2372
2373if ($output_mode eq "rst") {
2374    get_sphinx_version() if (!$sphinx_major);
2375}
2376
2377$kernelversion = get_kernel_version();
2378
2379# generate a sequence of code that will splice in highlighting information
2380# using the s// operator.
2381for (my $k = 0; $k < @highlights; $k++) {
2382    my $pattern = $highlights[$k][0];
2383    my $result = $highlights[$k][1];
2384#   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2385    $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2386}
2387
2388# Read the file that maps relative names to absolute names for
2389# separate source and object directories and for shadow trees.
2390if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2391    my ($relname, $absname);
2392    while(<SOURCE_MAP>) {
2393        chop();
2394        ($relname, $absname) = (split())[0..1];
2395        $relname =~ s:^/+::;
2396        $source_map{$relname} = $absname;
2397    }
2398    close(SOURCE_MAP);
2399}
2400
2401if ($output_selection == OUTPUT_EXPORTED ||
2402    $output_selection == OUTPUT_INTERNAL) {
2403
2404    push(@export_file_list, @ARGV);
2405
2406    foreach (@export_file_list) {
2407        chomp;
2408        process_export_file($_);
2409    }
2410}
2411
2412foreach (@ARGV) {
2413    chomp;
2414    process_file($_);
2415}
2416if ($verbose && $errors) {
2417    print STDERR "$errors errors\n";
2418}
2419if ($verbose && $warnings) {
2420    print STDERR "$warnings warnings\n";
2421}
2422
2423if ($Werror && $warnings) {
2424    print STDERR "$warnings warnings as Errors\n";
2425    exit($warnings);
2426} else {
2427    exit($output_mode eq "none" ? 0 : $errors)
2428}
2429
2430__END__
2431
2432=head1 OPTIONS
2433
2434=head2 Output format selection (mutually exclusive):
2435
2436=over 8
2437
2438=item -man
2439
2440Output troff manual page format.
2441
2442=item -rst
2443
2444Output reStructuredText format. This is the default.
2445
2446=item -none
2447
2448Do not output documentation, only warnings.
2449
2450=back
2451
2452=head2 Output format modifiers
2453
2454=head3 reStructuredText only
2455
2456=over 8
2457
2458=item -sphinx-version VERSION
2459
2460Use the ReST C domain dialect compatible with a specific Sphinx Version.
2461
2462If not specified, kernel-doc will auto-detect using the sphinx-build version
2463found on PATH.
2464
2465=back
2466
2467=head2 Output selection (mutually exclusive):
2468
2469=over 8
2470
2471=item -export
2472
2473Only output documentation for the symbols that have been exported using
2474EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2475
2476=item -internal
2477
2478Only output documentation for the symbols that have NOT been exported using
2479EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2480
2481=item -function NAME
2482
2483Only output documentation for the given function or DOC: section title.
2484All other functions and DOC: sections are ignored.
2485
2486May be specified multiple times.
2487
2488=item -nosymbol NAME
2489
2490Exclude the specified symbol from the output documentation.
2491
2492May be specified multiple times.
2493
2494=back
2495
2496=head2 Output selection modifiers:
2497
2498=over 8
2499
2500=item -no-doc-sections
2501
2502Do not output DOC: sections.
2503
2504=item -export-file FILE
2505
2506Specify an additional FILE in which to look for EXPORT_SYMBOL information.
2507
2508To be used with -export or -internal.
2509
2510May be specified multiple times.
2511
2512=back
2513
2514=head3 reStructuredText only
2515
2516=over 8
2517
2518=item -enable-lineno
2519
2520Enable output of .. LINENO lines.
2521
2522=back
2523
2524=head2 Other parameters:
2525
2526=over 8
2527
2528=item -h, -help
2529
2530Print this help.
2531
2532=item -v
2533
2534Verbose output, more warnings and other information.
2535
2536=item -Werror
2537
2538Treat warnings as errors.
2539
2540=back
2541
2542=cut
2543