xref: /linux/arch/sh/kernel/vsyscall/vsyscall.lds.S (revision c532de5a67a70f8533d495f8f2aaa9a0491c3ad0) 
1/* SPDX-License-Identifier: GPL-2.0 */
2/*
3 * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
4 * object prelinked to its virtual address, and with only one read-only
5 * segment (that fits in one page).  This script controls its layout.
6 */
7#include <asm/asm-offsets.h>
8
9#ifdef CONFIG_CPU_LITTLE_ENDIAN
10OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
11#else
12OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
13#endif
14OUTPUT_ARCH(sh)
15
16/* The ELF entry point can be used to set the AT_SYSINFO value.  */
17ENTRY(__kernel_vsyscall);
18
19SECTIONS
20{
21	. = SIZEOF_HEADERS;
22
23	.hash		: { *(.hash) }			:text
24	.gnu.hash	: { *(.gnu.hash) }
25	.dynsym		: { *(.dynsym) }
26	.dynstr		: { *(.dynstr) }
27	.gnu.version	: { *(.gnu.version) }
28	.gnu.version_d	: { *(.gnu.version_d) }
29	.gnu.version_r	: { *(.gnu.version_r) }
30
31	/*
32	 * This linker script is used both with -r and with -shared.
33	 * For the layouts to match, we need to skip more than enough
34	 * space for the dynamic symbol table et al.  If this amount
35	 * is insufficient, ld -shared will barf.  Just increase it here.
36	 */
37	. = 0x400;
38
39	.text		: { *(.text) } 			:text	=0x90909090
40	.note		: { *(.note.*) }		:text	:note
41	.eh_frame_hdr	: { *(.eh_frame_hdr ) }		:text	:eh_frame_hdr
42	.eh_frame	: {
43		KEEP (*(.eh_frame))
44		LONG (0)
45	}						:text
46	.dynamic	: { *(.dynamic) }		:text	:dynamic
47	.useless	: {
48	      *(.got.plt) *(.got)
49	      *(.data .data.* .gnu.linkonce.d.*)
50	      *(.dynbss)
51	      *(.bss .bss.* .gnu.linkonce.b.*)
52	}						:text
53}
54
55/*
56 * Very old versions of ld do not recognize this name token; use the constant.
57 */
58#define PT_GNU_EH_FRAME	0x6474e550
59
60/*
61 * We must supply the ELF program headers explicitly to get just one
62 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
63 */
64PHDRS
65{
66	text		PT_LOAD FILEHDR PHDRS FLAGS(5);	/* PF_R|PF_X */
67	dynamic		PT_DYNAMIC FLAGS(4);		/* PF_R */
68	note		PT_NOTE FLAGS(4);		/* PF_R */
69	eh_frame_hdr	PT_GNU_EH_FRAME;
70}
71
72/*
73 * This controls what symbols we export from the DSO.
74 */
75VERSION
76{
77	LINUX_2.6 {
78	global:
79		__kernel_vsyscall;
80		__kernel_sigreturn;
81		__kernel_rt_sigreturn;
82
83	local: *;
84	};
85}
86