xref: /freebsd/contrib/bmake/configure.in (revision 2ed3236082a4473c1da8f72c1ebc071a7b54321f) 
1dnl
2dnl RCSid:
3dnl	$Id: configure.in,v 1.66 2020/07/10 16:34:38 sjg Exp $
4dnl
5dnl Process this file with autoconf to produce a configure script
6dnl
7AC_PREREQ(2.50)
8AC_INIT([bmake], [20200710], [sjg@NetBSD.org])
9AC_CONFIG_HEADERS(config.h)
10
11dnl make srcdir absolute
12case "$srcdir" in
13/*) ;;
14*) srcdir=`cd $srcdir && pwd`;;
15esac
16
17dnl get _MAKE_VERSION
18. $srcdir/VERSION
19OS=`uname -s`
20
21dnl
22AC_ARG_WITH(defshell,
23[  --with-defshell=SHELL  use SHELL by default - must be sh compatible, use sh or ksh to pick the internal definitions],
24[case "${withval}" in
25yes)   AC_MSG_ERROR(bad value ${withval} given for bmake DEFSHELL) ;;
26no)    ;;
27*)     case "$with_defshell" in
28       sh)  DEFSHELL_INDEX=DEFSHELL_INDEX_SH;;	# it's the default anyway
29       ksh) DEFSHELL_INDEX=DEFSHELL_INDEX_KSH;;
30       csh) DEFSHELL_INDEX=DEFSHELL_INDEX_CSH;;	# kidding right?
31       *)   defshell_path=$with_defshell;;	# better be sh compatible!
32       esac
33       ;;
34       esac])
35dnl
36case "$OS" in
37CYGWIN*|MINGW*) use_makefile=no;;
38*) use_makefile=yes;;
39esac
40AC_ARG_WITH(makefile,
41[ --without-makefile dissable use of generated makefile],
42[case "${withval}" in
43yes|no) use_makefile=${withval};;
44*) AC_MSG_ERROR(bad value ${withval} given for makefile) ;;
45esac])
46dnl
47use_meta=yes
48AC_ARG_WITH(meta,
49[ --without-meta dissable use of meta-mode],
50[case "${withval}" in
51yes|no) use_meta=${withval};;
52*) AC_MSG_ERROR(bad value ${withval} given for meta) ;;
53esac])
54dnl
55AC_ARG_WITH(filemon,
56[ --with-filemon={no,dev,ktrace,path/filemon.h} indicate filemon method for meta-mode. Path to filemon.h implies dev],
57[ case "/${withval}" in
58/no) use_filemon=no;;
59/*trace) filemon_h=no use_filemon="${withval}";;
60*/filemon.h) filemon_h="${withval}";;
61*/filemon*) filemon_h="${withval}/filemon.h";;
62*) AC_MSG_ERROR(bad value ${withval} given for filemon) ;;
63esac
64case "$use_filemon,$filemon_h" in
65,*.h) use_filemon=dev;;
66esac
67],
68[
69case "$OS" in
70NetBSD) filemon_h=no use_filemon=ktrace;;
71*)
72    for d in "/usr/include/dev/filemon" "$prefix/include/dev/filemon" "$srcdir/../../sys/dev/filemon"
73    do
74        for x in "/$OS" ""
75        do
76            filemon_h="$d$x/filemon.h"
77            test -s "$filemon_h" && break
78        done
79        test -s "$filemon_h" && { use_filemon=dev; break; }
80    done
81    ;;
82esac
83use_filemon=${use_filemon:-no}
84case "$use_filemon" in
85dev) ;;
86*) filemon_h=no;;
87esac
88])
89dnl echo "Note: use_meta=$use_meta use_filemon=$use_filemon filemon_h=$filemon_h" >&6
90case "$use_meta" in
91yes)
92	case "$use_filemon" in
93	no) ;;
94	*) echo "Using: filemon_${use_filemon}.c" >&6;;
95	esac
96	;;
97esac
98dnl
99dnl Check for OS problems
100dnl Solaris's signal.h only privides sigset_t etc if one of
101dnl _EXTENSIONS_ _POSIX_C_SOURCE or _XOPEN_SOURCE are defined.
102dnl The later two seem to cause more problems than they solve so if we
103dnl see _EXTENSIONS_ we use it.
104AC_USE_SYSTEM_EXTENSIONS
105dnl Checks for programs.
106AC_PROG_CC
107AC_PROG_CC_C99
108dnl AC_PROG_GCC_TRADITIONAL
109AC_PROG_INSTALL
110dnl Executable suffix - normally empty; .exe on os2.
111AC_SUBST(ac_exe_suffix)dnl
112dnl
113dnl Hurd refuses to define PATH_MAX or MAXPATHLEN
114if test -x /usr/bin/getconf; then
115   bmake_path_max=`getconf PATH_MAX / 2> /dev/null`
116   # only a numeric response is useful
117   test ${bmake_path_max:-0} -gt 0 2> /dev/null || bmake_path_max=
118fi
119bmake_path_max=${bmake_path_max:-1024}
120if test $bmake_path_max -gt 1024; then
121   # this is all we expect
122   bmake_path_max=1024
123fi
124echo "Using: BMAKE_PATH_MAX=$bmake_path_max" >&6
125AC_SUBST(bmake_path_max)dnl
126dnl
127dnl AC_C_CROSS
128dnl
129
130dnl Checks for header files.
131AC_INCLUDES_DEFAULT
132AC_HEADER_SYS_WAIT
133AC_HEADER_DIRENT
134dnl Keep this list sorted
135AC_CHECK_HEADERS(sys/param.h)
136dnl On BSDi at least we really need sys/param.h for sys/sysctl.h
137AC_CHECK_HEADERS([sys/sysctl.h], [], [],
138[#ifdef HAVE_SYS_PARAM_H
139# include <sys/param.h>
140# endif
141])
142
143AC_CHECK_HEADERS( \
144	ar.h \
145	err.h \
146	fcntl.h \
147	libgen.h \
148	limits.h \
149	paths.h \
150	poll.h \
151	ranlib.h \
152	sys/mman.h \
153	sys/select.h \
154	sys/socket.h \
155	sys/time.h \
156	sys/uio.h \
157	utime.h \
158	)
159
160dnl Both *BSD and Linux have sys/cdefs.h, most do not.
161dnl If it is missing, we add -I${srcdir}/missing to CFLAGS
162dnl also if sys/cdefs.h does not have __RCSID we need to use ours
163dnl but we need to include the host's one too *sigh*
164AC_CHECK_HEADER(sys/cdefs.h,
165echo $ECHO_N "checking whether sys/cdefs.h is compatible... $ECHO_C" >&6
166AC_EGREP_CPP(yes,
167[#include <sys/cdefs.h>
168#ifdef __RCSID
169yes
170#endif
171],
172echo yes  >&6,
173echo no  >&6; CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd` -DNEED_HOST_CDEFS_H"),
174CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd`")
175
176dnl Checks for typedefs, structures, and compiler characteristics.
177AC_C___ATTRIBUTE__
178AC_C_BIGENDIAN
179AC_C_CONST
180AC_TYPE_MODE_T
181AC_TYPE_OFF_T
182AC_TYPE_PID_T
183AC_TYPE_SIZE_T
184AC_TYPE_UINT32_T
185AC_DECL_SYS_SIGLIST
186AC_HEADER_TIME
187AC_STRUCT_TM
188
189dnl Checks for library functions.
190AC_TYPE_SIGNAL
191AC_FUNC_VFORK
192AC_FUNC_VPRINTF
193AC_FUNC_WAIT3
194dnl Keep this list sorted
195AC_CHECK_FUNCS( \
196	err \
197	errx \
198	getcwd \
199	getenv \
200	getopt \
201	getwd \
202	killpg \
203	mmap \
204	putenv \
205	select \
206	setenv \
207	setpgid \
208	setsid \
209	sigaction \
210	sigvec \
211	snprintf \
212	strerror \
213	strftime \
214	strsep \
215	strtod \
216	strtol \
217	sysctl \
218	unsetenv \
219	vsnprintf \
220	wait3 \
221	wait4 \
222	waitpid \
223	warn \
224	warnx \
225	)
226
227dnl functions which we may need to provide
228AC_REPLACE_FUNCS( \
229	realpath \
230	dirname \
231	stresep \
232	strlcpy \
233	)
234
235AC_CHECK_LIB([util], [emalloc],
236    [ AC_CHECK_LIB([util], [erealloc],
237      [ AC_CHECK_LIB([util], [estrdup],
238        [ AC_CHECK_LIB([util], [estrndup],
239	  [ LIBS="$LIBS -lutil"
240	    CPPFLAGS="$CPPFLAGS -DUSE_EMALLOC" ])])])])
241
242dnl
243dnl Structures
244dnl
245AC_HEADER_STAT
246AC_STRUCT_ST_RDEV
247dnl
248echo "checking if compiler supports __func__" >&6
249AC_LANG(C)
250AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[[const char *func = __func__;]])],,
251	AC_DEFINE(__func__, __FUNCTION__, C99 function name))
252dnl
253dnl we want this for unit-tests/Makefile
254echo $ECHO_N "checking if diff -u works... $ECHO_C" >&6
255if diff -u /dev/null /dev/null > /dev/null 2>&1; then
256   diff_u=-u
257   echo yes >&6
258else
259   diff_u=
260   echo no >&6
261fi
262dnl
263dnl AC_* don't quite cut it.
264dnl
265echo "checking for MACHINE & MACHINE_ARCH..." >&6
266cat > conftest.$ac_ext <<EOF
267#include "confdefs.h"
268#include <sys/param.h>
269#ifdef MACHINE
270machine=MACHINE
271#endif
272#ifdef MACHINE_ARCH
273machine_arch=MACHINE_ARCH
274#endif
275EOF
276
277default_machine=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 |
278	egrep machine= | tr -d ' "'`
279rm -rf conftest*
280if test "$default_machine"; then
281	eval "$default_machine"
282fi
283machine=${machine:-`$srcdir/machine.sh`}
284machine_arch=${machine_arch:-`$srcdir/machine.sh arch`}
285echo "defaults: MACHINE=$machine, MACHINE_ARCH=$machine_arch" 1>&6
286dnl
287dnl now allow overrides
288dnl
289AC_ARG_WITH(machine,
290[  --with-machine=MACHINE  explicitly set MACHINE],
291[case "${withval}" in
292yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE) ;;
293no)    ;;
294generic) machine=`$srcdir/machine.sh`;;
295*)     machine=$with_machine;;
296esac])
297force_machine=
298AC_ARG_WITH(force_machine,
299[  --with-force-machine=MACHINE  set FORCE_MACHINE],
300[case "${withval}" in
301yes)   force_machine=FORCE_;;
302no)    ;;
303*)     force_machine=FORCE_; machine=$with_force_machine;;
304esac])
305dnl
306force_machine_arch=
307AC_ARG_WITH(force_machine_arch,
308[  --with-force-machine-arch=MACHINE  set FORCE_MACHINE_ARCH],
309[case "${withval}" in
310yes)   force_machine_arch=FORCE_;;
311no)    ;;
312*)     force_machine_arch=FORCE_; machine_arch=$with_force_machine;;
313esac])
314dnl
315AC_ARG_WITH(machine_arch,
316[  --with-machine_arch=MACHINE_ARCH  explicitly set MACHINE_ARCH],
317[case "${withval}" in
318yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE_ARCH) ;;
319no)    ;;
320*)     machine_arch=$with_machine_arch;;
321esac])
322dnl
323dnl Tell them what we ended up with
324dnl
325echo "Using: ${force_machine}MACHINE=$machine, MACHINE_ARCH=$machine_arch" 1>&6
326dnl
327dnl Allow folk to control _PATH_DEFSYSPATH
328dnl
329default_sys_path=\${prefix}/share/mk
330AC_ARG_WITH(default-sys-path,
331[  --with-default-sys-path=PATH:DIR:LIST  use an explicit _PATH_DEFSYSPATH
332	MAKESYSPATH is a ':' separated list of directories
333	that bmake will search for system .mk files.
334	_PATH_DEFSYSPATH is its default value.],
335[case "${withval}" in
336yes)	AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_DEFSYSPATH) ;;
337no)	;;
338*)	default_sys_path="$with_default_sys_path"
339	;;
340esac])
341dnl
342dnl Some folk don't like this one
343dnl
344AC_ARG_WITH(path-objdirprefix,
345[  --with-path-objdirprefix=PATH  override _PATH_OBJDIRPREFIX],
346[case "${withval}" in
347yes)   AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_OBJDIRPREFIX) ;;
348no)    CPPFLAGS="$CPPFLAGS -DNO_PATH_OBJDIRPREFIX" ;;
349*)     CPPFLAGS="$CPPFLAGS \"-D_PATH_OBJDIRPREFIX=\\\"$with_path-objdir\\\"\"" ;;
350esac])
351dnl
352dnl And this can be handy to do with out.
353dnl
354AC_ARG_ENABLE(pwd-override,
355[  --disable-pwd-override  disable \$PWD overriding getcwd()],
356[case "${enableval}" in
357yes)   ;;
358no)    CPPFLAGS="$CPPFLAGS -DNO_PWD_OVERRIDE" ;;
359*)     AC_MSG_ERROR(bad value ${enableval} given for pwd-override option) ;;
360esac])
361dnl
362dnl Just for grins
363dnl
364AC_ARG_ENABLE(check-make-chdir,
365[  --disable-check-make-chdir disable make trying to guess
366	when it should automatically cd \${.CURDIR}],
367[case "${enableval}" in
368yes)   ;;
369no)    CPPFLAGS="$CPPFLAGS -DNO_CHECK_MAKE_CHDIR" ;;
370*)     AC_MSG_ERROR(bad value ${enableval} given for check-make-chdir option) ;;
371esac])
372dnl
373dnl On non-BSD systems, bootstrap won't work without mk
374dnl
375AC_ARG_WITH(mksrc,
376[  --with-mksrc=PATH tell makefile.boot where to find mk src],
377[case "${withval}" in
378""|yes|no) ;;
379*) test -s $withval/install-mk && mksrc=$withval ||
380AC_MSG_ERROR(bad value ${withval} given for mksrc cannot find install-mk)
381;;
382esac
383])
384dnl
385dnl Now make sure we have a value
386dnl
387srcdir=`cd $srcdir && pwd`
388for mksrc in $mksrc $srcdir/mk $srcdir/../mk mk
389do
390	test -s $mksrc/install-mk || continue
391	mksrc=`cd $mksrc && pwd`
392	break
393done
394mksrc=`echo $mksrc | sed "s,$srcdir,\\\${srcdir},"`
395echo "Using: MKSRC=$mksrc" 1>&6
396dnl On some systems we want a different default shell by default
397if test -x /usr/xpg4/bin/sh; then
398        defshell_path=${defshell_path:-/usr/xpg4/bin/sh}
399fi
400if test -n "$defshell_path"; then
401	echo "Using: SHELL=$defshell_path"  >&6
402	AC_DEFINE_UNQUOTED(DEFSHELL_CUSTOM, "$defshell_path", Path of default shell)
403fi
404if test -n "$DEFSHELL_INDEX"; then
405       AC_DEFINE_UNQUOTED(DEFSHELL_INDEX, $DEFSHELL_INDEX, Shell spec to use by default)
406fi
407dnl
408AC_SUBST(machine)
409AC_SUBST(force_machine)
410AC_SUBST(machine_arch)
411AC_SUBST(mksrc)
412AC_SUBST(default_sys_path)
413AC_SUBST(INSTALL)
414AC_SUBST(GCC)
415AC_SUBST(diff_u)
416AC_SUBST(use_meta)
417AC_SUBST(use_filemon)
418AC_SUBST(filemon_h)
419AC_SUBST(_MAKE_VERSION)
420bm_outfiles="Makefile.config unit-tests/Makefile.config make-bootstrap.sh"
421if test $use_makefile = yes; then
422   bm_outfiles="makefile $bm_outfiles"
423fi
424AC_OUTPUT($bm_outfiles)
425cat <<EOF
426
427You can now run
428
429	sh ./make-bootstrap.sh
430
431to produce a fully functional bmake.
432
433EOF
434