xref: /linux/arch/um/kernel/uml.lds.S (revision 6e8331ac6973435b1e7604c30f2ad394035b46e1) 
1#include <asm-generic/vmlinux.lds.h>
2
3OUTPUT_FORMAT(ELF_FORMAT)
4OUTPUT_ARCH(ELF_ARCH)
5ENTRY(_start)
6jiffies = jiffies_64;
7
8SECTIONS
9{
10  /* This must contain the right address - not quite the default ELF one.*/
11  PROVIDE (__executable_start = START);
12  /* Static binaries stick stuff here, like the sigreturn trampoline,
13   * invisibly to objdump.  So, just make __binary_start equal to the very
14   * beginning of the executable, and if there are unmapped pages after this,
15   * they are forever unusable.
16   */
17  __binary_start = START;
18
19  . = START + SIZEOF_HEADERS;
20
21#ifdef MODE_TT
22  .remap_data : { UNMAP_PATH (.data .bss) }
23  .remap : { UNMAP_PATH (.text) }
24
25  . = ALIGN(4096);		/* Init code and data */
26#endif
27
28  _stext = .;
29  __init_begin = .;
30  .init.text : {
31	_sinittext = .;
32	*(.init.text)
33	_einittext = .;
34  }
35  . = ALIGN(4096);
36
37  .text      :
38  {
39    *(.text)
40    SCHED_TEXT
41    LOCK_TEXT
42    *(.fixup)
43    /* .gnu.warning sections are handled specially by elf32.em.  */
44    *(.gnu.warning)
45    *(.gnu.linkonce.t*)
46
47    . = ALIGN(4096);
48    __syscall_stub_start = .;
49    *(.__syscall_stub*)
50    __syscall_stub_end = .;
51    . = ALIGN(4096);
52  }
53
54  #include "asm/common.lds.S"
55
56  init.data : { *(init.data) }
57  .data    :
58  {
59    . = ALIGN(KERNEL_STACK_SIZE);		/* init_task */
60    *(.data.init_task)
61    *(.data)
62    *(.gnu.linkonce.d*)
63    CONSTRUCTORS
64  }
65  .data1   : { *(.data1) }
66  .ctors         :
67  {
68    *(.ctors)
69  }
70  .dtors         :
71  {
72    *(.dtors)
73  }
74
75  .got           : { *(.got.plt) *(.got) }
76  .dynamic       : { *(.dynamic) }
77  .tdata	  : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
78  .tbss		  : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
79  /* We want the small data sections together, so single-instruction offsets
80     can access them all, and initialized data all before uninitialized, so
81     we can shorten the on-disk segment size.  */
82  .sdata     : { *(.sdata) }
83  _edata  =  .;
84  PROVIDE (edata = .);
85  . = ALIGN(0x1000);
86  .sbss      :
87  {
88   __bss_start = .;
89   PROVIDE(_bss_start = .);
90   *(.sbss)
91   *(.scommon)
92  }
93  .bss       :
94  {
95   *(.dynbss)
96   *(.bss)
97   *(COMMON)
98  }
99  _end = .;
100  PROVIDE (end = .);
101
102  STABS_DEBUG
103
104  DWARF_DEBUG
105}
106