xref: /linux/arch/powerpc/kernel/vmlinux.lds.S (revision e5c86679d5e864947a52fb31e45a425dea3e7fa9) 
1#ifdef CONFIG_PPC64
2#define PROVIDE32(x)	PROVIDE(__unused__##x)
3#else
4#define PROVIDE32(x)	PROVIDE(x)
5#endif
6#include <asm/page.h>
7#include <asm-generic/vmlinux.lds.h>
8#include <asm/cache.h>
9#include <asm/thread_info.h>
10
11ENTRY(_stext)
12
13PHDRS {
14	kernel PT_LOAD FLAGS(7); /* RWX */
15	notes PT_NOTE FLAGS(0);
16	dummy PT_NOTE FLAGS(0);
17
18	/* binutils < 2.18 has a bug that makes it misbehave when taking an
19	   ELF file with all segments at load address 0 as input.  This
20	   happens when running "strip" on vmlinux, because of the AT() magic
21	   in this linker script.  People using GCC >= 4.2 won't run into
22	   this problem, because the "build-id" support will put some data
23	   into the "notes" segment (at a non-zero load address).
24
25	   To work around this, we force some data into both the "dummy"
26	   segment and the kernel segment, so the dummy segment will get a
27	   non-zero load address.  It's not enough to always create the
28	   "notes" segment, since if nothing gets assigned to it, its load
29	   address will be zero.  */
30}
31
32#ifdef CONFIG_PPC64
33OUTPUT_ARCH(powerpc:common64)
34jiffies = jiffies_64;
35#else
36OUTPUT_ARCH(powerpc:common)
37jiffies = jiffies_64 + 4;
38#endif
39SECTIONS
40{
41	. = KERNELBASE;
42
43/*
44 * Text, read only data and other permanent read-only sections
45 */
46
47	_text = .;
48	_stext = .;
49
50	/*
51	 * Head text.
52	 * This needs to be in its own output section to avoid ld placing
53	 * branch trampoline stubs randomly throughout the fixed sections,
54	 * which it will do (even if the branch comes from another section)
55	 * in order to optimize stub generation.
56	 */
57	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
58#ifdef CONFIG_PPC64
59		KEEP(*(.head.text.first_256B));
60#ifdef CONFIG_PPC_BOOK3E
61# define END_FIXED	0x100
62#else
63		KEEP(*(.head.text.real_vectors));
64		*(.head.text.real_trampolines);
65		KEEP(*(.head.text.virt_vectors));
66		*(.head.text.virt_trampolines);
67# if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
68		KEEP(*(.head.data.fwnmi_page));
69#  define END_FIXED	0x8000
70# else
71#  define END_FIXED	0x7000
72# endif
73#endif
74		ASSERT((. == END_FIXED), "vmlinux.lds.S: fixed section overflow error");
75#else /* !CONFIG_PPC64 */
76		HEAD_TEXT
77#endif
78	} :kernel
79
80	/*
81	 * If the build dies here, it's likely code in head_64.S is referencing
82	 * labels it can't reach, and the linker inserting stubs without the
83	 * assembler's knowledge. To debug, remove the above assert and
84	 * rebuild. Look for branch stubs in the fixed section region.
85	 *
86	 * Linker stub generation could be allowed in "trampoline"
87	 * sections if absolutely necessary, but this would require
88	 * some rework of the fixed sections. Before resorting to this,
89	 * consider references that have sufficient addressing range,
90	 * (e.g., hand coded trampolines) so the linker does not have
91	 * to add stubs.
92	 *
93	 * Linker stubs at the top of the main text section are currently not
94	 * detected, and will result in a crash at boot due to offsets being
95	 * wrong.
96	 */
97#ifdef CONFIG_PPC64
98	/*
99	 * BLOCK(0) overrides the default output section alignment because
100	 * this needs to start right after .head.text in order for fixed
101	 * section placement to work.
102	 */
103	.text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) {
104#else
105	.text : AT(ADDR(.text) - LOAD_OFFSET) {
106		ALIGN_FUNCTION();
107#endif
108		/* careful! __ftr_alt_* sections need to be close to .text */
109		*(.text .fixup __ftr_alt_* .ref.text)
110		SCHED_TEXT
111		CPUIDLE_TEXT
112		LOCK_TEXT
113		KPROBES_TEXT
114		IRQENTRY_TEXT
115		SOFTIRQENTRY_TEXT
116		MEM_KEEP(init.text)
117		MEM_KEEP(exit.text)
118
119#ifdef CONFIG_PPC32
120		*(.got1)
121		__got2_start = .;
122		*(.got2)
123		__got2_end = .;
124#endif /* CONFIG_PPC32 */
125
126	} :kernel
127
128	. = ALIGN(PAGE_SIZE);
129	_etext = .;
130	PROVIDE32 (etext = .);
131
132	/* Read-only data */
133	RODATA
134
135	EXCEPTION_TABLE(0)
136
137	NOTES :kernel :notes
138
139	/* The dummy segment contents for the bug workaround mentioned above
140	   near PHDRS.  */
141	.dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
142		LONG(0)
143		LONG(0)
144		LONG(0)
145	} :kernel :dummy
146
147/*
148 * Init sections discarded at runtime
149 */
150	. = ALIGN(PAGE_SIZE);
151	__init_begin = .;
152	INIT_TEXT_SECTION(PAGE_SIZE) :kernel
153
154	/* .exit.text is discarded at runtime, not link time,
155	 * to deal with references from __bug_table
156	 */
157	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
158		EXIT_TEXT
159	}
160
161	.init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
162		INIT_DATA
163		__vtop_table_begin = .;
164		*(.vtop_fixup);
165		__vtop_table_end = .;
166		__ptov_table_begin = .;
167		*(.ptov_fixup);
168		__ptov_table_end = .;
169	}
170
171	.init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
172		INIT_SETUP(16)
173	}
174
175	.initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
176		INIT_CALLS
177	}
178
179	.con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
180		CON_INITCALL
181	}
182
183	SECURITY_INIT
184
185	. = ALIGN(8);
186	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
187		__start___ftr_fixup = .;
188		*(__ftr_fixup)
189		__stop___ftr_fixup = .;
190	}
191	. = ALIGN(8);
192	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
193		__start___mmu_ftr_fixup = .;
194		*(__mmu_ftr_fixup)
195		__stop___mmu_ftr_fixup = .;
196	}
197	. = ALIGN(8);
198	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
199		__start___lwsync_fixup = .;
200		*(__lwsync_fixup)
201		__stop___lwsync_fixup = .;
202	}
203#ifdef CONFIG_PPC64
204	. = ALIGN(8);
205	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
206		__start___fw_ftr_fixup = .;
207		*(__fw_ftr_fixup)
208		__stop___fw_ftr_fixup = .;
209	}
210#endif
211	.init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
212		INIT_RAM_FS
213	}
214
215	PERCPU_SECTION(L1_CACHE_BYTES)
216
217	. = ALIGN(8);
218	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
219		__machine_desc_start = . ;
220		*(.machine.desc)
221		__machine_desc_end = . ;
222	}
223#ifdef CONFIG_RELOCATABLE
224	. = ALIGN(8);
225	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
226	{
227#ifdef CONFIG_PPC32
228		__dynamic_symtab = .;
229#endif
230		*(.dynsym)
231	}
232	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
233	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
234	{
235		__dynamic_start = .;
236		*(.dynamic)
237	}
238	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
239	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
240	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
241	{
242		__rela_dyn_start = .;
243		*(.rela*)
244	}
245#endif
246	/* .exit.data is discarded at runtime, not link time,
247	 * to deal with references from .exit.text
248	 */
249	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
250		EXIT_DATA
251	}
252
253	/* freed after init ends here */
254	. = ALIGN(PAGE_SIZE);
255	__init_end = .;
256
257/*
258 * And now the various read/write data
259 */
260
261	. = ALIGN(PAGE_SIZE);
262	_sdata = .;
263
264#ifdef CONFIG_PPC32
265	.data : AT(ADDR(.data) - LOAD_OFFSET) {
266		DATA_DATA
267		*(.sdata)
268		*(.got.plt) *(.got)
269	}
270#else
271	.data : AT(ADDR(.data) - LOAD_OFFSET) {
272		DATA_DATA
273		*(.data.rel*)
274		*(.toc1)
275		*(.branch_lt)
276	}
277
278	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
279		*(.opd)
280	}
281
282	. = ALIGN(256);
283	.got : AT(ADDR(.got) - LOAD_OFFSET) {
284		__toc_start = .;
285#ifndef CONFIG_RELOCATABLE
286		__prom_init_toc_start = .;
287		arch/powerpc/kernel/prom_init.o*(.toc .got)
288		__prom_init_toc_end = .;
289#endif
290		*(.got)
291		*(.toc)
292	}
293#endif
294
295	/* The initial task and kernel stack */
296	INIT_TASK_DATA_SECTION(THREAD_SIZE)
297
298	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
299		PAGE_ALIGNED_DATA(PAGE_SIZE)
300	}
301
302	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
303		CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
304	}
305
306	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
307		READ_MOSTLY_DATA(L1_CACHE_BYTES)
308	}
309
310	. = ALIGN(PAGE_SIZE);
311	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
312		NOSAVE_DATA
313	}
314
315	. = ALIGN(PAGE_SIZE);
316	_edata  =  .;
317	PROVIDE32 (edata = .);
318
319/*
320 * And finally the bss
321 */
322
323	BSS_SECTION(0, 0, 0)
324
325	. = ALIGN(PAGE_SIZE);
326	_end = . ;
327	PROVIDE32 (end = .);
328
329	/* Sections to be discarded. */
330	DISCARDS
331}
332