xref: /freebsd/sys/contrib/openzfs/config/zfs-build.m4 (revision a0409676120c1e558d0ade943019934e0f15118d) 
1AC_DEFUN([ZFS_AC_LICENSE], [
2	AC_MSG_CHECKING([zfs author])
3	AC_MSG_RESULT([$ZFS_META_AUTHOR])
4
5	AC_MSG_CHECKING([zfs license])
6	AC_MSG_RESULT([$ZFS_META_LICENSE])
7])
8
9AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
10	DEBUG_CFLAGS="-Werror"
11	DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
12	DEBUG_LDFLAGS=""
13	DEBUG_ZFS="_with_debug"
14	WITH_DEBUG="true"
15	AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
16
17	KERNEL_DEBUG_CFLAGS="-Werror"
18	KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
19])
20
21AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
22	DEBUG_CFLAGS=""
23	DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
24	DEBUG_LDFLAGS=""
25	DEBUG_ZFS="_without_debug"
26	WITH_DEBUG=""
27
28	KERNEL_DEBUG_CFLAGS=""
29	KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
30])
31
32dnl #
33dnl # When debugging is enabled:
34dnl # - Enable all ASSERTs (-DDEBUG)
35dnl # - Promote all compiler warnings to errors (-Werror)
36dnl #
37AC_DEFUN([ZFS_AC_DEBUG], [
38	AC_MSG_CHECKING([whether assertion support will be enabled])
39	AC_ARG_ENABLE([debug],
40		[AS_HELP_STRING([--enable-debug],
41		[Enable compiler and code assertions @<:@default=no@:>@])],
42		[],
43		[enable_debug=no])
44
45	AS_CASE(["x$enable_debug"],
46		["xyes"],
47		[ZFS_AC_DEBUG_ENABLE],
48		["xno"],
49		[ZFS_AC_DEBUG_DISABLE],
50		[AC_MSG_ERROR([Unknown option $enable_debug])])
51
52	AC_SUBST(DEBUG_CFLAGS)
53	AC_SUBST(DEBUG_CPPFLAGS)
54	AC_SUBST(DEBUG_LDFLAGS)
55	AC_SUBST(DEBUG_ZFS)
56	AC_SUBST(WITH_DEBUG)
57
58	AC_SUBST(KERNEL_DEBUG_CFLAGS)
59	AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
60
61	AC_MSG_RESULT([$enable_debug])
62])
63
64AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
65	DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline $NO_IPA_SRA"
66
67	KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline $NO_IPA_SRA"
68	KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
69
70	DEBUGINFO_ZFS="_with_debuginfo"
71])
72
73AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
74	DEBUGINFO_ZFS="_without_debuginfo"
75])
76
77AC_DEFUN([ZFS_AC_DEBUGINFO], [
78	AC_MSG_CHECKING([whether debuginfo support will be forced])
79	AC_ARG_ENABLE([debuginfo],
80		[AS_HELP_STRING([--enable-debuginfo],
81		[Force generation of debuginfo @<:@default=no@:>@])],
82		[],
83		[enable_debuginfo=no])
84
85	AS_CASE(["x$enable_debuginfo"],
86		["xyes"],
87		[ZFS_AC_DEBUGINFO_ENABLE],
88		["xno"],
89		[ZFS_AC_DEBUGINFO_DISABLE],
90		[AC_MSG_ERROR([Unknown option $enable_debuginfo])])
91
92	AC_SUBST(DEBUG_CFLAGS)
93	AC_SUBST(DEBUGINFO_ZFS)
94
95	AC_SUBST(KERNEL_DEBUG_CFLAGS)
96	AC_SUBST(KERNEL_MAKE)
97
98	AC_MSG_RESULT([$enable_debuginfo])
99])
100
101dnl #
102dnl # Disabled by default, provides basic memory tracking.  Track the total
103dnl # number of bytes allocated with kmem_alloc() and freed with kmem_free().
104dnl # Then at module unload time if any bytes were leaked it will be reported
105dnl # on the console.
106dnl #
107AC_DEFUN([ZFS_AC_DEBUG_KMEM], [
108	AC_MSG_CHECKING([whether basic kmem accounting is enabled])
109	AC_ARG_ENABLE([debug-kmem],
110		[AS_HELP_STRING([--enable-debug-kmem],
111		[Enable basic kmem accounting @<:@default=no@:>@])],
112		[],
113		[enable_debug_kmem=no])
114
115	AS_IF([test "x$enable_debug_kmem" = xyes], [
116		KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM"
117		DEBUG_KMEM_ZFS="_with_debug_kmem"
118	], [
119		DEBUG_KMEM_ZFS="_without_debug_kmem"
120	])
121
122	AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
123	AC_SUBST(DEBUG_KMEM_ZFS)
124
125	AC_MSG_RESULT([$enable_debug_kmem])
126])
127
128dnl #
129dnl # Disabled by default, provides detailed memory tracking.  This feature
130dnl # also requires --enable-debug-kmem to be set.  When enabled not only will
131dnl # total bytes be tracked but also the location of every kmem_alloc() and
132dnl # kmem_free().  When the module is unloaded a list of all leaked addresses
133dnl # and where they were allocated will be dumped to the console.  Enabling
134dnl # this feature has a significant impact on performance but it makes finding
135dnl # memory leaks straight forward.
136dnl #
137AC_DEFUN([ZFS_AC_DEBUG_KMEM_TRACKING], [
138	AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
139	AC_ARG_ENABLE([debug-kmem-tracking],
140		[AS_HELP_STRING([--enable-debug-kmem-tracking],
141		[Enable detailed kmem tracking  @<:@default=no@:>@])],
142		[],
143		[enable_debug_kmem_tracking=no])
144
145	AS_IF([test "x$enable_debug_kmem_tracking" = xyes], [
146		KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM_TRACKING"
147		DEBUG_KMEM_TRACKING_ZFS="_with_debug_kmem_tracking"
148	], [
149		DEBUG_KMEM_TRACKING_ZFS="_without_debug_kmem_tracking"
150	])
151
152	AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
153	AC_SUBST(DEBUG_KMEM_TRACKING_ZFS)
154
155	AC_MSG_RESULT([$enable_debug_kmem_tracking])
156])
157
158AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD], [
159	AS_IF([sysctl -n kern.conftxt | fgrep -qx $'options\tINVARIANTS'],
160		[enable_invariants="yes"],
161		[enable_invariants="no"])
162])
163
164AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT], [
165	AM_COND_IF([BUILD_FREEBSD],
166		[ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD],
167		[enable_invariants="no"])
168])
169
170dnl #
171dnl # Detected for the running kernel by default, enables INVARIANTS features
172dnl # in the FreeBSD kernel module.  This feature must be used when building
173dnl # for a FreeBSD kernel with "options INVARIANTS" in the KERNCONF and must
174dnl # not be used when the INVARIANTS option is absent.
175dnl #
176AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS], [
177	AC_MSG_CHECKING([whether FreeBSD kernel INVARIANTS checks are enabled])
178	AC_ARG_ENABLE([invariants],
179		[AS_HELP_STRING([--enable-invariants],
180		[Enable FreeBSD kernel INVARIANTS checks [[default: detect]]])],
181		[], [ZFS_AC_DEBUG_INVARIANTS_DETECT])
182
183	AS_IF([test "x$enable_invariants" = xyes],
184		[WITH_INVARIANTS="true"],
185		[WITH_INVARIANTS=""])
186	AC_SUBST(WITH_INVARIANTS)
187
188	AC_MSG_RESULT([$enable_invariants])
189])
190
191AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
192	AX_COUNT_CPUS([])
193	AC_SUBST(CPU_COUNT)
194
195	ZFS_AC_CONFIG_ALWAYS_CC_NO_UNUSED_BUT_SET_VARIABLE
196	ZFS_AC_CONFIG_ALWAYS_CC_NO_BOOL_COMPARE
197	ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
198	ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
199	ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_ZERO_LENGTH
200	ZFS_AC_CONFIG_ALWAYS_CC_NO_OMIT_FRAME_POINTER
201	ZFS_AC_CONFIG_ALWAYS_CC_NO_IPA_SRA
202	ZFS_AC_CONFIG_ALWAYS_CC_ASAN
203	ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
204	ZFS_AC_CONFIG_ALWAYS_SYSTEM
205	ZFS_AC_CONFIG_ALWAYS_ARCH
206	ZFS_AC_CONFIG_ALWAYS_PYTHON
207	ZFS_AC_CONFIG_ALWAYS_PYZFS
208	ZFS_AC_CONFIG_ALWAYS_SED
209	ZFS_AC_CONFIG_ALWAYS_CPPCHECK
210])
211
212AC_DEFUN([ZFS_AC_CONFIG], [
213
214        dnl # Remove the previous build test directory.
215        rm -Rf build
216
217	ZFS_CONFIG=all
218	AC_ARG_WITH([config],
219		AS_HELP_STRING([--with-config=CONFIG],
220		[Config file 'kernel|user|all|srpm']),
221		[ZFS_CONFIG="$withval"])
222	AC_ARG_ENABLE([linux-builtin],
223		[AS_HELP_STRING([--enable-linux-builtin],
224		[Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
225		[],
226		[enable_linux_builtin=no])
227
228	AC_MSG_CHECKING([zfs config])
229	AC_MSG_RESULT([$ZFS_CONFIG]);
230	AC_SUBST(ZFS_CONFIG)
231
232	ZFS_AC_CONFIG_ALWAYS
233
234	AM_COND_IF([BUILD_LINUX], [
235		AC_ARG_VAR([TEST_JOBS], [simultaneous jobs during configure])
236		if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
237			TEST_JOBS=$CPU_COUNT
238		fi
239		AC_SUBST(TEST_JOBS)
240	])
241
242	case "$ZFS_CONFIG" in
243		kernel) ZFS_AC_CONFIG_KERNEL ;;
244		user)	ZFS_AC_CONFIG_USER   ;;
245		all)    ZFS_AC_CONFIG_USER
246			ZFS_AC_CONFIG_KERNEL ;;
247		srpm)                        ;;
248		*)
249		AC_MSG_RESULT([Error!])
250		AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
251		              user kernel|user|all|srpm]) ;;
252	esac
253
254	AM_CONDITIONAL([CONFIG_USER],
255	    [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
256	AM_CONDITIONAL([CONFIG_KERNEL],
257	    [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
258	    [test "x$enable_linux_builtin" != xyes ])
259	AM_CONDITIONAL([CONFIG_QAT],
260	    [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
261	    [test "x$qatsrc" != x ])
262	AM_CONDITIONAL([WANT_DEVNAME2DEVID], [test "x$user_libudev" = xyes ])
263	AM_CONDITIONAL([WANT_MMAP_LIBAIO], [test "x$user_libaio" = xyes ])
264	AM_CONDITIONAL([PAM_ZFS_ENABLED], [test "x$enable_pam" = xyes])
265])
266
267dnl #
268dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
269dnl # are missing it is non-fatal but you will not be able to build
270dnl # RPM packages and will be warned if you try too.
271dnl #
272dnl # By default the generic spec file will be used because it requires
273dnl # minimal dependencies.  Distribution specific spec files can be
274dnl # placed under the 'rpm/<distribution>' directory and enabled using
275dnl # the --with-spec=<distribution> configure option.
276dnl #
277AC_DEFUN([ZFS_AC_RPM], [
278	RPM=rpm
279	RPMBUILD=rpmbuild
280
281	AC_MSG_CHECKING([whether $RPM is available])
282	AS_IF([tmp=$($RPM --version 2>/dev/null)], [
283		RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
284		HAVE_RPM=yes
285		AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
286	],[
287		HAVE_RPM=no
288		AC_MSG_RESULT([$HAVE_RPM])
289	])
290
291	AC_MSG_CHECKING([whether $RPMBUILD is available])
292	AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
293		RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
294		HAVE_RPMBUILD=yes
295		AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
296	],[
297		HAVE_RPMBUILD=no
298		AC_MSG_RESULT([$HAVE_RPMBUILD])
299	])
300
301	RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
302	RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUGINFO_ZFS) 1"'
303	RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_ZFS) 1"'
304	RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_TRACKING_ZFS) 1"'
305	RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(ASAN_ZFS) 1"'
306
307	RPM_DEFINE_UTIL=' --define "_initconfdir $(initconfdir)"'
308
309	dnl # Make the next three RPM_DEFINE_UTIL additions conditional, since
310	dnl # their values may not be set when running:
311	dnl #
312	dnl #	./configure --with-config=srpm
313	dnl #
314	AS_IF([test -n "$dracutdir" ], [
315		RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_dracutdir $(dracutdir)"'
316	])
317	AS_IF([test -n "$udevdir" ], [
318		RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevdir $(udevdir)"'
319	])
320	AS_IF([test -n "$udevruledir" ], [
321		RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevruledir $(udevruledir)"'
322	])
323	RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_SYSTEMD)'
324	RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYZFS)'
325	RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PAM)'
326	RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_VERSION)'
327	RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_PKG_VERSION)'
328
329	dnl # Override default lib directory on Debian/Ubuntu systems.  The
330	dnl # provided /usr/lib/rpm/platform/<arch>/macros files do not
331	dnl # specify the correct path for multiarch systems as described
332	dnl # by the packaging guidelines.
333	dnl #
334	dnl # https://wiki.ubuntu.com/MultiarchSpec
335	dnl # https://wiki.debian.org/Multiarch/Implementation
336	dnl #
337	AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
338		MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
339		RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_lib $(MULTIARCH_LIBDIR)"'
340		AC_SUBST(MULTIARCH_LIBDIR)
341	])
342
343	dnl # Make RPM_DEFINE_KMOD additions conditional on CONFIG_KERNEL,
344	dnl # since the values will not be set otherwise. The spec files
345	dnl # provide defaults for them.
346	dnl #
347	RPM_DEFINE_KMOD='--define "_wrong_version_format_terminate_build 0"'
348	AM_COND_IF([CONFIG_KERNEL], [
349		RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernels $(LINUX_VERSION)"'
350		RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "ksrc $(LINUX)"'
351		RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kobj $(LINUX_OBJ)"'
352	])
353
354	RPM_DEFINE_DKMS=''
355
356	SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
357	SRPM_DEFINE_UTIL=
358	SRPM_DEFINE_KMOD=
359	SRPM_DEFINE_DKMS=
360
361	RPM_SPEC_DIR="rpm/generic"
362	AC_ARG_WITH([spec],
363		AS_HELP_STRING([--with-spec=SPEC],
364		[Spec files 'generic|redhat']),
365		[RPM_SPEC_DIR="rpm/$withval"])
366
367	AC_MSG_CHECKING([whether spec files are available])
368	AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
369
370	AC_SUBST(HAVE_RPM)
371	AC_SUBST(RPM)
372	AC_SUBST(RPM_VERSION)
373
374	AC_SUBST(HAVE_RPMBUILD)
375	AC_SUBST(RPMBUILD)
376	AC_SUBST(RPMBUILD_VERSION)
377
378	AC_SUBST(RPM_SPEC_DIR)
379	AC_SUBST(RPM_DEFINE_UTIL)
380	AC_SUBST(RPM_DEFINE_KMOD)
381	AC_SUBST(RPM_DEFINE_DKMS)
382	AC_SUBST(RPM_DEFINE_COMMON)
383	AC_SUBST(SRPM_DEFINE_UTIL)
384	AC_SUBST(SRPM_DEFINE_KMOD)
385	AC_SUBST(SRPM_DEFINE_DKMS)
386	AC_SUBST(SRPM_DEFINE_COMMON)
387])
388
389dnl #
390dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
391dnl # tools are missing it is non-fatal but you will not be able to build
392dnl # DEB packages and will be warned if you try too.
393dnl #
394AC_DEFUN([ZFS_AC_DPKG], [
395	DPKG=dpkg
396	DPKGBUILD=dpkg-buildpackage
397
398	AC_MSG_CHECKING([whether $DPKG is available])
399	AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
400		DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
401		HAVE_DPKG=yes
402		AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
403	],[
404		HAVE_DPKG=no
405		AC_MSG_RESULT([$HAVE_DPKG])
406	])
407
408	AC_MSG_CHECKING([whether $DPKGBUILD is available])
409	AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
410		DPKGBUILD_VERSION=$(echo $tmp | \
411		    $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
412		HAVE_DPKGBUILD=yes
413		AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
414	],[
415		HAVE_DPKGBUILD=no
416		AC_MSG_RESULT([$HAVE_DPKGBUILD])
417	])
418
419	AC_SUBST(HAVE_DPKG)
420	AC_SUBST(DPKG)
421	AC_SUBST(DPKG_VERSION)
422
423	AC_SUBST(HAVE_DPKGBUILD)
424	AC_SUBST(DPKGBUILD)
425	AC_SUBST(DPKGBUILD_VERSION)
426])
427
428dnl #
429dnl # Until native packaging for various different packing systems
430dnl # can be added the least we can do is attempt to use alien to
431dnl # convert the RPM packages to the needed package type.  This is
432dnl # a hack but so far it has worked reasonable well.
433dnl #
434AC_DEFUN([ZFS_AC_ALIEN], [
435	ALIEN=alien
436
437	AC_MSG_CHECKING([whether $ALIEN is available])
438	AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
439		ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
440		HAVE_ALIEN=yes
441		AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
442	],[
443		HAVE_ALIEN=no
444		AC_MSG_RESULT([$HAVE_ALIEN])
445	])
446
447	AC_SUBST(HAVE_ALIEN)
448	AC_SUBST(ALIEN)
449	AC_SUBST(ALIEN_VERSION)
450])
451
452dnl #
453dnl # Using the VENDOR tag from config.guess set the default
454dnl # package type for 'make pkg': (rpm | deb | tgz)
455dnl #
456AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
457	AC_MSG_CHECKING([os distribution])
458	AC_ARG_WITH([vendor],
459		[AS_HELP_STRING([--with-vendor],
460			[Distribution vendor @<:@default=check@:>@])],
461		[with_vendor=$withval],
462		[with_vendor=check])
463	AS_IF([test "x$with_vendor" = "xcheck"],[
464		if test -f /etc/toss-release ; then
465			VENDOR=toss ;
466		elif test -f /etc/fedora-release ; then
467			VENDOR=fedora ;
468		elif test -f /etc/redhat-release ; then
469			VENDOR=redhat ;
470		elif test -f /etc/gentoo-release ; then
471			VENDOR=gentoo ;
472		elif test -f /etc/arch-release ; then
473			VENDOR=arch ;
474		elif test -f /etc/SuSE-release ; then
475			VENDOR=sles ;
476		elif test -f /etc/slackware-version ; then
477			VENDOR=slackware ;
478		elif test -f /etc/lunar.release ; then
479			VENDOR=lunar ;
480		elif test -f /etc/lsb-release ; then
481			VENDOR=ubuntu ;
482		elif test -f /etc/debian_version ; then
483			VENDOR=debian ;
484		elif test -f /etc/alpine-release ; then
485			VENDOR=alpine ;
486		elif test -f /bin/freebsd-version ; then
487			VENDOR=freebsd ;
488		else
489			VENDOR= ;
490		fi],
491		[ test "x${with_vendor}" != x],[
492			VENDOR="$with_vendor" ],
493		[ VENDOR= ; ]
494	)
495	AC_MSG_RESULT([$VENDOR])
496	AC_SUBST(VENDOR)
497
498	AC_MSG_CHECKING([default package type])
499	case "$VENDOR" in
500		toss)       DEFAULT_PACKAGE=rpm  ;;
501		redhat)     DEFAULT_PACKAGE=rpm  ;;
502		fedora)     DEFAULT_PACKAGE=rpm  ;;
503		gentoo)     DEFAULT_PACKAGE=tgz  ;;
504		alpine)     DEFAULT_PACKAGE=tgz  ;;
505		arch)       DEFAULT_PACKAGE=tgz  ;;
506		sles)       DEFAULT_PACKAGE=rpm  ;;
507		slackware)  DEFAULT_PACKAGE=tgz  ;;
508		lunar)      DEFAULT_PACKAGE=tgz  ;;
509		ubuntu)     DEFAULT_PACKAGE=deb  ;;
510		debian)     DEFAULT_PACKAGE=deb  ;;
511		freebsd)    DEFAULT_PACKAGE=pkg  ;;
512		*)          DEFAULT_PACKAGE=rpm  ;;
513	esac
514	AC_MSG_RESULT([$DEFAULT_PACKAGE])
515	AC_SUBST(DEFAULT_PACKAGE)
516
517	AC_MSG_CHECKING([default init directory])
518	case "$VENDOR" in
519		freebsd)    initdir=$sysconfdir/rc.d  ;;
520		*)          initdir=$sysconfdir/init.d;;
521	esac
522	AC_MSG_RESULT([$initdir])
523	AC_SUBST(initdir)
524
525	AC_MSG_CHECKING([default init script type and shell])
526	case "$VENDOR" in
527		toss)       DEFAULT_INIT_SCRIPT=redhat ;;
528		redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
529		fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
530		gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
531		alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
532		arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
533		sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
534		slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
535		lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
536		ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
537		debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
538		freebsd)    DEFAULT_INIT_SCRIPT=freebsd;;
539		*)          DEFAULT_INIT_SCRIPT=lsb    ;;
540	esac
541
542	# On gentoo, it's possible that OpenRC isn't installed.  Check if
543	# /sbin/openrc-run exists, and if not, fall back to generic defaults.
544
545	DEFAULT_INIT_SHELL="/bin/sh"
546	AS_IF([test "$DEFAULT_INIT_SCRIPT" = "openrc"], [
547		AS_IF([test -x "/sbin/openrc-run"],
548			[DEFAULT_INIT_SHELL="/sbin/openrc-run"],
549			[DEFAULT_INIT_SCRIPT=lsb])
550	])
551
552	AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT:$DEFAULT_INIT_SHELL])
553	AC_SUBST(DEFAULT_INIT_SCRIPT)
554	AC_SUBST(DEFAULT_INIT_SHELL)
555
556	AC_MSG_CHECKING([default nfs server init script])
557	AS_IF([test "$VENDOR" = "debian"],
558		[DEFAULT_INIT_NFS_SERVER="nfs-kernel-server"],
559		[DEFAULT_INIT_NFS_SERVER="nfs"]
560	)
561	AC_MSG_RESULT([$DEFAULT_INIT_NFS_SERVER])
562	AC_SUBST(DEFAULT_INIT_NFS_SERVER)
563
564	AC_MSG_CHECKING([default init config directory])
565	case "$VENDOR" in
566		alpine)     initconfdir=/etc/conf.d    ;;
567		gentoo)     initconfdir=/etc/conf.d    ;;
568		toss)       initconfdir=/etc/sysconfig ;;
569		redhat)     initconfdir=/etc/sysconfig ;;
570		fedora)     initconfdir=/etc/sysconfig ;;
571		sles)       initconfdir=/etc/sysconfig ;;
572		ubuntu)     initconfdir=/etc/default   ;;
573		debian)     initconfdir=/etc/default   ;;
574		freebsd)    initconfdir=$sysconfdir/rc.conf.d;;
575		*)          initconfdir=/etc/default   ;;
576	esac
577	AC_MSG_RESULT([$initconfdir])
578	AC_SUBST(initconfdir)
579
580	AC_MSG_CHECKING([whether initramfs-tools is available])
581	if test -d /usr/share/initramfs-tools ; then
582		RPM_DEFINE_INITRAMFS='--define "_initramfs 1"'
583		AC_MSG_RESULT([yes])
584	else
585		RPM_DEFINE_INITRAMFS=''
586		AC_MSG_RESULT([no])
587	fi
588	AC_SUBST(RPM_DEFINE_INITRAMFS)
589])
590
591dnl #
592dnl # Default ZFS package configuration
593dnl #
594AC_DEFUN([ZFS_AC_PACKAGE], [
595	ZFS_AC_DEFAULT_PACKAGE
596	AS_IF([test x$VENDOR != xfreebsd], [
597		ZFS_AC_RPM
598		ZFS_AC_DPKG
599		ZFS_AC_ALIEN
600	])
601])
602