xref: /linux/arch/loongarch/kernel/vmlinux.lds.S (revision 0e0073eb1b60f4ec6faecea034a6772fe1409a88) 
1/* SPDX-License-Identifier: GPL-2.0 */
2#include <linux/sizes.h>
3#include <asm/asm-offsets.h>
4#include <asm/thread_info.h>
5
6#define PAGE_SIZE _PAGE_SIZE
7
8/*
9 * Put .bss..swapper_pg_dir as the first thing in .bss. This will
10 * ensure that it has .bss alignment (64K).
11 */
12#define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
13
14#include <asm-generic/vmlinux.lds.h>
15#include "image-vars.h"
16
17/*
18 * Max avaliable Page Size is 64K, so we set SectionAlignment
19 * field of EFI application to 64K.
20 */
21PECOFF_FILE_ALIGN = 0x200;
22PECOFF_SEGMENT_ALIGN = 0x10000;
23
24OUTPUT_ARCH(loongarch)
25ENTRY(kernel_entry)
26PHDRS {
27	text PT_LOAD FLAGS(7);	/* RWX */
28	note PT_NOTE FLAGS(4);	/* R__ */
29}
30
31jiffies	 = jiffies_64;
32
33SECTIONS
34{
35	. = VMLINUX_LOAD_ADDRESS;
36
37	_text = .;
38	HEAD_TEXT_SECTION
39
40	. = ALIGN(PECOFF_SEGMENT_ALIGN);
41	_stext = .;
42	.text : {
43		TEXT_TEXT
44		SCHED_TEXT
45		CPUIDLE_TEXT
46		LOCK_TEXT
47		KPROBES_TEXT
48		IRQENTRY_TEXT
49		SOFTIRQENTRY_TEXT
50		*(.fixup)
51		*(.gnu.warning)
52	} :text = 0
53	. = ALIGN(PECOFF_SEGMENT_ALIGN);
54	_etext = .;
55
56	EXCEPTION_TABLE(16)
57
58	. = ALIGN(PECOFF_SEGMENT_ALIGN);
59	__init_begin = .;
60	__inittext_begin = .;
61
62	INIT_TEXT_SECTION(PAGE_SIZE)
63	.exit.text : {
64		EXIT_TEXT
65	}
66
67	. = ALIGN(PECOFF_SEGMENT_ALIGN);
68	__inittext_end = .;
69
70	__initdata_begin = .;
71
72	INIT_DATA_SECTION(16)
73	.exit.data : {
74		EXIT_DATA
75	}
76
77#ifdef CONFIG_SMP
78	PERCPU_SECTION(1 << CONFIG_L1_CACHE_SHIFT)
79#endif
80
81	.rela.dyn : ALIGN(8) { *(.rela.dyn) *(.rela*) }
82
83	.init.bss : {
84		*(.init.bss)
85	}
86	. = ALIGN(PECOFF_SEGMENT_ALIGN);
87	__initdata_end = .;
88
89	__init_end = .;
90
91	_sdata = .;
92	RO_DATA(4096)
93	RW_DATA(1 << CONFIG_L1_CACHE_SHIFT, PAGE_SIZE, THREAD_SIZE)
94
95	.sdata : {
96		*(.sdata)
97	}
98	.edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGN); }
99	_edata =  .;
100
101	BSS_SECTION(0, SZ_64K, 8)
102	. = ALIGN(PECOFF_SEGMENT_ALIGN);
103
104	_end = .;
105
106	STABS_DEBUG
107	DWARF_DEBUG
108	ELF_DETAILS
109
110	.gptab.sdata : {
111		*(.gptab.data)
112		*(.gptab.sdata)
113	}
114	.gptab.sbss : {
115		*(.gptab.bss)
116		*(.gptab.sbss)
117	}
118
119	DISCARDS
120	/DISCARD/ : {
121		*(.gnu.attributes)
122		*(.options)
123		*(.eh_frame)
124	}
125}
126