xref: /linux/arch/s390/boot/vmlinux.lds.S (revision 3113a29e25fe072d6eb0abccd695d7cc72ac9b6f) 
1/* SPDX-License-Identifier: GPL-2.0 */
2#include <asm-generic/vmlinux.lds.h>
3#include <asm/vmlinux.lds.h>
4#include <asm/thread_info.h>
5#include <asm/page.h>
6#include <asm/sclp.h>
7#include "boot.h"
8
9OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
10OUTPUT_ARCH(s390:64-bit)
11
12ENTRY(startup)
13
14SECTIONS
15{
16	. = 0;
17	.ipldata : {
18		*(.ipldata)
19	}
20	. = IPL_START;
21	.head.text : {
22		_head = . ;
23		HEAD_TEXT
24		_ehead = . ;
25	}
26	. = PARMAREA;
27	.parmarea : {
28		*(.parmarea)
29	}
30	.text :	{
31		_text = .;	/* Text */
32		*(.text)
33		*(.text.*)
34		INIT_TEXT
35		_etext = . ;
36	}
37	.rodata : {
38		_rodata = . ;
39		*(.rodata)	 /* read-only data */
40		*(.rodata.*)
41		_erodata = . ;
42	}
43	.got : {
44		*(.got)
45	}
46	NOTES
47	.data :	{
48		_data = . ;
49		*(.data)
50		*(.data.*)
51		_edata = . ;
52	}
53
54	BOOT_DATA
55	BOOT_DATA_PRESERVED
56
57	/*
58	 * This is the BSS section of the decompressor and not of the decompressed Linux kernel.
59	 * It will consume place in the decompressor's image.
60	 */
61	. = ALIGN(8);
62	.bss : {
63		_bss = . ;
64		*(.bss)
65		*(.bss.*)
66		*(COMMON)
67		/*
68		 * Stacks for the decompressor
69		 */
70		. = ALIGN(PAGE_SIZE);
71		_dump_info_stack_start = .;
72		. += PAGE_SIZE;
73		_dump_info_stack_end = .;
74		. = ALIGN(PAGE_SIZE);
75		_stack_start = .;
76		. += BOOT_STACK_SIZE;
77		_stack_end = .;
78		_ebss = .;
79	}
80
81	/*
82	 * uncompressed image info used by the decompressor it should match
83	 * struct vmlinux_info. It comes from .vmlinux.info section of
84	 * uncompressed vmlinux in a form of info.o
85	 */
86	. = ALIGN(8);
87	.vmlinux.info : {
88		_vmlinux_info = .;
89		*(.vmlinux.info)
90	}
91
92	.decompressor.syms : {
93		. += 1; /* make sure we have \0 before the first entry */
94		. = ALIGN(2);
95		_decompressor_syms_start = .;
96		*(.decompressor.syms)
97		_decompressor_syms_end = .;
98	}
99
100	_decompressor_end = .;
101
102#ifndef CONFIG_PIE_BUILD
103	. = ALIGN(4);
104	.vmlinux.relocs : {
105		__vmlinux_relocs_64_start = .;
106		*(.vmlinux.relocs_64)
107		__vmlinux_relocs_64_end = .;
108	}
109#endif
110
111#ifdef CONFIG_KERNEL_UNCOMPRESSED
112	. = ALIGN(PAGE_SIZE);
113	. += AMODE31_SIZE;		/* .amode31 section */
114#else
115	. = ALIGN(8);
116#endif
117	.rodata.compressed : {
118		_compressed_start = .;
119		*(.vmlinux.bin.compressed)
120		_compressed_end = .;
121	}
122
123#define SB_TRAILER_SIZE 32
124	/* Trailer needed for Secure Boot */
125	. += SB_TRAILER_SIZE; /* make sure .sb.trailer does not overwrite the previous section */
126	. = ALIGN(4096) - SB_TRAILER_SIZE;
127	.sb.trailer : {
128		QUAD(0)
129		QUAD(0)
130		QUAD(0)
131		QUAD(0x000000207a49504c)
132	}
133	_end = .;
134
135	DWARF_DEBUG
136	ELF_DETAILS
137
138	/*
139	 * Make sure that the .got.plt is either completely empty or it
140	 * contains only the three reserved double words.
141	 */
142	.got.plt : {
143		*(.got.plt)
144	}
145	ASSERT(SIZEOF(.got.plt) == 0 || SIZEOF(.got.plt) == 0x18, "Unexpected GOT/PLT entries detected!")
146
147	/*
148	 * Sections that should stay zero sized, which is safer to
149	 * explicitly check instead of blindly discarding.
150	 */
151	.plt : {
152		*(.plt) *(.plt.*) *(.iplt) *(.igot .igot.plt)
153	}
154	ASSERT(SIZEOF(.plt) == 0, "Unexpected run-time procedure linkages detected!")
155	.rela.dyn : {
156		*(.rela.*) *(.rela_*)
157	}
158	ASSERT(SIZEOF(.rela.dyn) == 0, "Unexpected run-time relocations (.rela) detected!")
159
160	/* Sections to be discarded */
161	/DISCARD/ : {
162		COMMON_DISCARDS
163		*(.eh_frame)
164		*(__ex_table)
165		*(*__ksymtab*)
166		*(___kcrctab*)
167	}
168}
169