xref: /freebsd/contrib/bmake/configure.in (revision ca53e5aedfebcc1b4091b68e01b2d5cae923f85e) 
1dnl
2dnl RCSid:
3dnl	$Id: configure.in,v 1.69 2020/11/14 07:40:43 sjg Exp $
4dnl
5dnl Process this file with autoconf to produce a configure script
6dnl
7AC_PREREQ(2.50)
8AC_INIT([bmake], [20201112], [sjg@NetBSD.org])
9AC_CONFIG_HEADERS(config.h)
10
11dnl make srcdir absolute
12case "$srcdir" in
13/*) ;;
14*) srcdir=`cd $srcdir && pwd`;;
15esac
16
17dnl get _MAKE_VERSION
18. $srcdir/VERSION
19OS=`uname -s`
20
21dnl
22AC_ARG_WITH(defshell,
23[  --with-defshell=SHELL  use SHELL by default - must be sh compatible, use sh or ksh to pick the internal definitions],
24[case "${withval}" in
25yes)   AC_MSG_ERROR(bad value ${withval} given for bmake DEFSHELL) ;;
26no)    ;;
27*)     case "$with_defshell" in
28       sh)  DEFSHELL_INDEX=DEFSHELL_INDEX_SH;;	# it's the default anyway
29       ksh) DEFSHELL_INDEX=DEFSHELL_INDEX_KSH;;
30       csh) DEFSHELL_INDEX=DEFSHELL_INDEX_CSH;;	# kidding right?
31       *)   defshell_path=$with_defshell;;	# better be sh compatible!
32       esac
33       ;;
34       esac])
35dnl
36case "$OS" in
37CYGWIN*|MINGW*) use_makefile=no;;
38*) use_makefile=yes;;
39esac
40AC_ARG_WITH(makefile,
41[  --without-makefile disable use of generated makefile],
42[case "${withval}" in
43yes|no) use_makefile=${withval};;
44*) AC_MSG_ERROR(bad value ${withval} given for makefile) ;;
45esac])
46dnl
47use_meta=yes
48AC_ARG_WITH(meta,
49[  --without-meta disable use of meta-mode],
50[case "${withval}" in
51yes|no) use_meta=${withval};;
52*) AC_MSG_ERROR(bad value ${withval} given for meta) ;;
53esac])
54dnl
55AC_ARG_WITH(filemon,
56[  --with-filemon={no,dev,ktrace,path/filemon.h} indicate filemon method for meta-mode. Path to filemon.h implies dev],
57[ case "/${withval}" in
58/no) use_filemon=no;;
59/*trace) filemon_h=no use_filemon="${withval}";;
60*/filemon.h) filemon_h="${withval}";;
61*/filemon*) filemon_h="${withval}/filemon.h";;
62*) AC_MSG_ERROR(bad value ${withval} given for filemon) ;;
63esac
64case "$use_filemon,$filemon_h" in
65,*.h) use_filemon=dev;;
66esac
67],
68[
69case "$OS" in
70NetBSD) filemon_h=no use_filemon=ktrace;;
71*)
72    for d in "/usr/include/dev/filemon" "$prefix/include/dev/filemon" "$srcdir/../../sys/dev/filemon"
73    do
74        for x in "/$OS" ""
75        do
76            filemon_h="$d$x/filemon.h"
77            test -s "$filemon_h" && break
78        done
79        test -s "$filemon_h" && { use_filemon=dev; break; }
80    done
81    ;;
82esac
83use_filemon=${use_filemon:-no}
84case "$use_filemon" in
85dev) ;;
86*) filemon_h=no;;
87esac
88])
89dnl echo "Note: use_meta=$use_meta use_filemon=$use_filemon filemon_h=$filemon_h" >&6
90case "$use_meta" in
91yes)
92	case "$use_filemon" in
93	no) ;;
94	*) echo "Using: filemon_${use_filemon}.c" >&6;;
95	esac
96	;;
97esac
98dnl
99dnl Check for OS problems
100dnl Solaris's signal.h only privides sigset_t etc if one of
101dnl _EXTENSIONS_ _POSIX_C_SOURCE or _XOPEN_SOURCE are defined.
102dnl The later two seem to cause more problems than they solve so if we
103dnl see _EXTENSIONS_ we use it.
104AC_USE_SYSTEM_EXTENSIONS
105dnl Checks for programs.
106AC_PROG_CC
107AC_PROG_CC_C99
108dnl AC_PROG_GCC_TRADITIONAL
109AC_PROG_INSTALL
110dnl Executable suffix - normally empty; .exe on os2.
111AC_SUBST(ac_exe_suffix)dnl
112dnl
113dnl Hurd refuses to define PATH_MAX or MAXPATHLEN
114if test -x /usr/bin/getconf; then
115   bmake_path_max=`getconf PATH_MAX / 2> /dev/null`
116   # only a numeric response is useful
117   test ${bmake_path_max:-0} -gt 0 2> /dev/null || bmake_path_max=
118fi
119bmake_path_max=${bmake_path_max:-1024}
120if test $bmake_path_max -gt 1024; then
121   # this is all we expect
122   bmake_path_max=1024
123fi
124echo "Using: BMAKE_PATH_MAX=$bmake_path_max" >&6
125AC_SUBST(bmake_path_max)dnl
126dnl
127dnl AC_C_CROSS
128dnl
129
130dnl Checks for header files.
131AC_HEADER_SYS_WAIT
132AC_HEADER_DIRENT
133dnl Keep this list sorted
134AC_CHECK_HEADERS(sys/param.h)
135dnl On BSDi at least we really need sys/param.h for sys/sysctl.h
136AC_CHECK_HEADERS([sys/sysctl.h], [], [],
137[#ifdef HAVE_SYS_PARAM_H
138# include <sys/param.h>
139# endif
140])
141
142AC_CHECK_HEADERS( \
143	ar.h \
144	err.h \
145	fcntl.h \
146	libgen.h \
147	limits.h \
148	paths.h \
149	poll.h \
150	ranlib.h \
151	sys/mman.h \
152	sys/select.h \
153	sys/socket.h \
154	sys/time.h \
155	sys/uio.h \
156	utime.h \
157	)
158
159dnl Both *BSD and Linux have sys/cdefs.h, most do not.
160dnl If it is missing, we add -I${srcdir}/missing to CFLAGS
161dnl also if sys/cdefs.h does not have __RCSID we need to use ours
162dnl but we need to include the host's one too *sigh*
163AC_CHECK_HEADER(sys/cdefs.h,
164echo $ECHO_N "checking whether sys/cdefs.h is compatible... $ECHO_C" >&6
165AC_EGREP_CPP(yes,
166[#include <sys/cdefs.h>
167#ifdef __RCSID
168yes
169#endif
170],
171echo yes  >&6,
172echo no  >&6; CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd` -DNEED_HOST_CDEFS_H"),
173CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd`")
174
175dnl Checks for typedefs, structures, and compiler characteristics.
176AC_C___ATTRIBUTE__
177AC_C_BIGENDIAN
178AC_C_CONST
179AC_TYPE_MODE_T
180AC_TYPE_OFF_T
181AC_TYPE_PID_T
182AC_TYPE_SIZE_T
183AC_TYPE_UINT32_T
184AC_DECL_SYS_SIGLIST
185AC_HEADER_TIME
186AC_STRUCT_TM
187
188dnl Checks for library functions.
189AC_TYPE_SIGNAL
190AC_FUNC_VFORK
191AC_FUNC_VPRINTF
192AC_FUNC_WAIT3
193dnl Keep this list sorted
194AC_CHECK_FUNCS( \
195	err \
196	errx \
197	getcwd \
198	getenv \
199	getopt \
200	getwd \
201	killpg \
202	mmap \
203	putenv \
204	select \
205	setenv \
206	setpgid \
207	setsid \
208	sigaction \
209	sigvec \
210	snprintf \
211	strerror \
212	strftime \
213	strsep \
214	strtod \
215	strtol \
216	sysctl \
217	unsetenv \
218	vsnprintf \
219	wait3 \
220	wait4 \
221	waitpid \
222	warn \
223	warnx \
224	)
225
226dnl functions which we may need to provide
227AC_REPLACE_FUNCS( \
228	realpath \
229	dirname \
230	stresep \
231	strlcpy \
232	)
233
234AC_CHECK_LIB([util], [emalloc],
235    [ AC_CHECK_LIB([util], [erealloc],
236      [ AC_CHECK_LIB([util], [estrdup],
237        [ AC_CHECK_LIB([util], [estrndup],
238	  [ LIBS="$LIBS -lutil"
239	    CPPFLAGS="$CPPFLAGS -DUSE_EMALLOC" ])])])])
240
241dnl
242dnl Structures
243dnl
244AC_HEADER_STAT
245AC_STRUCT_ST_RDEV
246dnl
247echo "checking if compiler supports __func__" >&6
248AC_LANG(C)
249AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[[const char *func = __func__;]])],,
250	AC_DEFINE(__func__, __FUNCTION__, C99 function name))
251dnl
252dnl we want this for unit-tests/Makefile
253echo $ECHO_N "checking if diff -u works... $ECHO_C" >&6
254if diff -u /dev/null /dev/null > /dev/null 2>&1; then
255   diff_u=-u
256   echo yes >&6
257else
258   diff_u=
259   echo no >&6
260fi
261dnl
262dnl AC_* don't quite cut it.
263dnl
264echo "checking for MACHINE & MACHINE_ARCH..." >&6
265cat > conftest.$ac_ext <<EOF
266#include "confdefs.h"
267#include <sys/param.h>
268#ifdef MACHINE
269machine=MACHINE
270#endif
271#ifdef MACHINE_ARCH
272machine_arch=MACHINE_ARCH
273#endif
274EOF
275
276default_machine=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 |
277	egrep machine= | tr -d ' "'`
278rm -rf conftest*
279if test "$default_machine"; then
280	eval "$default_machine"
281fi
282machine=${machine:-`$srcdir/machine.sh`}
283machine_arch=${machine_arch:-`$srcdir/machine.sh arch`}
284echo "defaults: MACHINE=$machine, MACHINE_ARCH=$machine_arch" 1>&6
285dnl
286dnl now allow overrides
287dnl
288AC_ARG_WITH(machine,
289[  --with-machine=MACHINE  explicitly set MACHINE],
290[case "${withval}" in
291yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE) ;;
292no)    ;;
293generic) machine=`$srcdir/machine.sh`;;
294*)     machine=$with_machine;;
295esac])
296force_machine=
297AC_ARG_WITH(force_machine,
298[  --with-force-machine=MACHINE  set FORCE_MACHINE],
299[case "${withval}" in
300yes)   force_machine=FORCE_;;
301no)    ;;
302*)     force_machine=FORCE_; machine=$with_force_machine;;
303esac])
304dnl
305force_machine_arch=
306AC_ARG_WITH(force_machine_arch,
307[  --with-force-machine-arch=MACHINE  set FORCE_MACHINE_ARCH],
308[case "${withval}" in
309yes)   force_machine_arch=FORCE_;;
310no)    ;;
311*)     force_machine_arch=FORCE_; machine_arch=$with_force_machine_arch;;
312esac])
313dnl
314AC_ARG_WITH(machine_arch,
315[  --with-machine_arch=MACHINE_ARCH  explicitly set MACHINE_ARCH],
316[case "${withval}" in
317yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE_ARCH) ;;
318no)    ;;
319*)     machine_arch=$with_machine_arch;;
320esac])
321dnl
322dnl Tell them what we ended up with
323dnl
324echo "Using: ${force_machine}MACHINE=$machine, ${force_machine_arch}MACHINE_ARCH=$machine_arch" 1>&6
325dnl
326dnl Allow folk to control _PATH_DEFSYSPATH
327dnl
328default_sys_path=\${prefix}/share/mk
329AC_ARG_WITH(default-sys-path,
330[  --with-default-sys-path=PATH:DIR:LIST  use an explicit _PATH_DEFSYSPATH
331	MAKESYSPATH is a ':' separated list of directories
332	that bmake will search for system .mk files.
333	_PATH_DEFSYSPATH is its default value.],
334[case "${withval}" in
335yes)	AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_DEFSYSPATH) ;;
336no)	;;
337*)	default_sys_path="$with_default_sys_path"
338	;;
339esac])
340dnl
341dnl Some folk don't like this one
342dnl
343AC_ARG_WITH(path-objdirprefix,
344[  --with-path-objdirprefix=PATH  override _PATH_OBJDIRPREFIX],
345[case "${withval}" in
346yes)   AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_OBJDIRPREFIX) ;;
347no)    CPPFLAGS="$CPPFLAGS -DNO_PATH_OBJDIRPREFIX" ;;
348*)     CPPFLAGS="$CPPFLAGS \"-D_PATH_OBJDIRPREFIX=\\\"$with_path-objdir\\\"\"" ;;
349esac])
350dnl
351dnl And this can be handy to do with out.
352dnl
353AC_ARG_ENABLE(pwd-override,
354[  --disable-pwd-override  disable $PWD overriding getcwd()],
355[case "${enableval}" in
356yes)   ;;
357no)    CPPFLAGS="$CPPFLAGS -DNO_PWD_OVERRIDE" ;;
358*)     AC_MSG_ERROR(bad value ${enableval} given for pwd-override option) ;;
359esac])
360dnl
361dnl Just for grins
362dnl
363AC_ARG_ENABLE(check-make-chdir,
364[  --disable-check-make-chdir disable make trying to guess
365	when it should automatically cd ${.CURDIR}],
366[case "${enableval}" in
367yes)   ;;
368no)    CPPFLAGS="$CPPFLAGS -DNO_CHECK_MAKE_CHDIR" ;;
369*)     AC_MSG_ERROR(bad value ${enableval} given for check-make-chdir option) ;;
370esac])
371dnl
372dnl On non-BSD systems, bootstrap won't work without mk
373dnl
374AC_ARG_WITH(mksrc,
375[  --with-mksrc=PATH tell makefile.boot where to find mk src],
376[case "${withval}" in
377""|yes|no) ;;
378*) test -s $withval/install-mk && mksrc=$withval ||
379AC_MSG_ERROR(bad value ${withval} given for mksrc cannot find install-mk)
380;;
381esac
382])
383dnl
384dnl Now make sure we have a value
385dnl
386srcdir=`cd $srcdir && pwd`
387for mksrc in $mksrc $srcdir/mk $srcdir/../mk mk
388do
389	test -s $mksrc/install-mk || continue
390	mksrc=`cd $mksrc && pwd`
391	break
392done
393mksrc=`echo $mksrc | sed "s,$srcdir,\\\${srcdir},"`
394echo "Using: MKSRC=$mksrc" 1>&6
395dnl On some systems we want a different default shell by default
396if test -x /usr/xpg4/bin/sh; then
397        defshell_path=${defshell_path:-/usr/xpg4/bin/sh}
398fi
399if test -n "$defshell_path"; then
400	echo "Using: SHELL=$defshell_path"  >&6
401	AC_DEFINE_UNQUOTED(DEFSHELL_CUSTOM, "$defshell_path", Path of default shell)
402fi
403if test -n "$DEFSHELL_INDEX"; then
404       AC_DEFINE_UNQUOTED(DEFSHELL_INDEX, $DEFSHELL_INDEX, Shell spec to use by default)
405fi
406dnl
407AC_SUBST(machine)
408AC_SUBST(force_machine)
409AC_SUBST(machine_arch)
410AC_SUBST(force_machine_arch)
411AC_SUBST(mksrc)
412AC_SUBST(default_sys_path)
413AC_SUBST(INSTALL)
414AC_SUBST(GCC)
415AC_SUBST(diff_u)
416AC_SUBST(use_meta)
417AC_SUBST(use_filemon)
418AC_SUBST(filemon_h)
419AC_SUBST(_MAKE_VERSION)
420bm_outfiles="Makefile.config unit-tests/Makefile.config make-bootstrap.sh"
421if test $use_makefile = yes; then
422   bm_outfiles="makefile $bm_outfiles"
423fi
424AC_OUTPUT($bm_outfiles)
425cat <<EOF
426
427You can now run
428
429	sh ./make-bootstrap.sh
430
431to produce a fully functional bmake.
432
433EOF
434